Actor LegendaryPowerShard : CustomInventory 16706 //Blood stop being cringy, leg crystal is a shitty name. -Legendary
{
//$Category Powerups/LCA
//$Sprite PPOSA0
//$Title "Legendary Power Shard"
Scale 0.75
+FLOAT
+FLOATBOB
+COUNTITEM
+NOTIMEFREEZE
+INVENTORY.INVBAR
+INVENTORY.BIGPOWERUP
Inventory.MaxAmount 1
Inventory.Icon "PPOSZ0"
Inventory.UseSound "legendary/defense"
Inventory.PickupSound "legendarycrystal/take"
Inventory.PickupMessage "You got the Legendary Power Shard!  Is this part of what makes Legendaries tick?"
Tag "Legendary Power Shard"
States
	{
	Spawn:
		PPOS ABCDEFABCDEF 4 Bright A_CustomMissile("LegendaryDRuneFlameSpawner",-20,0,random(0,-360),2,random(0,360))
		PPOS ABCDEF 4 Bright A_CustomMissile("LegendaryDRuneFlameSpawner",-20,0,random(0,-360),2,random(0,360)) 
		Loop
	Use:
		TNT1 A 0
		TNT1 A 1 A_GiveInventory("LegendaryCrystalProtect",1)
		TNT1 A 1 A_GiveInventory("LegendaryCrystalHealing",1)	
		Stop  	
	}
}

Actor PowerLegCrystalHeal : PowerTargeter
{
+NOTIMEFREEZE
Powerup.Duration -30
States
	{
	Targeter:
		TNT1 AA 0
		TNT1 A 0 HealThing(1,200)
		TNT1 A 0 A_GiveInventory("LegCrystalArmorGiver",1)
		TNT1 A 0 A_CustomMissile("LegendaryBlueSparkleSpawner",0,0,random(0,-360),2,random(0,360))
		TNT1 AA 3 A_SpawnItemEx("LegendaryBluePowerLine",random(32,-32),random(32,-32),random(8,48),0,0,random(1,4),0,SXF_CLIENTSIDE,0) 
		Loop
	}
}

Actor LegendaryCrystalHealing : PowerupGiver
{
+NOTIMEFREEZE
+INVENTORY.AUTOACTIVATE
+INVENTORY.ALWAYSPICKUP
Powerup.Type PowerLegCrystalHeal
}

ACTOR LegCrystalArmorGiver : ArmorBonus
{
+NOTIMEFREEZE
Armor.SavePercent 1
Armor.SaveAmount 1
Armor.MaxSaveAmount 450
Inventory.Icon "ARM2B0"
}

Actor LegendaryCrystalProtectEffect : PowerProtection
{
DamageFactor "Normal",0.5
}

Actor LegendaryCrystalProtect: PowerupGiver
{
+NOTIMEFREEZE
Inventory.MaxAmount 0
Powerup.Type LegendaryCrystalProtectEffect
Powerup.Color Blue 0.15
Powerup.Duration -30
+INVENTORY.AUTOACTIVATE
+INVENTORY.ALWAYSPICKUP
States
	{
	Spawn:
		ROWL A 1 Bright
		Loop
	}
}