ACTOR ExplosiveMinigunner : ChaingunGuy 16556
{
//$Category Monsters/LCA
//$Sprite EXP2A1
//$Title "Explosive Minigunner"
Monster
Health 150
Speed 7
Mass 100
PainChance 110
+MISSILEMORE
+QUICKTORETALIATE
DamageFactor "EMGEx", 0.0
DropItem "StimKit", 180
DropItem "ArmorBooster", 180
DropItem "AmmoPack", 165
DropItem "HandGrenadeAmmo", 250, 1
DropItem "MineAmmo", 180, 1
DropItem "BulletMag", 256, 10
DropItem "BulletBox", 128
DropItem "Armorplate", 215, 1
DropItem "Portablemedkit", 230, 1
DropItem "Backpack", 80, 1
DropItem "Explosive Minigun", 65
SeeSound "superzombie/sight"
PainSound "superzombie/pain"
DeathSound "superzombie/death"
ActiveSound "superzombie/active"
AttackSound "weapons/minigunfire"
Obituary "%o was blown to smithereens by an Explosive Minigunner."
States
	{
	Spawn:
		EXP2 A 10 A_Look
		EXPI A 10 A_Look
		Loop
	See:
		EXP2 AABB 3 A_Chase
		TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
		EXP2 CCDD 3 A_Chase
		TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
		Loop
	Missile:
		TNT1 A 0 A_PlaySound("weapons/expmgunspinstart")
		EXP2 EEEEEEEEEEEEEEEEEEEEEEEEE 1 A_FaceTarget(45)
		Goto MissileLoop
	MissileLoop:
		TNT1 A 0 A_PlaySoundEx("weapons/expmgunspin","Voice")
		TNT1 A 0 A_PlaySound("sentient/fire")
		TNT1 A 0 A_CustomMissile("MinigunnerExplosiveTracer",Random(30,34),0,Random(15,-15),0)
		TNT1 A 0 A_SpawnItemEx("OrangeShellCasing",12,6,28,Random(2,6),0,Random(1,3),Random(-80,-90),128)
		TNT1 A 0 A_Facetarget
		EXP2 E 4 Bright A_CPosAttack
		TNT1 A 0 A_PlaySound("sentient/fire")
		TNT1 A 0 A_CustomMissile("MinigunnerExplosiveTracer",Random(30,34),0,Random(15,-15),0)
		TNT1 A 0 A_SpawnItemEx("OrangeShellCasing",12,6,30,Random(2,6),0,Random(1,3),Random(-80,-90),128)
		TNT1 A 0 A_Facetarget
		EXP2 F 4 Bright A_CPosAttack
		TNT1 A 0 A_PlaySound("weapons/expmgunspinstop")
		TNT1 A 0 A_StopSoundEx("Voice")
		TNT1 A 0 A_CPosRefire
		Loop
	Pain:
		TNT1 A 0
		EXP2 G 6 A_Pain
		Goto See
	Death:
		TNT1 AAA 0 A_StopSoundEx("Voice")
		EXP2 H 5
		EXP2 I 5 A_Scream 
		EXP2 J 5 A_Fall
		EXP2 K 5 A_SpawnItem("BodyCrash",0,0,0,0)
		EXP2 LM 5
		EXP2 N 63000 CanRaise
		Stop
	XDeath:
		TNT1 AAA 0 A_StopSoundEx("Voice")
		EXP2 O 3 
		EXP2 P 3 A_XScream
		EXP2 Q 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		EXP2 R 3 A_Fall 
		EXP2 STUV 3
		EXP2 W 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		EXP2 VUTSRQPO 5
		Goto See
	}
}

ACTOR MinigunnerExplosiveTracer : BabySentientExplosiveTracer
{
DamageType "EMGEx"
States
	{
	Spawn:
		TRAC A 1 Bright
		Loop
	Death:
		TNT1 A 0
		TNT1 A 0 A_SetTranslucent(0.75,1)
		TNT1 A 0 A_SpawnItem("SentientExplosiveEffect")
		MISL B 4 Bright A_Explode(Random(3,6)*5,72)
		MISL CD 3 Bright
		Stop
	}
}