ACTOR DemonicZombie 16557
{ 
//$Category Monsters/LCA
//$Sprite DZMIA1
//$Title "Demonic Zombie"
MONSTER 
Health 200
Radius 20
Height 56
Speed 8
Mass 400
Scale 1.075
PainChance 100
PainChance "ZombieCannon", 0
+FLOORCLIP
+MISSILEMORE
+MISSILEEVENMORE
+QUICKTORETALIATE
DamageFactor "ZombieCannon", 0.0
DropItem "PortableMedkit", 200
DropItem "ArmorPlate", 200
DropItem "HandGrenadeAmmo", 225, 1
DropItem "MineAmmo", 125, 1
DropItem "AmmoPack", 125
DropItem "DemonAmmo", 250, 60
DropItem "DemonAmmoBox", 105
DropItem "BehemothCannon", 72
DropItem "RedArmor", 1
SeeSound "superzombie/sight"
PainSound "superzombie/pain"
DeathSound "superzombie/death"
ActiveSound "superzombie/active"
Obituary "%o met a Demonic Zombie and was obliterated by his Behemoth Cannon."
States
	{
	Spawn:
		DZMM A 10 A_Look
		DZMI A 10 A_Look
		Loop
	See:
		DZMM AABB 3 A_Chase
		TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
		DZMM CCDD 3 A_Chase
		TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
		Loop
	Missile:
		TNT1 A 0 A_Jump(128,"Missile2")
		TNT1 A 0 A_Jump(64,"Missile3")
		Goto See
	Missile2:
		DZMM EEEEEEEEEEEEEEE 1 A_FaceTarget
		TNT1 A 0 A_CustomMissile("ZombieComet",32,0,-2)
		TNT1 A 0 A_CustomMissile("ZombieComet",32,0,2)
		DZMM F 15 Bright A_CustomMissile("ZombieComet",32,0,0)
		DZMM E 12 A_FaceTarget
		TNT1 A 0 A_CustomMissile("ZombieComet",32,0,-2)
		TNT1 A 0 A_CustomMissile("ZombieComet",32,0,2)
		DZMM F 15 Bright A_CustomMissile("ZombieComet",32,0,0)
		DZMM E 20
		TNT1 A 0 A_Jump(64,"Missile3")
		Goto See
	Missile3:
		DZMM EEEEEEEEEEEEEEE 1 A_FaceTarget
		TNT1 A 0 A_CustomMissile("ZombieSeekingComet",32,0,-10)
		DZMM F 15 Bright A_CustomMissile("ZombieSeekingComet",32,0,10)
		DZMM E 20 
		Goto See
	Pain:
		DZMM G 6 A_Pain
		Goto See
	Death:
		DZMM H 5 A_Scream
		DZMM I 5 A_Fall
		DZMM J 5 A_SpawnItem("BodyCrash",0,0,0,0)
		DZMM KLM 5
		DZMM N 63000 CanRaise
		Stop
	XDeath:
		DZMM O 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		DZMM P 3 A_XScream
		DZMM Q 3 A_Fall
		DZMM RST 3
		DZMM W 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		DZMM NMLKJIH 5
		Goto See
	}
}

ACTOR ZombieComet : BehemothComet
{
DamageType "ZombieCannon"
}

ACTOR ZombieSeekingComet : Comet
{
Scale 0.55
RenderStyle Add
Alpha 0.85
MissileType ""
Decal "Scorch"
+THRUSPECIES
+MTHRUSPECIES
+SEEKERMISSILE
+SCREENSEEKER
DamageType "ZombieCannon"
States
	{
	Spawn:
		TNT1 A 0 A_SeekerMissile(15,15,SMF_LOOK)
		BHTB AAAAA 1 Bright A_SpawnItemEx("BehemothSeekingTail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		TNT1 A 0 A_SeekerMissile(15,15,SMF_LOOK)
		BHTB BBBBB 1 Bright A_SpawnItemEx("BehemothSeekingTail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		Loop
	Death:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("OrangeParticleSpawner",0,0,0,0,0,0,0,128)
		COMT D 3 Bright A_SpawnItemEx("CometDeathGlow",0,0,0,0,0,0,0,128,0)
		COMT E 3 Bright A_SpawnItemEx("CometDeath",0,0,0,0,0,0,0,128,0)
		Stop
	}
}