ACTOR ToxicLord 28528
{
Monster
Health 1125
Height 64
Radius 24
Mass 1000
Speed 8
Scale 1.15
BloodColor "Green"
PainChance 45
PainChance "Explosion", 60
PainChance "Poison", 0
PainChance "PoisonCloud", 0
MeleeDamage 15
-BOSSDEATH
+FLOORCLIP
+FASTMELEE
+MISSILEMORE
+QUICKTORETALIATE
Species "Nobles"
DamageFactor "NobleComet", 0.0
Damagefactor "Poison", 0.001
Damagefactor "PoisonCloud", 0.001
DropItem "BossLifeEssence", 128
DropItem "BossArmorBonusMax", 128
DropItem "DemonAmmoBox", 128, 200
SeeSound "TLord/See"
MeleeSound "baron/melee"
PainSound "TLord/Pain"
DeathSound "TLord/Death"
Obituary "%o was disintegrated by the toxins of the Toxic Lord."
HitObituary "%o received a sweet hug from the Toxic Lord."
Tag "\cdToxic Lord\c-"
States 
	{
	Spawn:
		TNT1 A 0 A_SpawnItemEx("GHellionSmokeSpawner4",0,0,0,0,0,0,0,SXF_CLIENTSIDE)
		TLOD A 7 Bright A_Look
		TNT1 A 0 A_SpawnItemEx("GHellionSmokeSpawner4",0,0,0,0,0,0,0,SXF_CLIENTSIDE)
		TLOD A 7 Bright A_Look
		TNT1 A 0 A_SpawnItemEx("GHellionSmokeSpawner4",0,0,0,0,0,0,0,SXF_CLIENTSIDE)
		TLOI A 7 Bright A_Look
		TNT1 A 0 A_SpawnItemEx("GHellionSmokeSpawner4",0,0,0,0,0,0,0,SXF_CLIENTSIDE)
		TLOI A 7 Bright A_Look
		Loop
	See:
		TNT1 A 0 A_SpawnItemEx("GHellionSmokeSpawner4",0,0,0,0,0,0,0,SXF_CLIENTSIDE)
		TLOD AA 3 Bright A_Chase
		TNT1 A 0 A_SpawnItemEx("GHellionSmokeSpawner4",0,0,0,0,0,0,0,SXF_CLIENTSIDE)
		TLOD BB 3 Bright A_Chase
		TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
		TNT1 A 0 A_SpawnItemEx("GHellionSmokeSpawner4",0,0,0,0,0,0,0,SXF_CLIENTSIDE)
		TLOD CC 3 Bright A_Chase
		TNT1 A 0 A_SpawnItemEx("GHellionSmokeSpawner4",0,0,0,0,0,0,0,SXF_CLIENTSIDE)
		TLOD DD 3 Bright A_Chase
		TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
		Loop
	Missile:
		TNT1 A 0
		TNT1 A 0 Bright A_Jump(128,"GiantBalls","BurstComet")
		Goto Normal
	Normal:
        TLOD EF 6 Bright A_FaceTarget 
		TLOD G 1 Bright A_CustomMissile("PoisonBall",42,0,0,CMF_TRACKOWNER)
		TNT1 A 0 Bright A_CustomMissile("PoisonBall",42,0,-6,CMF_TRACKOWNER)
		TLOD G 4 Bright A_CustomMissile("PoisonBall",42,0,6,CMF_TRACKOWNER)
        TLOD IJ 6 Bright A_FaceTarget
		TLOD K 1 Bright A_CustomMissile("PoisonBall",42,0,0,CMF_TRACKOWNER)
		TNT1 A 0 Bright A_CustomMissile("PoisonBall",42,0,-6,CMF_TRACKOWNER)
		TLOD K 4 Bright A_CustomMissile("PoisonBall",42,0,6,CMF_TRACKOWNER)
		TNT1 A 0 A_Jump(87,"GiantBalls","BurstComet")
        Goto See
	GiantBalls:
		TLOD EF 7 Bright A_FaceTarget
		TLOD G 6 Bright A_CustomMissile("DukeBall2",32,0,0,CMF_TRACKOWNER)
		TLOD IJ 7 Bright A_FaceTarget
		TLOD K 6 Bright A_CustomMissile("DukeBall2",32,0,0,CMF_TRACKOWNER)
		TNT1 A 0 A_Jump(87,"BurstComet")
		Goto See
	BurstComet:
        TLO2 AB 8 Bright A_FaceTarget
        TLO2 C 2 Bright A_Custommissile("TLordComet",32,0,0,CMF_TRACKOWNER)
		TNT1 A 0 Bright A_Custommissile("TLordComet",32,0,-10,CMF_TRACKOWNER)
		TLO2 C 5 Bright A_Custommissile("TLordComet",32,0,10,CMF_TRACKOWNER)
        Goto See
	Melee:
		TLO2 AB 7 Bright A_FaceTarget
		TLO2 C 6 Bright A_MeleeAttack
		Goto See
	Pain:
		TNT1 A 0
		TNT1 A 0 A_Jump(80,"PainMissile")
		TLOD N 4 Bright A_Pain
		Goto See
	PainMissile:
		TLOD N 10 Bright A_Pain
        Goto Missile
    XDeath:
    Death:
		TNT1 A 0
		TLOD O 7
		TLOD P 6 A_Scream
		TLOD Q 5 A_Fall
		TLOD R 4 A_SpawnItem("BodyCrash",0,0,0,0)
		TLOD ST 4 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
		TLOD U 63000 CanRaise A_KillMaster
	    Stop
	Raise:
	    TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TLOD UTSRQPO 6
        Goto See 
        } 
}
actor PoisonBall : CStaffMissile
{
PROJECTILE
Height 12
Radius 8
Speed 18
FastSpeed 22
Renderstyle Add
Alpha 0.90
PoisonDamage 15
damage 7
+EXPLODEONWATER
Damagetype "Poison"
SeeSound "monsters/newfireshoot"
DeathSound "monsters/newfireexplode"
States
	{
	Spawn:
		FVN1 A 1 Bright A_BishopMissileWeave
		TNT1 A 0 Bright A_SpawnItemEx("PoisonTrail",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,10)
		FVN1 B 1 Bright A_BishopMissileWeave
		TNT1 A 0 Bright A_SpawnItemEx("PoisonTrail",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,10)
		FVN1 C 1 Bright A_BishopMissileWeave
		TNT1 A 0 Bright A_SpawnItemEx("PoisonTrail",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,10)
		FVN1 D 1 Bright A_BishopMissileWeave
		TNT1 A 0 Bright A_SpawnItemEx("PoisonTrail",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,10)
		Loop
	Death:
		TNT1 A 0 Bright
		FVN1 EFGHIJ 3 Bright
		Stop
	Crash:
	XDeath:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_SpawnItemEx("GreenParticleSpawner",0,0,0,0,0,0,0,128)
		TNT1 AAA 0 Bright A_CustomMissile("Kaboom7",0,0,random(0,360),2,random(0,360))
		TNT1 AAA 0 Bright A_CustomMissile("SmokeFX4",0,0,random(0,360),2,random(0,360))
		FVN1 EFGHIJ 3 Bright
		Stop
	}
}

