ACTOR PoisonousBruiserDemon 16570
{
//$Category Monsters/LCA
//$Sprite BRUSA1
//$Title "PoisonousBruiserDemon"
Monster
Health 1500
Height 64
Radius 24
Mass 2000
Speed 12
Scale 1.25
MissileType "PoisonousBruiserBall"
PainChance 6
MeleeDamage 128
+FLOORCLIP
+LOOKALLAROUND
+MISSILEEVENMORE
+QUICKTORETALIATE
+DONTHURTSPECIES
+DONTHARMSPECIES
Species "Nobles"
Damagefactor "Poison", 0.1
Damagefactor "Fire", 0.1
SeeSound "PoisonousBruiserDemon/scream"
PainSound "PoisonousBruiserDemon/pain"
DeathSound "PoisonousBruiserDemon/death"
ActiveSound "PoisonousBruiserDemon/act"
MeleeSound "baron/melee"
Obituary "%o was slaughtered by Poisonous Bruiser Demon."
HitObituary "%o was cremated by Poisonous Bruiser Demon."
Tag "\ctPoisonous Bruiser Demon\c-"
States
	{
	Spawn:
		PBRS A 10 Bright A_Look
		Loop
	See:
		PBRS AABBCCDD 3 Bright A_Chase
		Loop
	Melee:
		PBRS E 6 Bright A_FaceTarget
		PBRS F 6 Bright A_FaceTarget
		PBRS G 6 Bright A_ComboAttack
		Goto See
	Missile:
		TNT1 A 0 Bright A_Jump(144,"Missile3")
		PBRS EF 6 Bright A_FaceTarget
		PBRS G 6 Bright A_MissileAttack
		TNT1 A 0 Bright A_Jump(96,"Missile2")
		Goto See
	Missile2:
		PBRS HI 6 Bright A_FaceTarget
		PBRS J 6 Bright A_MissileAttack
		Goto See
	Missile3:
		TNT1 A 0 Bright A_Jump(96,"Missile5")
		PBRS E 6 Bright A_FaceTarget
		PBRS F 4 Bright A_FaceTarget
		PBRS F 2 Bright A_Custommissile("PoisonousBruiserBall2",56,0,-40,CMF_TRACKOWNER)
		PBRS G 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,-30,CMF_TRACKOWNER)
		PBRS G 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,-20,CMF_TRACKOWNER)
		PBRS G 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,-10,CMF_TRACKOWNER)
		PBRS G 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,0,CMF_TRACKOWNER)
		PBRS G 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,10,CMF_TRACKOWNER)
		PBRS G 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,20,CMF_TRACKOWNER)
		PBRS G 0 Bright A_Jump(96,"Missile4")
		Goto See
	Missile4:
		PBRS H 6 Bright A_FaceTarget
		PBRS I 4 Bright A_FaceTarget
		PBRS I 2 Bright A_Custommissile("PoisonousBruiserBall2",56,0,40,CMF_TRACKOWNER)
		PBRS J 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,30,CMF_TRACKOWNER)
		PBRS J 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,20,CMF_TRACKOWNER)
		PBRS J 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,10,CMF_TRACKOWNER)
		PBRS J 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,0,CMF_TRACKOWNER)
		PBRS J 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,-10,CMF_TRACKOWNER)
		PBRS J 1 Bright A_Custommissile("PoisonousBruiserBall2",56,0,-20,CMF_TRACKOWNER)
		Goto See
	Missile5:
		PBRS KL 6 Bright A_FaceTarget
		PBRS M 2 Bright A_Custommissile("PoisonousBruiserFireSpawner",16,0,-15,CMF_TRACKOWNER)
		PBRS M 2 Bright A_Custommissile("PoisonousBruiserFireSpawner",16,0,0,CMF_TRACKOWNER)
		PBRS M 2 Bright A_Custommissile("PoisonousBruiserFireSpawner",16,0,15,CMF_TRACKOWNER)
		Goto See
	Pain:
		PBRS N 5 Bright A_Pain
		Goto See
	Death:
		PBRE A 6 Bright A_Scream
		PBRE BCD 4 Bright
		PBRE EFG 4 Bright
		PBRE H 4 Bright A_Fall
		PBRE IJKLMNOP 4 Bright
		PBRE QRSTUV 4
		PBRE W 63000 CanRaise
		Stop
	}
}

Actor PoisonousBruiserBall
{
Projectile
Height 16
Radius 16
Speed 18
RenderStyle Add
Alpha 0.9
Decal "Scorch"
Damage 26
+RANDOMIZE
SeeSound "imp/attack"
DeathSound "imp/shotx"
States
	{
	Spawn:
		PBB1 AABB 2 Bright A_SpawnItemEx("PoisonousBruiserBallTrail2",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		Loop
	Death:
		PBB1 KLMNOPQRSTUVWX 3 Bright
		Stop
	}
}

Actor PoisonousBruiserBall2
{
Projectile
Height 8
Radius 8
Speed 10
RenderStyle Add
Alpha 0.9
Decal "BaronScorch"
Damage 18
+RANDOMIZE
SeeSound "imp/attack"
DeathSound "imp/shotx"
States
	{
	Spawn:
		PBB2 AB 6 Bright
		Loop
	Death:
		PBB2 CDEFGHI 3 Bright
		Stop
	}
}

Actor PoisonousBruiserFireSpawner
{
Projectile
Height 8
Radius 8
Speed 12
Missileheight 0
MissileType "PoisonousBruiserFire"
Damage (0)
+RIPPER
+FLOORHUGGER
+BLOODLESSIMPACT
States
	{
	Spawn:
		TNT1 A 3 Bright A_MissileAttack
		TNT1 A 3
		TNT1 A 3
		Loop
	Death:
		TNT1 A 6
		Stop
	}
}

Actor PoisonousBruiserBallTrail2
{
Projectile
Height 1
Radius 1
Speed 0
RenderStyle Add
Alpha 0.7
+NOINTERACTION
+CLIENTSIDEONLY
States
	{
	Spawn:
		TNT1 A 0 Bright
		PBB1 CDEFGHIJ 4 Bright
		Stop
	}
}

Actor PoisonousBruiserFire
{
Projectile
Height 1
Radius 1
Speed 0
RenderStyle Add
Alpha 0.9
Damage 20
+NOCLIP
+FLOORHUGGER
+THRUSPECIES
+MTHRUSPECIES
SeeSound "weapons/rocklx"
States
	{
	Spawn:
		TNT1 A 0 Bright
		XPBF AB 3 Bright
		XPBF C 3 Bright A_Explode(48,128,0)
		XPBF DEFGHIJKLMNOPQRST 3 Bright
		Stop
	}
}