ACTOR EMinigunner 
{
Monster
Health 140
Height 56 
Radius 20 
Speed 6
Mass 150
PainChance 60
+FLOORCLIP 
+MISSILEMORE
+QUICKTORETALIATE
DamageFactor "ZombieEx", 0.0
DropItem "StimKit", 80
DropItem "ArmorBooster", 80
DropItem "AmmoPack", 65
DropItem "HandGrenadeAmmo", 150, 1
DropItem "MineAmmo", 75, 1
DropItem "BulletMag", 256, 10
DropItem "Explosive Minigun", 90, 1
SeeSound "superzombie/sight"
PainSound "superzombie/pain"
DeathSound "superzombie/death"
ActiveSound "superzombie/active"
Tag "Explosive Minigunner"
Obituary "%o do not expect a zombie would have that type of weapon."
States
	{
	Spawn:
		EMNG AZ 10 A_Look
		Loop
	See:
        EMNG AABB 2 A_Chase
        TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
        EMNG CCDD 2 A_Chase
        TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
		Loop
    Missile:
		TNT1 A 0
        TNT1 A 0 A_PlaySound("weapons/expmgunspinstart")
        EMNG EEEEEEEEEEEEEEE 1 A_FaceTarget
	MissileLoop:
	    TNT1 A 0 A_PlaySoundEx("weapons/expmgunspin","Voice")
		TNT1 A 0 A_PlaySound("sentient/fire")
	    EMNG E 4 Bright A_CustomMissile("ZombieExplosiveTracer",Random(30,34),0,Random(5,-5),0)
        TNT1 A 0 Bright A_SpawnItemEx("OrangeShellCasing",12,6,28,Random(2,6),0,Random(1,3),Random(-80,-90),128)
		TNT1 A 0 A_PlaySound("sentient/fire")
	    EMNG F 4 Bright A_CustomMissile("ZombieExplosiveTracer",Random(30,34),0,Random(5,-5),0)
        TNT1 A 0 Bright A_SpawnItemEx("OrangeShellCasing",12,6,30,Random(2,6),0,Random(1,3),Random(-80,-90),128)
		TNT1 A 0 A_StopSoundEx("Weapon")
		TNT1 A 0 A_Jump(4,"See")
        TNT1 A 0 A_CPosRefire
        Loop
	Pain:
		TNT1 A 0
		EMNG G 5 A_Pain
		Goto See
	XDeath:
	Death:
        EMNG H 5
        EMNG I 5 A_Scream
        EMNG J 5 A_Fall
        EMNG KLM 5 A_SpawnItem("BodyCrash",0,0,0,0)
		EMNG N 63000 CanRaise
        Stop
	}
}

ACTOR ZombieExplosiveTracer : SentientExplosiveTracer
{
Scale 0.4
DamageType "ZombieEx"
States
	{
	Spawn:
		TRAC A 1 Bright
		Loop
	Death:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_SetTranslucent(0.75,1)
		TNT1 A 0 Bright A_SpawnItem("SentientExplosiveEffect")
		MISL B 4 Bright A_Explode(Random(3,6)*5,72)
		MISL CD 3 Bright
		Stop
	}
}