ACTOR ChaingunFiend : BullFiend 6005
{ 
Monster
Health 275
Speed 13
Damage 5
PainChance 70
Scale 1.15
+QUICKTORETALIATE
-FASTMELEE
+FLOORCLIP
+MissileMore
Species "Fiends"
DamageFactor "FiendFire", 0.0
DamageFactor "DTFiendEx", 0.0
DropItem "LifeEssence", 125
DropItem "ArmorBonusMax", 125
DropItem "Minigun ", 100
DropItem "HealthFlask", 55
DropItem "ArmorCharge", 55
DropItem "AmmoPack", 40
SeeSound "blooddemon/sight"
PainSound "blooddemon/pain"
DeathSound "blooddemon/death"
ActiveSound "blooddemon/active"
Attacksound "doublecger/fire"
Obituary "%o was mowed down by a Chaigun Fiend." 
States 
	{ 
	Spawn: 
		CRG2 A 12 A_Look
		Loop 
	See: 
		TNT1 A 0 A_PlaySound("blooddemon/walk")
		CRG2 AABB 2 A_Chase
		TNT1 A 0 A_PlaySound("blooddemon/walk")
		CRG2 CCDD 2 A_Chase
		Loop 
	Missile:
		TNT1 A 0
		TNT1 A 0 A_Jump(170,"Chaingun")
		TNT1 A 0 A_JumpIfCloser(250,"Lunge")
		Goto see
	Chaingun:
		CRG2 EEEEEEEEEE 1 A_FaceTarget(45)
	ChaingunLoop:
		TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(5,-5),0)
		CRG2 E 3 Bright A_CustomBulletAttack(22.5,0,1,random(1,5)*5,"FiendBulletPuff",0,CBAF_NORANDOM)
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(5,-5),0)
		CRG2 F 4 Bright A_CustomBulletAttack(22.5,0,1,random(1,5)*5,"FiendBulletPuff",0,CBAF_NORANDOM)
		TNT1 A 0 A_SpidRefire
		Loop
	Melee:
	Lunge:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("cyberfiend/melee")
		CRG2 AA 7 A_FaceTarget
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
		TNT1 A 0 ThrustThingZ(0,20,0,1)
		CRG2 B 2 A_Recoil(-28)
		CRG2 B 3 A_CustomMissile("PinkyLunge",18,0,0,CMF_AIMDIRECTION)
		CRG2 B 6
		CRG2 B 2 A_ScaleVelocity(0.2)
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		CRG2 B 1 A_ScaleVelocity(0)
		Goto See
	Pain:
		TNT1 A 0
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		CRG2 H 2
		CRG2 H 2 A_Pain
		Goto See
	Death:
		TNT1 A 0
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		SRG2 I 5 
		SRG2 J 5 A_Scream   
		TNT1 AA 0 A_CustomMissile("RedBloodCloud", random(30,60),0,random(0,360),2,random(0,360))
		SRG2 K 4 A_SpawnItemEx("BloodDemonArm",10,0,32,0,Random(6,8),0,0,128)
		SRG2 L 4 A_NoBlocking     
		SRG2 M 4 A_SpawnItem("BodyCrash",0,0,0,0)
		SRG2 N 63000 CanRaise
		Stop 
	XDeath:
		TNT1 A 0
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		CYFN I 3
		CYFX A 3 A_XScream
		CYFX B 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		CYFX C 3 A_NoBlocking
		CYFX D 3 A_SpawnItem("BodyCrash",0,0,0,0)
		CYFX EFG 3
		CYFX H 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		SRG2 NMLKJI 5 
		Goto See 
	} 
}

Actor FiendBulletPuff : ModdedBulletPuff { DamageType "DTFiendEx" }

ACTOR BloodDemonArm
{
Radius 8
Height 8
Speed 8
+DOOMBOUNCE
+DROPOFF
+Missile
States
	{
	Spawn:
		SG2A ABCDEFGH 2
		Loop
	Death:
		SG2A I 2100
		Stop
	}
}