ACTOR Poisontrail
{   
PROJECTILE
Height 1
Radius 0
RENDERSTYLE ADD
ALPHA 0.80
+NOINTERACTION
States
	{
	Spawn:
		TNT1 A 1 Bright
		SSFX ABCDEFG 2 Bright
		Stop 
	}
}

ACTOR TLordComet : Comet
{
Damage 6
ExplosionDamage 42
DamageType "NobleComet"
MissileType ""
DeathSound "barbcomet/explosion"
States
	{
	Spawn:
		BRTB AAABBB 1 Bright A_SpawnItemEx("BarbCometTail",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		Loop
	Death:
		TNT1 A 0 Bright
		BRTB C 3 Bright A_Explode
		BRTB D 3 Bright A_SetTranslucent(0.75,1)
		TNT1 AAAAA 0 Bright A_SpawnItemEx("TLordPoison",0,0,10,Random(4,-4),Random(4,-4),Random(4,-2))
		BRTB EFG 3 Bright
		Stop
	Crash:
	XDeath:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_SpawnItemEx("GreenParticleSpawner",0,0,0,0,0,0,0,128)
		TNT1 AAA 0 Bright A_CustomMissile("SmokeFX2",0,0,random(0,360),2,random(0,360))
		TNT1 AAA 0 Bright A_CustomMissile("Kaboom13",0,0,random(0,360),random(2,3),random(0,360))
		BRTB C 3 Bright A_Explode
		BRTB D 3 Bright A_SetTranslucent(0.75,1)
		TNT1 AAAAA 0 Bright A_SpawnItemEx("TLordPoison",0,0,10,Random(4,-4),Random(4,-4),Random(4,-2))
		BRTB EFG 3 Bright
		Stop
	}
}

ACTOR GHellionSmokeSpawner4 : RedParticleSpawner
{
+NOINTERACTION
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
		TNT1 A 0 Bright A_CheckSight("Toaster")
		TNT1 AAA 0 Bright A_SpawnItemEx("GHellionSmoke4",random(12,-12),random(12,-12),random(12,64),0,0,random(1,3),0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE,0)
		TNT1 A 1 Bright
		Stop
	Toaster:
		TNT1 A 1 Bright
		Stop
	}
}

ACTOR GHellionSmoke4 : GHellionSmoke
{
Scale 0.6
+NONETID
}

Actor TLordPoison : BarbatosPoison { DamageType "NobleComet" }