ACTOR Demobus
{
Monster 
Health 1400
Height 64
Radius 48
Mass 1000
Speed 8
PainChance 40
+FLOORCLIP
+BOSSDEATH
+MISSILEMORE
+MISSILEEvenMORE
+QUICKTORETALIATE
+DONTHURTSPECIES
+DONTHARMSPECIES
+DONTHARMCLASS
Species "Fatsos"
DamageFactor "BeheComet", 0.0
DamageFactor "FatFlamer", 0.0
DropItem "BossLifeEssence", 128, 25
DropItem "BossArmorBonusMax", 128, 1
DropItem "DemonAmmoBox", 128, 200
DropItem "BFG10K ", 70, 1
SeeSound "monsters/volsee"
PainSound "monsters/volpain"
DeathSound "monsters/voldeath"
ActiveSound "manc/idle"
Obituary "%o was not expecting a visit from a Demobus."
Tag "Demobus"
States
	{
	Spawn:
		BFAT A 10 A_Look
		Loop
	See:
		TNT1 A 0 A_SpawnItem("BeefyStep",0,0,0,0)
		BFAT AABBCCDD 3 A_Chase
		TNT1 A 0 A_SpawnItem("BeefyStep",0,0,0,0)
		BFAT EEFF 3 A_Chase
		Loop
	Missile:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("weapons/charge15k")
		BFAT GGGG 5 A_FaceTarget    
		TNT1 A 0 A_FaceTarget 	   
		TNT1 A 0 Bright A_CustomMissile("DBusBFG15K",26,26,Random(6,-12),CMF_TRACKOWNER)
		BFAT H 8 Bright A_CustomMissile("DBusBFG15K",26,-26,Random(12,-6),CMF_TRACKOWNER)
		BFAT I 6 A_FaceTarget     
		BFAT G 6 A_FaceTarget   
		TNT1 A 0 Bright A_CustomMissile("DBusBFG15K",26,26,Random(6,-12),CMF_TRACKOWNER)
		BFAT H 8 Bright A_CustomMissile("DBusBFG15K",26,-26,Random(12,-6),CMF_TRACKOWNER)
		BFAT I 10 A_FaceTarget
		BFAT G 10 A_FaceTarget
		TNT1 A 0 Bright A_CustomMissile("DBusBFG15K",26,26,Random(-7,-13),CMF_TRACKOWNER)
		TNT1 A 0 Bright A_CustomMissile("DBusBFG15K",26,26,Random(0,-6),CMF_TRACKOWNER)
		TNT1 A 0 Bright A_CustomMissile("DBusBFG15K",26,-26,Random(0,6),CMF_TRACKOWNER)
		BFAT H 8 Bright A_CustomMissile("DBusBFG15K",26,-26,Random(7,13),CMF_TRACKOWNER)
		BFAT I 8
		Goto See
	Pain:
		TNT1 A 0
		BFAT J 6 A_Pain
		Goto See
	Death:
		TNT1 A 0
		BFAT K 6
		BFAT L 6 A_Scream
		TNT1 A 0 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		BFAT M 6 A_NoBlocking
		BFAT NOPQR 6
		TNT1 A 0 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		BFAT S 6
		BFAT T 63000 CanRaise A_KillMaster
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		BFAT SRQPONMLK 6
		Goto See
	}
}

ACTOR DBusBFG15K : BFG15KBall
{
FastSpeed 30
Scale 0.6
DamageType "BeheComet"
-THRUSPECIES
SeeSound "weapons/bfg15kfire"
States
	{
	Spawn:
		TNT1 AA 0 Bright A_SpawnItemEx("ProjectileTrailParticleOrange2",Random(-8,8),Random(-8,8),Random(-8,8),Random(-1,1),Random(-1,1),Random(-1,1),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		CFS1 A 4 Bright
		TNT1 AA 0 Bright A_SpawnItemEx("ProjectileTrailParticleOrange2",Random(-8,8),Random(-8,8),Random(-8,8),Random(-1,1),Random(-1,1),Random(-1,1),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		CFS1 B 4 Bright
		Loop
	Death:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_SpawnItemEx("RedParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 Bright A_CustomMissile("Kaboom14",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		CFE1 A 3 Bright A_Explode
		CFE1 BC 3 Bright
		CFE1 BA 3 Bright
		CFG9 ABCDEF 3 Bright
		Stop
	}
}