ACTOR ToxicFiend : BullFiend 16660
{ 
//$Category Monsters/LCA
//$Sprite TOXDA1C1
//$Title "Toxic Fiend"
Monster
Health 350
Speed 16
Scale 1.1
BloodColor "Green"
MaxTargetRange 790
PainChance 55
+MISSILEMORE
+MISSILEEVENMORE
+QUICKTORETALIATE
+FASTMELEE
+DONTHURTSPECIES
+DONTHARMSPECIES
DamageFactor "Poison", 0.0
DamageFactor "PoisonCloud", 0.0
DamageFactor "FiendFire", 0.0
DamageFactor "DTFiendEx", 0.0
DropItem "LifeEssence", 256
DropItem "ArmorBonusMax", 256
DropItem "BossLifeEssence", 128
DropItem "BossArmorBonusMax", 128
DropItem "DemonAmmo", 132, 120
DropItem "DemonAmmoBox", 32, 200
SeeSound "magma/sight"
PainSound "monster/psopain"
DeathSound "magma/death"
ActiveSound "magma/active"
AttackSound "magma/attack"
Obituary "%o was turned into toxic waste by a Toxic Fiend." 
HitObituary "%o was ripped open by a Toxic Fiend."
Tag "\cdToxic Fiend\c-"
States 
	{ 
	Spawn: 
		TOXD A 12 Bright A_Look
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawnerFiend",0,0,0,0)
		TAI3 A 12 Bright A_Look
		TNT1 AA 0 A_SpawnItem("GHellionSmokeSpawnerFiend",0,0,0,0)
		Loop
	See: 
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawnerFiend",0,0,0,0)
		TOXD AABB 2 Bright A_Chase
		TNT1 A 0 A_SpawnItem("HeavyFleshStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawnerFiend",0,0,0,0)
		TOXD CCDD 2 Bright A_Chase
		TNT1 A 0 A_SpawnItem("HeavyFleshStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawnerFiend",0,0,0,0)
		Loop 
	Melee: 
		TOXD EF 5 Bright A_FaceTarget
		TOXD G 4 Bright A_MeleeAttack
		TOXD E 5 Bright A_FaceTarget
		Goto See
	Missile:
		TNT1 A 0 A_Jump(128,"Lunge","ToxicBreath","ToxicSwirlBall")
	Normal:
		TOXD GE 10 Bright A_FaceTarget		
		TOXD F 8 Bright A_CustomMissile("ToxicComet",32,0,0)
		TOXD E 6 Bright
		Goto See
	ToxicSwirlBall:
		TOXD GE 10 Bright A_FaceTarget		
		TOXD F 8 Bright A_CustomMissile("ToxicSwirlComet",32,0,0)
		TOXD E 8 Bright
		Goto See
	Lunge:
		TNT1 A 0 A_JumpIfCloser(355,1)
		Goto See
		TNT1 A 0 A_PlaySound("magma/attack")
		TOXD EF 7 Bright A_FaceTarget
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
		TNT1 A 0 ThrustThingZ(0,25,0,1)
		TOXD F 2 Bright A_Recoil(-30)
		TOXD F 3 Bright A_CustomMissile("PinkyLunge",18,0,0,CMF_AIMDIRECTION)
		TOXD G 6 Bright
		TOXD G 2 Bright A_ScaleVelocity(0.2)
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		TOXD G 1 Bright A_ScaleVelocity(0)
		Goto See
	ToxicBreath:
		TNT1 A 0 A_JumpIfCloser(300,1)
		Goto See
		TOXD EF 5 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("hectebus/flameready")
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 A_PlaySound("Daedabus/Chem")
		TOXD FFF 2 Bright A_CustomMissile("ToxicChemSpray", 32, 0, Random(6,-6))
		TNT1 A 0 A_FaceTarget
		TOXD FFF 2 Bright A_CustomMissile("ToxicChemSpray", 32, 0, Random(6,-6))
		TNT1 A 0 A_FaceTarget
		TOXD FFF 2 Bright A_CustomMissile("ToxicChemSpray", 32, 0, Random(6,-6))
		TNT1 A 0 A_FaceTarget		
		TOXD FFF 2 Bright A_CustomMissile("ToxicChemSpray", 32, 0, Random(6,-6))
		TOXD E 5 Bright
		Goto See
	Pain: 
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		TOXD H 4 Bright A_Pain
		Goto See
	Death: 
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		TOXD I 5 
		TOXD J 5 A_Scream
		TOXD K 4
		TOXD L 4 A_NoBlocking     
		TOXD M 4 A_SpawnItem("BodyCrash",0,0,0,0)
		TOXD N 63000 CanRaise
		Stop
	XDeath:
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		TOXD I 3
		TOXG A 3 A_XScream
		TOXG B 3 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
		TOXG C 3 A_NoBlocking
		TOXG D 3 A_SpawnItem("BodyCrash",0,0,0,0)
		TNT1 AAAAAAAAAAAAAAAAAAAA 0 A_SpawnItemEx("ToxicFiendPoison",0,0,20,Random(8,-8),Random(8,-8),Random(6,-6))	 
		TOXG EFG 3
		TOXG H 63000 CanRaise
		Stop
	Raise: 
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TOXD NMLKJI 5 
		Goto See 
	}
}

