ACTOR LegendaryStealthTrooper 16502 
{ 
//$Category Monsters/LCA
//$Sprite LCMDA1
//$Title "Legendary Stealth Trooper"
MONSTER 
Health 1100
Radius 20
Height 56
Speed 10
Mass 100
BloodColor "Blue"
PainChance 25
PainChance "ZombieDemonTech", 0
+BOSS
+NOFEAR
+BOSSDEATH
+NOTIMEFREEZE
+FLOORCLIP
+MISSILEMORE
+MISSILEEVENMORE
+QUICKTORETALIATE
+NOICEDEATH
+NODROPOFF
+DONTGIB
+NOTARGET
+NORADIUSDMG
+FORCERADIUSDMG
DamageFactor "PDTBFG", 0.25
DamageFactor "PDTBFGTracer", 0.25
DamageFactor "PlayerDevBall", 0.125
DamageFactor "PlayerDevBall2", 0.125
DamageFactor "PlayerDTBFGRailgunSlug", 0.125
DamageFactor "PlayerDevTracer", 0.125
DamageFactor "DBFG10K2", 0.65
DamageFactor "PlayerDBFG10K2", 0.65
DamageFactor "DBFG2", 0.65
DamageFactor "PlayerDBFG2", 0.65
DamageFactor "PlayerDTRG", 0.5
DamageFactor "LegendaryPlayer", 0.3
DamageFactor "LegendaryGuruPlayer", 0.3
DamageFactor 0.65
//No infighting
DamageFactor "LegendaryZombie", 0.0
DamageFactor "Legendary", 0.0
DamageFactor "LegendaryGuru", 0.0
DropItem "LegendaryArmor" 87 1
DropItem "LegAmmoSphere" 90 1
DropItem "HandGrenadeAmmo" 237 2
DropItem "MineAmmo" 237 2
DropItem "Backpack" 200 1
DropItem "Armorplate" 207 1
DropItem "Portablemedkit", 212, 1
DropItem "LegendaryBulletBox", 202 
DropItem "LegendaryBulletMag", 252, 20
DropItem "LegendaryRune", 62, 1
DropItem "Legendary Light Machine Gun", 202, 1
DropItem "LegendaryPowerShard", 65, 1
SeeSound "lcmdo/sight"
AttackSound "Null"
PainSound "lcmdo/pain"
DeathSound "lcmdo/death"
ActiveSound "lcmdo/active"
Obituary "%o was immediately gunned down by a Legendary Stealth Trooper."
var int user_music;
var int user_protection;
var int user_protected;
States 
	{
	Spawn:
		LCMD A 10 Bright A_Look
		TNT1 A 0 A_SpawnItemEx("LHellionSmokeSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,64)
		LCMD Z 10 Bright A_Look
		TNT1 AA 0 A_SpawnItemEx("LHellionSmokeSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,64)
		Loop
	See:
		TNT1 A 0 A_JumpIf(user_music == 1,3)
		TNT1 A 0 ACS_NamedExecuteAlways("StartMonsterMusic",0,19)
		TNT1 A 0 A_SetUserVar("user_music",1)
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		TNT1 A 0 A_JumpIfTargetInLOS("Strafing")
		LCMD AA 3 Bright A_Chase
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		LCMD BB 3 Bright A_Chase
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		TNT1 A 0 A_SpawnItem("LegendaryFootStep",0,0,0,0)
		TNT1 A 0 A_JumpIfTargetInLOS("Strafing")
		LCMD CC 3 Bright A_Chase
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		LCMD DD 3 Bright A_Chase
		TNT1 A 0 A_Jump(80,"Phase")		
		TNT1 A 0 A_Jump(80,"Rush")
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		TNT1 A 0 A_SpawnItem("LegendaryFootStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)	
		Loop
	Rush:
		TNT1 A 0 A_JumpIfTargetInLOS("Strafing")
		TNT1 A 0 A_SpawnItem("LegendaryFootStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		TNT1 A 0 A_SpawnItemEx("LegSTGhostA",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		LCMD A 1 Bright A_Chase
		TNT1 A 0 A_SpawnItemEx("LegSTGhostA",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		LCMD A 1 Bright A_Chase
		TNT1 A 0 A_SpawnItemEx("LegSTGhostB",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		LCMD B 1 Bright A_Chase
		TNT1 A 0 A_SpawnItemEx("LegSTGhostB",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		LCMD B 1 Bright A_Chase
		TNT1 A 0 A_Jump(80,"Phase")
		TNT1 A 0 A_SpawnItem("LegendaryFootStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		TNT1 A 0 A_SpawnItemEx("LegSTGhostC",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		LCMD C 1 Bright A_Chase
		TNT1 A 0 A_SpawnItemEx("LegSTGhostC",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		LCMD C 1 Bright A_Chase
		TNT1 A 0 A_SpawnItemEx("LegSTGhostD",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		LCMD D 1 Bright A_Chase
		TNT1 A 0 A_SpawnItemEx("LegSTGhostD",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		LCMD D 1 Bright A_Chase
		TNT1 A 0 A_SpawnItem("LegendaryFootStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		TNT1 A 0 A_Jump(84,"See")
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		Loop
	Strafing:
		TNT1 A 0 A_SpawnItem("LegendaryFootStep",0,0,0,0)
		TNT1 A 0 A_Chase("","Missile",CHF_DONTMOVE)
		LCMD AA 3 Bright A_GiveInventory("LegZombieStrafing",1)
		TNT1 A 0 A_Chase("","Missile",CHF_DONTMOVE)
		LCMD BB 3 Bright A_GiveInventory("LegZombieStrafing",1)
		TNT1 A 0 A_SpawnItem("LegendaryFootStep",0,0,0,0)
		TNT1 A 0 A_Chase("","Missile",CHF_DONTMOVE)
		LCMD CC 3 Bright A_GiveInventory("LegZombieStrafing",1)	
		TNT1 A 0 A_Chase("","Missile",CHF_DONTMOVE)
		LCMD DD 3 Bright A_GiveInventory("LegZombieStrafing",1)
		Goto See
	Phase:
		TNT1 A 0 A_PlaySound("phaseimp/teleport")
		LCMD E 2 A_FaceTarget
		LCMD E 1 A_SetTranslucent(0.75)
		LCMD E 1 A_SetTranslucent(0.55)
		LCMD E 1 A_SetTranslucent(0.35)
		LCMD E 1 A_SetTranslucent(0.20)
		Goto Phased
	UnPhase:
		TNT1 A 0 A_PlaySound("phaseimp/teleport")
		LCMD E 1 A_SetTranslucent(0.15)
		LCMD E 1 A_SetTranslucent(0.35)
		LCMD E 1 A_SetTranslucent(0.55)
		LCMD E 1 A_SetTranslucent(0.75)
		TNT1 A 0 A_SetTranslucent(1)
		LCMD E 2 A_FaceTarget		
		Goto See	
	Phased:
		LCMD AABBCCDDAABBCCDDAABBCCDDAABBCCDD 1 A_ExtChase(0,0)
		LCMD AABBCCDDAABBCCDD 1 A_Chase
		TNT1 A 0 A_Jump(24,"UnPhase")
		Goto Phased+32
	Pause:
		//TNT1 A 0 A_PlaySound("weapons/demontechsteam")
		LCMD EEEEE 3 Bright A_GiveInventory("LegZombieStrafing",1)
		Goto See
	Teleport:
		LCMD A 1 Bright A_UnSetShootable
		TNT1 AAAA 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		LCMD AAAAAAAAAA 1 Bright A_FadeOut(0.1,0)
		LCMD A 2 Bright
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 Bright A_Wander
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 Bright A_Wander
		LCMD A 1 Bright A_PlayWeaponSound("boss/teleport")
		TNT1 AAAA 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		LCMD AAAAAAAAAA 1 Bright A_FadeIn(0.1)
		TNT1 A 0 A_SetTranslucent(1)
		LCMD A 1 Bright A_SetShootable
		Goto See	
	Missile:
		LCMD EEEEEEEEEE 1 A_FaceTarget(45)
	Refire:
		TNT1 A 0 A_JumpIfInventory("LegLMGAmmo",76,"Reload")
		TNT1 A 0 A_CustomMissile("LegendaryBlueTracer",Random(28,34),0,Random(6,-6),0)
		TNT1 A 0 A_GiveInventory("LegLMGAmmo",1)
		TNT1 A 0 A_SpawnItemEx("LegRifleCasing", 12, -6, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
		TNT1 A 0 A_CustomBulletAttack(42.5,14,1,Random(10,20)*3,"LegModdedBulletPuff",0,CBAF_NORANDOM)
		TNT1 A 0 A_PlaySoundEx("weapons/LMGFire","Weapon")
		LCMD E 1 Bright A_GiveInventory("LegZombieStrafing",1)	
		LCMD E 5 Bright A_CustomBulletAttack(22.5,0,1,random(1,5)*3,"LegModdedBulletPuff",0,CBAF_NORANDOM)
		TNT1 A 0 A_CustomMissile("LegendaryBlueTracer",Random(28,34),0,Random(6,-6),0)
		TNT1 A 0 A_GiveInventory("LegLMGAmmo",1)
		TNT1 A 0 A_SpawnItemEx("LegRifleCasing",12,-6,36,Random(2,6),0,Random(1,3),Random(-80, -90),128)
		TNT1 A 0 A_CustomBulletAttack(42.5,14,1,Random(10,20)*3,"LegModdedBulletPuff",0,CBAF_NORANDOM)
		TNT1 A 0 A_PlaySoundEx("weapons/LMGFire","Weapon")
		LCMD E 1 Bright A_GiveInventory("LegZombieStrafing",1)
		LCMD F 5 Bright A_CustomBulletAttack(22.5,0,1,random(1,5)*3,"LegModdedBulletPuff",0,CBAF_NORANDOM)
		TNT1 A 0 A_CPosRefire
		TNT1 A 0 A_Jump(20,"Pause")
		TNT1 A 0 A_Jump(55,"Nade")
		//TNT1 A 0 A_Jump(20,"Mine")
		TNT1 A 0 A_Jump(45,"LegNade")
		Loop
	Nade:
		LCMD E 1 Bright A_JumpIfCloser(1000,1)
		Goto Missile
		TNT1 A 0 A_JumpIfCloser(280,"Missile")
		LCMD E 6 Bright A_GiveInventory("LegZombieStrafing",1)
		LCMD EEE 4 Bright A_GiveInventory("LegZombieStrafing",1)
		TNT1 A 0 A_GiveInventory("LegZombieStrafing",1)
		LCMD E 6 Bright A_CustomMissile("LGrenade",32,0,0,2,10)
		LCMD E 1 Bright
		Goto See
	LegNade:
		LCMD E 1 A_JumpIfCloser(1000,1)
		Goto Missile
		TNT1 A 0 A_JumpIfCloser(280,"Missile")
		LCMD E 12 Bright A_GiveInventory("LegZombieStrafing",1)
		LCMD EEE 6 Bright A_GiveInventory("LegZombieStrafing",1)
		TNT1 A 0 A_GiveInventory("LegZombieStrafing",1)
		LCMD E 6 Bright A_CustomMissile("LegThrownGrenade",32,0,0,2,10)
		LCMD EE 25 Bright
		Goto See
	Mine:
		LCMD C 1 Bright
		LCMD C 12 Bright A_CustomMissile("LACThrownMine",32,0,0,5,15)
		TNT1 A 0 Bright A_CustomMissile("LACThrownMine",32,0,0,-5,15)
		TNT1 A 0 Bright A_CustomMissile("LACThrownMine",32,0,0,0,15)
		LCMD E 12 Bright
		LCMD C 3 Bright
		Goto See
	Pain:
		TNT1 A 0 A_SetTranslucent(1)
		TNT1 A 0 A_Jump(15,"Protection")
	Pain2:
		TNT1 A 0 A_Jump(90,"Phase")
		TNT1 A 0 A_Jump(15,"Teleport")
		LCMD G 3 Bright A_GiveInventory("LegZombieStrafing",1)
		TNT1 A 0 A_Pain
		LCMD G 3 Bright A_GiveInventory("LegZombieStrafing",1)
		Goto See
	Protection:
		TNT1 A 0 A_JumpIf(user_protection >= 3,"Pain2")
		TNT1 A 0 A_JumpIf(user_protected == 1,"Pain2")
		TNT1 A 0 A_PlaySound("legendary/defense")
		TNT1 A 0 A_FaceTarget
		LCMD E 2 Bright ACS_NamedExecuteAlways("LegendaryProtection",0,0,0,0)
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		Goto See	
	Reload:
		TNT1 A 0 A_ChangeFlag("NoPain",1)
		TNT1 A 0 A_PlaySound("weapons/LMGReload2")
		TNT1 A 0 A_SpawnItemEx("LegendaryEmptyDrumSpawner",-8,7,30,4,0,(0.1)*Random(30,40),Random(-80,-90),128)
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		LCMD EE 25 Bright A_TakeInventory("LegLMGAmmo",76)
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		LCMD E 20 Bright A_PlaySound("weapons/LMGReload1") 
		LCMD E 40 Bright A_PlaySound("weapons/LMGReload3")
		TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner",0,0,0,0)
		TNT1 A 0 A_ChangeFlag("NoPain",0)
		Goto See
	Death:
		TNT1 A 0 A_Jump(36,"LegendarySoul") 
		TNT1 A 0 A_SetTranslucent(1)
		TNT1 A 0 A_StopSound(6)
		LCMD H 5 A_Scream
		LCMD I 5 A_Fall
		LCMD J 5 A_SpawnItem("BodyCrash",0,0,0,0)
		LCMD K 5 
		LCMD L 63000 CanRaise
		Stop
	LegendarySoul:
		TNT1 A 0 A_SetTranslucent(1)
		TNT1 A 0 A_StopSound(6)
		TNT1 A 0 A_SpawnItem("BHellionSmokeSpawner",0,0,0,0)
		LCMD H 5 A_Scream
		TNT1 A 0 A_SpawnItem("BHellionSmokeSpawner",0,0,0,0)
		LCMD I 5 A_Fall
		TNT1 A 0 A_SpawnItem("BHellionSmokeSpawner",0,0,0,0)
		LCMD J 5 A_SpawnItem("BodyCrash",0,0,0,0)
		TNT1 A 0 A_SpawnItem("BHellionSmokeSpawner",0,0,0,0)
		LCMD K 5 
		TNT1 A 0 A_SpawnItem("BHellionSmokeSpawner",0,0,0,0)
		LCMD L 140
		TNT1 A 0 A_PlaySoundEx("brain/spit","Voice",0,2)
		LCMD LLLLLLLLLLLLLLLLL 2 Bright A_GiveInventory("LegSoulEvent",1)
		LCMD LLLLLLLLLLLLLLLLL 2 Bright A_GiveInventory("LegSoulEvent",1)
		LCMD LLLLLLLLLLLLLLLLL 2 Bright A_GiveInventory("LegSoulEvent",1)
		TNT1 A 0 A_SpawnItemEx("LegendarySoul",0,0,16,0,0,0,0,32)
		TNT1 A 0 A_SpawnItemEx("TeleportFog",0,0,16,0,0,0,0,32)
		LCMD L 525
		LCMD L 5 A_FadeOut(0.1,1)
		Wait
	XDeath:
		TNT1 A 0 A_StopSound(6)
		LCMD O 3 A_SpawnItemEx("BlueGibbedGenerator",0,0,0,0,0,0,0,128,0)
		LCMD P 3 A_XScream
		LCMD R 3 A_Fall
		LCMD STUV 3 
		LCMD W 63000 CanRaise 
		Stop
	}
}

ACTOR LegSTGhostA 
{
PROJECTILE
Height 56
Radius 20
Speed 0
Scale 1.1
RENDERSTYLE Translucent
Alpha 0.7
+NOTIMEFREEZE
+NOINTERACTION
+CLIENTSIDEONLY
States 
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
		TNT1 A 1 Bright
		Goto Fade
	Fade:
		LCMD A 2 A_FadeOut(0.1,1)
		Loop
	Toaster:
		TNT1 A 1 Bright
		Stop
    }
}

ACTOR LegSTGhostB : LegSTGhostA 
{   
States 
	{
	Fade:
		LCMD B 2 A_FadeOut(0.1,1)
		Loop
    }
}

ACTOR LegSTGhostC : LegSTGhostA 
{   
States 
	{
	Fade:
		LCMD C 2 A_FadeOut(0.1,1)
		Loop
    }
}

ACTOR LegSTGhostD : LegSTGhostA 
{   
States 
	{
	Fade:
		LCMD D 2 A_FadeOut(0.1,1)
		Loop
	}
}
	
ACTOR LegLMGAmmo: Ammo
{
+IGNORESKILL
Inventory.MaxAmount 76
}

Actor LGrenade : ThrownGrenade
{
MissileType "LGrenadeExplosion"
Damage 8
+NOTIMEFREEZE
+BOUNCEONACTORS
Damagetype "Legendary"
Obituary "%o was blown up by a Legendary Commando's grenade."
States
	{
	Spawn:
		TNT1 A 0
		HGN1 A 3 A_StopSound
		HGN1 BCDEFGHABCDEFGHABCDEFGH 3
		Goto Death      
	Death: 
		TNT1 A 0
		TNT1 A 0 A_ChangeFlag("MISSILE",0)
		TNT1 A 0 A_AlertMonsters
		TNT1 A 0 A_PlaySound("weapons/hgrenadeex")
		TNT1 A 0 A_SpawnItemEx("LegendaryOrangeParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
		TNT1 AAA 0 A_CustomMissile("LegendaryKaboom3", 0, 0, random(0,360), 2, random(0,360))
		TNT1 AAA 0 A_CustomMissile("LegendarySmokeFX2", 0, 0, random(0,360), 2, random(0,360))
		TNT1 AAAA 0 A_SpawnItemEx("LegendaryDebris",0,0,0,Random(4,-4),Random(4,-4),Random(4,8),0,128)
		MISL B 4 Bright A_MissileAttack
		MISL CD 4 Bright A_SetTranslucent(0.75,1)
		Stop
	}
}

Actor LGrenadeExplosion
{
Projectile
Height 1
Radius 1
Speed 0
Scale 2.4
RenderStyle ADD
Alpha 0.95
Damagetype "Legendary"
+NOCLIP
+FLOORHUGGER
+NODAMAGETHRUST
+FORCERADIUSDMG
+NOTIMEFREEZE
Obituary "%o was blown up by a Legendary Commando's grenade."
States
	{
	Spawn:
		TNT1 A 1 
		TNT1 A 1 A_Explode(64,146)
		Stop
	}
}

Actor ExplosionSpawner
{
Height 6
Radius 6
Speed 40
Scale 0.01
Renderstyle Add
Alpha 0.9
Decal "Scorch"
BounceFactor 0.5
Damage (0)
+MISSILE
+FORCEXYBILLBOARD
//+DOOMBOUNCE
//+BLOODSPLATTER
States
	{
	Spawn:
		TNT1 AAAA 2 A_SpawnItem("SpawnedExplosionSmall")
		Stop
	Death:
		MISG A 1
		TNT1 A 10
		Stop
	XDeath:
		MISG A 1
		TNT1 A 10
		Stop
	}
}

Actor SmallExplosionSpawner: ExplosionSpawner
{
Speed 30
States
	{
	Spawn:
		TNT1 A 0
		TNT1 AAA 2 A_SpawnItem("SpawnedExplosionSmall")
		Stop
	}
}

Actor BarrelKaboom : DeadMarine
{
Game Doom
States
	{
	Spawn:
		TNT1 A 1
		TNT1 AAAAAA 0 A_CustomMissile ("SmallExplosionSpawner",20,0,random(0,360),2,random(0,180))
		TNT1 A 1 Bright
		Stop
	}
}

ACTOR SmokeFXN : SmokeFX  { Scale 0.5 }

ACTOR ExplosionSmoke
{
Health 99999
Height 5
Radius 5
Speed 1
Scale 1.1
RenderStyle Translucent
Alpha 0.1
BounceFactor 0.5
+MISSILE
+DROPOFF
+NOGRAVITY
+NOBLOCKMAP
+NOTELEPORT
+DONTSPLASH
+DOOMBOUNCE
+THRUACTORS
+FORCEXYBILLBOARD
+CLIENTSIDEONLY
States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(waterlevel > 1, "Death")
		SMK3 BBB 2 A_FadeIn(0.1)
		SMK3 B 20
		TNT1 A 0 A_JumpIf(waterlevel > 1, "Death")
		SMK3 CDEFGHIJKLM 3
		Goto Death
	Death:
		TNT1 A 1
		Stop
	}
}

ACTOR FlameTrails
{
Height 1
Radius 1
Speed 3
Scale 0.5
RenderStyle Add
Alpha 1
Damage (0)
+MISSILE
+DROPOFF
+NOGRAVITY
+NOBLOCKMAP
+THRUACTORS
+NOTELEPORT
+DONTSPLASH
+FORCEXYBILLBOARD
+CLIENTSIDEONLY
States
	{
	Spawn:
		TNT1 A 2
		FRPR ABCDEFGH 3 BRIGHT
		Stop
	}
}

ACTOR ExplosionFlames: FlameTrails
{
Speed 2
Scale 1.2
States
	{
    Spawn:
		TNT1 A 0
		BXPO AA 3 BRIGHT
		TNT1 AAA 0 A_CustomMissile("ExplosionSmoke",0,0,random(0,360),2,random(0,360))
		BXPO GHII 3 BRIGHT
		Stop
	}
}

ACTOR SmallExplosionFlames : ExplosionFlames
{
Speed 3
Scale 0.6
States
	{
    Spawn:
		TNT1 A 0
        BXPO AA 2 BRIGHT 
        BXPO BCDF 1 BRIGHT
        BXPO GHII 1 BRIGHT
        Stop
	}
}

Actor SpawnedExplosionSmall
{
Speed 30
+NOCLIP
+NOGRAVITY
+NOBLOCKMAP
States
	{
	Spawn:
		TNT1 A 2
		TNT1 A 2
		FXPO A 0 A_CustomMissile("SmokeFXN",0,0,random(0,360),2,random(0,360))
		FXPO A 0 A_CustomMissile("SmokeFXN",0,0,random(0,360),2,random(0,360))
		TNT1 AAAA 0 A_CustomMissile("SmallExplosionFlames",0,0,random(0,360),2,random(0,360))
		TNT1 A 1
		Stop
	}
}

ACTOR LegThrownGrenade : ThrownGrenade
{  
WallBounceFactor 0.32
BounceFactor 0.72
DamageType "Legendary"
SeeSound "weapons/lgrenadebounce"
Obituary "%o was blown up by a Legendary Commando's Legendary grenade."
States
	{
	Spawn:
		TNT1 A 0
		LGN1 A 3 A_StopSound
		LGN1 BCDEFGHABCDEFGHABCDEFGH 3
		Goto Death      
	Death: 
		TNT1 A 0
		TNT1 A 0 A_Explode(250,350,0)
		TNT1 A 0 A_SpawnItemEx("BarrelKaboom",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,0)
		TNT1 A 0 A_AlertMonsters
		TNT1 A 0 A_PlaySound("lnade/exp")
		TNT1 A 0 A_SpawnItemEx("BlueParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 A_CustomMissile("BlueKaboom3",0,0,random(0,360),2,random(0,360))
		TNT1 AAA 0 A_CustomMissile("SmokeFX2",0,0,random(0,360),2,random(0,360))
		TNT1 AAAA 0 A_SpawnItemEx("Debris",0,0,0,Random(-4,4),Random(-4,4),Random(4,8),0,SXF_CLIENTSIDE,0)
		TNT1 A 1 A_SpawnItem("LegendaryBlueRocketEx")
		Stop
	}
}