ACTOR DarkCybernoble : CyberNoble
{ 
Health 1600
PainChance 50
Scale 1.15
Obituary "%o was turned into a mass of particles and dust by a Dark Cyber-noble."
HitObituary "%o was pummeled by a Dark Cyber-noble."
SeeSound "monster/brusit" 
PainSound "cbaron/pain"
DeathSound "cbaron/death"
MeleeSound "baron/melee"
ActiveSound "cbaron/active"
DropItem "LifeEssence" 150
DropItem "ArmorBonusMax" 150
DropItem "Assault Shotgun" 128
Species "Nobles"
  States 
  { 
  Spawn: 
    CBO3 A 7 A_Look
    Loop 
  See:
    CBO3 AABB 3 A_Chase
    TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
    CBO3 CCDD 3 A_Chase
    TNT1 A 0 A_Playsound("monster/bruwlk")
    Loop
  Pause:
	CBO3 E 10
	Goto See
  Missile:
    TNT1 A 0 A_Jump(128,"BurstBall","LargeBall","Rocket")
  Normal:
    CBO3 E 8 A_FaceTarget
	CBO3 E 6 A_FaceTarget
	TNT1 A 0 A_SpawnItemEx("ShellCasing", 0, 12, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
	TNT1 AAA 0 A_CustomMissile("ProjectileBullet",40,0,Random(-1000,1000)/100.00,0)
	TNT1 A 0 A_CustomBulletAttack(22.5, 18.3, 4, Random(1,5)*3, "CyNoblePuff")
	CBO3 F 2 Bright A_PlaySoundEx("AShotgun/Fire","Weapon")
    TNT1 A 0 A_Jump(48,"Pause")
    TNT1 A 0 A_SpidRefire
	Goto Normal+2
  BurstBall:
	CBO3 PQ 7 A_FaceTarget 
	CBO3 R 1 Bright A_CustomMissile("CyNobleBall", 32, 0, 0)		
	TNT1 A 0 A_CustomMissile("CyNobleBall", 32, 0, 6)
	CBO3 R 5 Bright A_CustomMissile("CyNobleBall", 32, 0, -6)
	TNT1 A 0 A_Jump(87,"LargeBall","Rocket")
	Goto See
  LargeBall:
  	CBO3 PQ 7 A_FaceTarget
	CBO3 R 6 Bright A_CustomMissile("DukeBall2", 32, 0, 0)
  Rocket:
    TNT1 A 0 A_Jump(128,"Missiles")
    CBO3 E 14 A_FaceTarget
    CBO3 F 8 Bright A_CustomMissile("CyNobleRocket",32,0,0,0)
    CBO3 E 10 A_FaceTarget
    CBO3 F 8 Bright A_CustomMissile("CyNobleRocket",32,0,0,0)
    CBO3 E 10 A_FaceTarget
    CBO3 F 8 Bright A_CustomMissile("CyNobleRocket",32,0,0,0)
    CBO3 E 10
    Goto See
  Missiles:
    CBO3 E 14 A_FaceTarget
    CBO3 F 8 Bright A_CustomMissile("BruiserMissile",32,0,0,0)
    CBO3 E 10 A_FaceTarget
    CBO3 F 8 Bright A_CustomMissile("BruiserMissile",32,0,0,0)
    CBO3 E 10 A_FaceTarget
    CBO3 F 8 Bright A_CustomMissile("BruiserMissile",32,0,0,0)
    CBO3 E 10
    Goto See
  Melee:
    CBO3 PQ 7 A_FaceTarget
    CBO3 R 7 A_MeleeAttack
    Goto See
  Pain: 
    TNT1 A 0 A_Jump(87,"PainMissile")
    CBO3 H 4 A_Pain
    Goto See
  PainMissile:
    CBO3 H 4 A_Pain
    Goto Missile	
  Death:
    CBO3 I 20 A_Scream
	TNT1 AA 0 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)	
	CBO3 JJJKKK 2 Bright A_CustomMissile ("Kaboom5", Random(10,50), 0, random(0,360), 2, random(0,360))
	TNT1 AA 0 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
    TNT1 AAAA 0 A_CustomMissile("SmokeFX", Random(30,60), 0, random(0,360), 2, random(0,360))	
    CBO3 L 4 Bright A_NoBlocking
    CBO3 MN 3 Bright
    CBO3 O -1
    Stop
  Raise:
  	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    CBO3 N 5
	CBO3 MLKJI 5
	Goto See
    } 
}
