ACTOR AdultRunnerOnCeiling
{
	Health 150
	PainChance 120
	Speed 5
	Radius 20
	Height 56
	Mass 400
	Monster
	+FLOORCLIP
	+NOTARGET
	+NOGRAVITY
	//+DROPOFF
	+SPAWNCEILING
	+NOVERTICALMELEERANGE 
    +NOTELEOTHER
	+NOTELEPORT
	MaxDropOffHeight 32
	MinMissileChance 150
	SeeSound ""
	AttackSound "BambiMelee"
	PainSound "BambiPain"
	DeathSound "BambiDie"
	ActiveSound ""
	BloodType "ATGreenBlood"	
	BloodColor "Green"
	DamageFactor "XenoPosioin", 0.0
	Scale 0.7
	States
	{
	Spawn:
	    TNT1 A 0 A_JumpIfInventory("DropOnFloor", 1, "LookFloor")
		BAM3 A 1 A_Look
		Loop
	LookFloor:
		BAM2 A 1 A_Look
		Loop
		
	See:
            TNT1 A 0 ACS_ExecuteAlways(802, 0, 20, 56)
	    TNT1 A 0 A_JumpIfInventory("DropOnFloor", 1, "SeeFloor")
		BAM3 AAABBBCCCDDDEEEFFFGGG 1 A_Chase
		Loop
	SeeFloor:
		BAM2 AAABBBCCCDDDEEEFFFGGG 1 A_Chase
		Loop		
	Melee:
	    TNT1 A 0 A_JumpIfInventory("DropOnFloor", 1, "MeleeOnFloor")
		TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(506,0,0,0) <= 50, "DropOnFloor")
	    Goto See	
	MeleeOnFloor:
	    BAM2 A 2
	    BAM2 HIJ 1  A_FaceTarget 
		BAM2 K 2 A_CustomMeleeAttack(10)
		BAM2 L 1 A_FaceTarget
		BAM2 MN 1  A_FaceTarget
		BAM2 A 2
		Goto See
		
	DropOnFloor:
	    TNT1 A 0 A_ChangeFlag("NOPAIN", True)
		TNT1 A 0 A_ChangeFlag("NOGRAVITY", False)
		TNT1 A 0 A_PlaySound("BambiPain")
		BAM2 QPO 3
		TNT1 A 0 A_GiveInventory("DropOnFloor", 1)
		TNT1 A 0 A_ChangeFlag("NOPAIN", False)
		Goto SeeFloor	
	Pain:
	    TNT1 A 0 A_JumpIfInventory("DropOnFloor", 1, "PainOnFloor")
	    BAM3 A 1
	    Goto See
	PainOnFloor:
		BAM2 O 1 A_Pain
		BAM2 O 3
		BAM2 PQ 4 
		Goto See
	Death:
	    TNT1 A 0 A_JumpIfInventory("DropOnFloor", 1, "DeathOnFloor")
	    BAM3 H 4 A_Scream
		BAM3 IJ 4
		BAM3 K 4
		BAM3 L 4
	    TNT1 A 0 A_SpawnItemEx("DogCeilingDeath", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	    Stop
	DeathOnFloor:
		BAM2 R 4 A_Scream
		BAM2 STU 4 
		BAM2 V 4 A_NoBlocking
		TNT1 A 0 A_SpawnItemEx("DogAlienDeath", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
		Stop
	XDeath:	
	    TNT1 AAA 0 A_SpawnItem("ATGreenBlood", 0, 450) 
		TNT1 A 0 A_Scream
		TNT1 A 0 A_NoBlocking
		Stop		
	}
}

Actor DogCeilingDeath
{
    -SOLID
	-SHOOTABLE
	+ACTIVATEMCROSS
	+DONTGIB
	+NOICEDEATH
	+OLDRADIUSDMG
	+NODAMAGETHRUST
    +BLOODLESSIMPACT
	+DONTSPLASH
	-NOGRAVITY
	radius 0
    height 0
	Scale 0.7
	mass 500
	DamageType "XenoPosioin"
	States
	{
		Spawn:
		BAM3 L 55 A_Explode(1,4)
		Loop
		}
}

Actor DogCeilingSpawner
{
  States
  {
    Spawn:
	   TNT1 A 1
	   TNT1 A 1 A_JumpIf(ACS_ExecuteWithResult(507,0,0,0) == 1, "IsSky")
	   Spawn1:
	   TNT1 A 0 A_SpawnItemEx("AdultRunnerOnCeiling", 0, 0, CeilingZ-Z, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	   Stop
	IsSky:
	   TNT1 A 0 A_SpawnItemEx("AdultRunner", 0, 0, FloorZ-Z, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	   Stop
	   }
}