ACTOR ToxicFiendPoison : BarbatosPoison
{ 
Species "Fiends"
DamageType "DTFiendEx"
States 
	{ 
	Spawn:
		TNT1 A 0
		TRPS ABCDEFGDFEGDF 3 A_Explode(2,68)
		Goto Death
	Death:
		TRPS CCBBAA 1 A_FadeOut(0.15,1)
		Stop 
	}
}

ACTOR ToxicComet : BarbatosComet
{
DamageType "DTFiendEx"
States
	{
	Spawn:
		BRTB AAABBB 1 Bright A_SpawnItemEx("BarbCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
		Loop
	Death:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("GreenParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
		TNT1 AAA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))
		TNT1 AAA 0 A_CustomMissile("Kaboom13", 0, 0, random(0,360), random(2,3), random(0,360))
		BRTB C 3 Bright A_Explode
		BRTB D 3 Bright A_SetTranslucent(0.75,1)
		TNT1 AAAAA 0 A_SpawnItemEx("ToxicFiendPoison",0,0,10,Random(4,-4),Random(4,-4),Random(4,-2))
		BRTB EFG 3 Bright
		Stop
	}
}

ACTOR ToxicSwirlComet : ToxicComet
{
Damage 8
ExplosionDamage 45
+SEEKERMISSILE
+NOBOSSRIP
+BLOODLESSIMPACT
States
	{
	Spawn:
		TNT1 A 0 A_SeekerMissile(16,0)
		TNT1 A 0 A_BishopMissileWeave
		BRTB A 1 Bright A_SpawnItemEx("BarbCometTail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		TNT1 A 0 A_BishopMissileWeave
		BRTB B 1 Bright A_SpawnItemEx("BarbCometTail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		Loop
	Death:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("GreenParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 A_CustomMissile("SmokeFX2",0,0,random(0,360),2,random(0,360))
		TNT1 AAA 0 A_CustomMissile("Kaboom13",0,0,random(0,360),2,random(0,360))
		BRTB C 3 Bright A_Explode
		BRTB D 3 Bright A_SetTranslucent(0.75,1)
		TNT1 AAAAA 0 A_SpawnItemEx("ToxicFiendPoison",0,0,10,Random(4,-4),Random(4,-4),Random(4,-2),0,SXF_SETMASTER,0)
		BRTB EFG 3 Bright
		Stop
	}
}

ACTOR ToxicChemSpray : DaedabusChemSpray
{ 
Species "Fiends"
DamageType "DTFiendEx"
States 
	{ 
	Spawn:
		TNT1 A 0
		TRPS ABCDEFGDFEG 3 A_Explode(2,68)
		Goto Death
	Death: 
		TRPS CCBBAA 1 A_FadeOut(0.15,1)
		Stop 
	} 
}

ACTOR GHellionSmokeSpawnerFiend : RedParticleSpawner
{
+CLIENTSIDEONLY
States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
		TNT1 AAA 0 A_SpawnItemEx("GHellionSmokeTx",random(12,-12),random(12,-12),random(12,64),0,0,random(1,3),0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		TNT1 A 1 Bright
		Stop
	Toaster:
		TNT1 A 1 Bright
		Stop		
	}
}

ACTOR GHellionSmokeTx : GHellionSmoke { Scale 0.3 }