Actor D4Cycloptis : D4Demon replaces FlemoidusCycloptisCommonusV3
{
	Health 50
	SeeSound "spectre/sight"
	AttackSound "spectre/melee"
	PainSound "spectre/pain"
	DeathSound "spectre/death"
	ActiveSound "spectre/active"
	Obituary "$OB_CYCLOPTIS"
	Tag "Flemoidus Cyclopticus"
	+MISSILEMORE
	Translation ""
	BloodColor "Green"
	States
	{
	Spawn:
		CYCL A 0 NODELAY A_SetUserVar(user_bigmonstersound,0)
		Goto Idle
	Idle:
		CYCL A 10 A_Look
		Loop
	See:
		CYCL AABBCCDD 3 A_Chase
		Loop
	
		
	//------------------------	
	Missile:
		TNT1 A 0 A_PlaySound("Doom4/Monsters/Grunt/AttackOneInEight",CHAN_AUTO,1.0,false,1.2)
		CYCL EF 5 A_FaceTarget
		CYCL G 0 Bright A_CustomMissile("FlemPlasmaBall",31,7,-3)
		CYCL G 0 Bright A_CustomMissile("FlemPlasmaBall",31,7,-3)
		CYCL G 0 Bright A_CustomMissile("FlemPlasmaBall",31,7,-2)
		CYCL G 0 Bright A_CustomMissile("FlemPlasmaBall",31,7,-2)
		CYCL G 0 Bright A_CustomMissile("FlemPlasmaBall",31,7,1)
		CYCL G 0 Bright A_CustomMissile("FlemPlasmaBall",31,7,-1)
		CYCL G 5 Bright A_CustomMissile("FlemPlasmaBall",31,7,0)
		CYCL F 5 A_FaceTarget
		Goto See
	
	Pain:
		CYCL H 3
		CYCL H 3 A_Pain
		Goto See

	Death:
		"####" "#" 0 A_SpawnItemEx("SituationalPinata",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION|SXF_TRANSFERPOINTERS)
		CYCL I 4 
		CYCL J 4 A_Scream
		CYCL K 4 A_NoBlocking
		CYCL LM 4
		CYCL N -1 
		Stop
	
	Raise:
		CYCL MLK 3
		CYCL JI 3
		Goto See
		
	//-------------------------
	// Regular chainsaw kill
	Death.ChainsawKill:
		TNT1 A 0 A_SpawnItemEx("D4PinataHealth",0,0,0,frandom(-4,4),frandom(-4,4),frandom(1,5),0,SXF_NOCHECKPOSITION)
		Goto XDeath
	//-------------------------
	// Chainsaw execution	
	Death.ChainsawPinata:	
		TNT1 A 0 A_GiveToTarget("SuccessfulExecutionToken",1)
		TNT1 A 0 A_SpawnItemEx("ChainsawExecutionPinata",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION|SXF_TRANSFERPOINTERS)
		Goto XDeath
	//-------------------------		
	// BerserkKill
	Death.BerserkKill:
		TNT1 AA 0 A_SpawnItemEx("D4PinataHealth",0,0,0,frandom(-4,4),frandom(-4,4),frandom(1,5),0,SXF_NOCHECKPOSITION)
		Goto XDeath
		
	//------------------------------------------------------------------------
	// Start of Stagger / Glory Kill states
	//------------------------------------------------------------------------
	Wound:
		CYCL H 0 A_SetUserVar(user_healto,20)
		Goto WoundStagger	// see MonsterBase.AED
		
	Death.GloryKill:
		CYCL H 0
		Goto GloryKillGeneric // see MonsterBase.AED
		
	GloryEnd:	//depending on the monster, is what and how much will spawn
		TNT1 A 1 A_SpawnItemEx("GloryKillPinata",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION|SXF_TRANSFERPOINTERS)
		Goto XDeath
	}
}

//================================================================================================================
//================================================================================================================
//
//	"No drops" version
//	
//================================================================================================================
//================================================================================================================

Actor D4CycloptisND : D4Cycloptis
{
	//$Angled
	//$Category "D4T Monsters (No Drops)"
	//$Color 12
	//$Title "Possessed Solider (pistol)"
	DropItem ""
}