ACTOR D4FlemMine : D4LostSoul replaces D4ChexSoul
{
	Health 40
	SeeSound "skull/sight"
	AttackSound "skull/melee"
	PainSound "skull/pain"
	DeathSound "skull/death"
	ActiveSound "skull/active"
	Obituary "$OB_FLEMMINE"
	+DONTCORPSE
	Tag "Flem Mine"
	States
	{
	Spawn:
		SKUL A 0 NODELAY A_SetUserVar(user_cooldown,4) //gives a bit of time so that it doesnt attack immediately after spawning
	Idle:
		SKUL AB 1 BRIGHT
		SKUL A 0 A_Look
		Loop
	See:
		SKUL A 0 A_JumpIf(user_cooldown>=0,"Wander")
		SKUL A 2 BRIGHT A_Chase
		SKUL B 2 BRIGHT A_Chase("","")
		Loop
	Wander:
		SKUL A 0 A_Chase("Melee","",CHF_DONTMOVE)
		SKUL A 2 BRIGHT A_Wander
		SKUL A 0 A_Chase("Melee","",CHF_DONTMOVE)
		SKUL B 2 BRIGHT A_Wander
		SKUL A 0 A_SetUserVar(user_cooldown,user_cooldown-1)
		Goto See
		
	Melee:
		SKUL A 0 A_Die("SkullExplo")
		Goto Death
	Missile:
		SKUL A 0 A_FaceTarget
		SKUL A 0 A_PlaySound("skull/melee",CHAN_AUTO,0.6,false,1.15)
		SKUL ABABABABABABABA 2 BRIGHT
		SKUL B 0 BRIGHT A_SkullAttack(24)	//attack frame
		SKUL A 0 A_SetUserVar(user_cooldown,26)	//sets the cooldown timer, about 3 sec
		SKUL B 2 BRIGHT
		Wait
	Pain: 
		SKUL EE 2 BRIGHT
		SKUL E 0 A_Pain
		SKUL E 2 BRIGHT
		Goto See
	
	Death.SkullExplo:
		//SKUL A 0 A_Explode(40,64,0)
		SKUL A 0 A_CustomMissile("LostSoulExploder",0,0,0)
		Goto Death
	XDeath:
	Death:
		SKUL F 0 A_ChangeFlag(THRUACTORS,true)
		SKUL F 0 A_Scream
		SKUL F 0 A_NoBlocking
		SKUL F 0 A_SpawnItemEx("LostSoulExploParticle",0,0,25,frandom(-2,2),frandom(-2,2),frandom(-2,2),random(0,359),SXF_NOCHECKPOSITION)
		TNT1 A 2 Light("YellowMediumFlicker1")
		TNT1 A 2 Light("YellowMediumFlicker2")
		TNT1 A 1 Light("YellowMediumFlicker3")
		TNT1 A 1 Light("YellowSmallFlicker1")
		TNT1 A 1 Light("YellowSmallFlicker2")
		TNT1 A 1 Light("YellowSmallFlicker3")
		Stop
	}
}

//================================================================================================================
//================================================================================================================
//
//	"No drops" version
//	Excatly the same as regular, but oh well
//================================================================================================================
//================================================================================================================

Actor D4FlemMineND : D4FlemMine
{
	//$Angled
	//$Category "D4T Monsters (No Drops)"
	//$Color 12
	//$Title "Lost Soul"
	DropItem ""
}