ACTOR DesertHornet 16558
{
//$Category Monsters/LCA
//$Sprite WASPA1
//$Title "Desert Hornet"
MONSTER
Health 10
Height 32
Radius 16
Mass 50
Speed 20
Bloodcolor "yellow"
Maxtargetrange 256
Damage 2
+FLOAT
+FLOATBOB
+NOGRAVITY
+SPAWNFLOAT
+NOBLOODDECALS
+DONTOVERLAP
Species "nobles"
damagetype "hornet"
damagefactor "hornet", 0
DamageFactor "NobleComet", 0.0
DropItem "LifeEssence", 25
Deathsound "Hornet/Death"
Obituary "%o was pierced by a Desert Hornet's stinger."
States
	{
	Spawn:
		WASP A 0
		TNT1 A 0 A_PlaySound("Hornet/Fly",7,1.0,1)
		WASP AB 2 A_Look
		Goto Spawn+1
	See:
		TNT1 A 0 A_PlaySound("Hornet/Fly",7,1.0,1)
		TNT1 A 0 A_JumpIfCloser(180,"Dodge")
		WASP AB 2 A_Chase
		Loop
	Dodge:
		TNT1 A 0 A_PlaySound("Hornet/Fly",7,1.0,1)
		WASP A 1 A_FastChase
		WASP A 1 A_FaceTarget
		WASP B 1 A_FastChase
		WASP B 1 A_FaceTarget
		Goto See
	Missile:
		TNT1 A 0 A_Jump(128,"Stinger")
		TNT1 A 0 A_PlaySound("Hornet/Fly",7,1.0,1)
		WASP A 2 A_FaceTarget
		WASP B 2 A_SkullAttack
		Goto See
	Stinger:
		WASP A 2 A_FaceTarget
		WASP B 2 A_CustomMissile("HornetStinger",6,0,0)
		WASP B 2
		Goto See
	Death:
		TNT1 AAA 0 A_StopSound(7)
		WASP C 1
		TNT1 A 0 A_ChangeFlag("FLOATBOB",0)
		TNT1 A 0 A_ScreamAndUnblock
	Fall:
		WASP C 1 A_CheckFloor("Splat")
		Loop
	Splat:
		WASP D 1 A_Stop
		TNT1 A 0 A_PlaySound("Hornet/Splat")
		WASP D 525
		WASP D 5 A_FadeOut(0.1,1)
		Stop
	}
}

Actor HornetStinger
{
Projectile
Radius 5
Height 8
Speed 60
Decal "Bulletchip"
Scale 0.4
Damage 3
+BLOODSPLATTER
SeeSound ""
DeathSound ""
States
	{
	Spawn:
		DART A 1 A_CustomMissile("NailBlur",0,0,180)
		Loop
	Crash:
		DART BCDEFG 2
		Stop
	XDeath:
		DART BCDEFG 2
		Stop
	Death:
		DART BCDEFG 2
		Stop
	}
}

Actor NailBlur       
{
Height 8
Radius 1
Speed 0.2
Damage 0
Scale 0.6
RenderStyle Translucent
Alpha 0.5
+NOGRAVITY
+DROPOFF
States
	{
	Spawn:
		DART A 1 A_FadeOut(0.1,1)
		Loop
	}
}