ACTOR BabyBFGMastermind : Arachnotron 23399
{
Health 1500
Radius 52
Speed 13
Scale 1.2
PainChance 70
+MISSILEMORE
Species "BabySpiders"
DamageFactor "Baby15K", 0.0
DropItem "LifeEssence", 140
DropItem "ArmorBonusMax", 140
DropItem "NewCellPack", 140
DropItem "Railgun ", 96
SeeSound "minidemo/sight"
ActiveSound "minidemo/active"
AttackSound ""
PainSound "monsters/fusionitepain"
DeathSound "minidemo/death"
Obituary "%o was vaporized by a baby bfg mastermind's plasma."
Tag "\c[z2]Baby BFG Mastermind"
States
	{
	Spawn:
		BABM A 10 A_Look
		Loop
	See:
		BABM A 2 A_BabyMetal
		BABM ABBCC 2 A_Chase
		BABM D 2 A_BabyMetal
		BABM DEEFF 2 A_Chase
		Loop
	Missile:
		TNT1 A 0 A_Jump(82,"BFG15K","BFG10K")
	Normal: 
		TNT1 A 0 A_PlaySound("weapons/rgcharge")
		BABM G 10 A_FaceTarget
		BABM G 5 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabySpiderRail",20,0,0) 
		BABM G 20 Bright A_FaceTarget	
		TNT1 A 0 A_Jump(20,"BFG15K","BFG10K")
		Goto Missile
	BFG10K:
		TNT1 A 0 Bright A_PlaySound("weapons/charge15k")
		BABM G 18 Bright A_FaceTarget
		BABM G 6 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabyBFGM10K",20,0,Random(4,-4)) 
		BABM G 6 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabyBFGM10K",20,0,Random(4,-4)) 
		BABM G 6 Bright A_FaceTarget	
		BABM H 4 Bright A_CustomMissile("BabyBFGM10K",20,0,Random(4,-4)) 	
		BABM G 6 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabyBFGM10K",20,0,Random(4,-4)) 
		BABM G 6 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabyBFGM10K",20,0,Random(4,-4)) 
		BABM G 6 Bright A_FaceTarget	
		BABM H 4 Bright A_CustomMissile("BabyBFGM10K",20,0,Random(4,-4)) 
		BABM G 20 Bright A_PlaySound("weapons/bfg15kcooldown",CHAN_AUTO)
		Goto See
	BFG15K:
		TNT1 A 0 Bright A_PlaySound("weapons/charge15k")
		BABM G 18 Bright A_FaceTarget
		BABM G 6 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabyDemo15K",20,0,Random(4,-4)) 
		BABM G 6 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabyDemo15K",20,0,Random(4,-4)) 
		BABM G 6 Bright A_FaceTarget	
		BABM H 4 Bright A_CustomMissile("BabyDemo15K",20,0,Random(4,-4)) 	
		BABM G 6 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabyDemo15K",20,0,Random(4,-4)) 
		BABM G 6 Bright A_FaceTarget
		BABM H 4 Bright A_CustomMissile("BabyDemo15K",20,0,Random(4,-4)) 
		BABM G 6 Bright A_FaceTarget	
		BABM H 4 Bright A_CustomMissile("BabyDemo15K",20,0,Random(4,-4)) 
		BABM G 20 Bright A_PlaySound("weapons/bfg15kcooldown",CHAN_AUTO)
		Goto See
	Pain:
		TNT1 A 0 A_Jump(87,"PainMissile")
		BABM I 12 A_Pain
		Goto See
	PainMissile:
		BABM I 12 A_Pain
		Goto Missile
	XDeath:
	Death:
		TNT1 A 0
		BABM I 20 A_Scream
		BABM J 6
		TNT1 AAA 0 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		BABM KKKKK 2 Bright A_CustomMissile("Kaboom5", random(20,40), random(10,-10), random(0,360), 2, random(0,360))
		TNT1 AAAA 0 A_CustomMissile("SmokeFX2", random(20,40), 0, random(0,360), 2, random(0,360))
		BABM L 6 A_NoBlocking
		BABM MN 6
		BABM O 6
		TNT1 A 0 A_KillMaster
		BABM P 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		BABM PONMLKJ 5
		Goto See+1
	}
}

ACTOR BabyBFGM10K : DarkDemo10k
{
DamageType "Baby15K"
Species "BabySpiders"
States
	{
	Death:
	XDeath:  
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("BabyBFGM10KEx",0,0,0,0,0,0,0,SXF_SETMASTER,0)
		Stop
	}
}

ACTOR BabyBFGM10KEx : Player10KEx
{
Height 8
Radius 11
Scale 0.85
Renderstyle Add
Alpha 0.75
Decal BFG15KLightning
+NOBLOCKMAP
+NOGRAVITY
+NOTELEPORT 
+FORCERADIUSDMG
Species "BabySpiders"
DamageType "Baby15K"
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 A_SpawnItemEx("BFGShockwave",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AA 0 A_SpawnItemEx("GreenParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAAA 0 A_CustomMissile("Kaboom13",0,0,random(0,360),2,random(0,360))
		BFE1 A 4 Bright A_Detonate
		BFE1 BCDEF 4 Bright
		Stop
	}
}

ACTOR BabySpiderRail : FastProjectile
{
Height 5
Radius 5
Speed 300
Scale 1.15
Decal BFG9500Lightning
MissileType "DarkCyberRailTrail"
Damage (Random(40,60))
+RIPPER
+THRUSPECIES
+BLOODLESSIMPACT
Species "BabySpiders"
DamageFactor "Baby15K", 0.0
SeeSound "monsters/darkcyberrail"
DeathSound "cyberrail/impact"
States
	{
	Spawn:
		DCRP A 1 Bright
		Loop
	Death:
		TNT1 A 0 Bright
		TNT1 A 0 A_SpawnItemEx("BFGShockwave",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAAA 0 A_CustomMissile("Kaboom13",0,0,random(0,360),2,random(0,360))
		TNT1 A 1 A_SpawnItem("RailgunImpactEffectGreen")
		Stop
	}
}

Actor CBabyBFGMastermind : BabyBFGMastermind
{
+NOEXTREMEDEATH
+NOTARGET
+NOINFIGHTING
+DONTHURTSPECIES
+DONTHARMSPECIES
+DONTHARMCLASS
Species ""
Species "Masterminds"
DamageFactor "Commander", 0.0
DamageFactor "DemolisherEx", 0.0
DamageFactor "DarkDemoEx", 0.0
DamageFactor "CerChainguns", 0.0	
DamageFactor "CerEnergyBall", 0.0
DamageFactor "Baby15K", 0.0
DropItem ""
Tag "\c[z2]Baby BFG Mastermind"
States
	{
	XDeath:
	Death:
		TNT1 A 0
		BABM I 20 A_Scream
		BABM J 6
		TNT1 AAA 0 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		BABM KKKKK 2 Bright A_CustomMissile("Kaboom5", random(20,40), random(10,-10), random(0,360), 2, random(0,360))
		TNT1 AAAA 0 A_CustomMissile("SmokeFX2", random(20,40), 0, random(0,360), 2, random(0,360))
		BABM L 6 A_NoBlocking
		BABM MN 6
		BABM O 6
		BABM P 525
		BABM P 5 A_FadeOut(0.1,1)
		Wait
	}
}