Actor Mancutank : Fatso
{
  Health 1700
  Mass 2000
  Speed 12
  Scale 1.1
  PainChance 20
  +NORADIUSDMG
  SeeSound "MancuTank/sight"
  PainSound "MancuTank/pain"
  DeathSound "MancuTank/death"
  ActiveSound "MancuTank/active"
  DropItem "BossLifeEssence" 128 25
  DropItem "BossArmorBonusMax" 128 1
  DropItem "MissileBox" 128 20
  DropItem "BulletBox" 128 20
  DropItem "Explosive Minigun" 128 1
  Obituary "%o was wrecked by a Mancutank."
	States
	{
  Spawn:
	TNT1 A 0 A_PlaySound("Mancutank/Tank",7,1,True)
	BS1W AC 10 A_Look
	Loop
  See:
	TNT1 A 0 A_PlaySound("Mancutank/Tank",7,1,True)
	BS1W ABCD 3 A_Chase
    Goto See+1
  Missile:
    TNT1 A 0 A_Jump(256, "Chainguns", "Missiles")
  Chainguns:
	BS1T AAAA 4 A_FaceTarget
	TNT1 A 0 A_PlaySoundEx("weapons/expmgunspin",7)
	TNT1 A 0 A_PlaySound("sentient/fire")
	BS1T B 0 A_CustomMissile("MancutankExplosiveTracer", 53, -36, Random(5,-5))
	BS1T B 2 Bright A_CustomMissile("MancutankExplosiveTracer", 53, 36, Random(5,-5))
	BS1T A 4 
	TNT1 A 0 A_SpidRefire
	Goto Chainguns+4
  Missiles:
	BS1T AAAA 4 A_FaceTarget
	BS1T C 0 A_CustomMissile("MancutankRocket", 71, -49, 0)
	BS1T C 4 A_CustomMissile("MancutankRocket", 71, 49, 0)
	BS1T A 8 A_Facetarget
	BS1T D 0 A_CustomMissile("MancutankRocket", 64, -49, 0)
	BS1T D 4 A_CustomMissile("MancutankRocket", 64, 49, 0)
	BS1T A 8 A_Facetarget
	BS1T E 0 A_CustomMissile("MancutankRocket", 53, -49, 0)
	BS1T E 4 A_CustomMissile("MancutankRocket", 53, 49, 0)
	Goto See
  Pain:
	BS1W A 3
	BS1W A 3 A_Pain
	Goto See
  Death:
    TNT1 A 0 A_StopSound(7)
	BS1B A 6
	BS1B B 6 A_Scream
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator",Random(10,-10),Random(10,-10),Random(20,60),0,0,0,0,128,0)
	TNT1 AA 0 A_CustomMissile("BigRedBloodCloud", random(10,80), 0, random(0,360), 2, random(0,360))
	BS1B CCCCDDDD 3 Bright A_SpawnItemEx("Kaboom",random(60,-60),random(60,-60),random(20,70),0,0,0,0,32)
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator",Random(10,-10),Random(10,-10),Random(20,60),0,0,0,0,128,0)
	TNT1 AA 0 A_CustomMissile("BigRedBloodCloud", random(10,80), 0, random(0,360), 2, random(0,360))
	BS1B EEEEFFFFGGGG 3 Bright A_SpawnItemEx("Kaboom",random(60,-60),random(60,-60),random(20,70),0,0,0,0,32)
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator",Random(10,-10),Random(10,-10),Random(20,60),0,0,0,0,128,0)
	TNT1 AA 0 A_CustomMissile("BigRedBloodCloud", random(10,80), 0, random(0,360), 2, random(0,360))
	BS1B HHHIII 3 Bright A_SpawnItemEx("Kaboom",random(60,-60),random(60,-60),random(20,70),0,0,0,0,32)
	BS1B JK 6 A_NoBlocking
	BS1B L -1
	Stop
	}
}


ACTOR MancutankRocket : NewRocket
{
Speed 23
Damage 20
FastSpeed 28
-THRUSPECIES
}


ACTOR MancutankExplosiveTracer : SentientExplosiveTracer
{
Scale 0.4
States
{
Spawn:
    TRAC A 1 Bright
	Loop
Death:
	TNT1 A 0
	TNT1 A 0 A_SetTranslucent(0.75,1)
	TNT1 A 0 A_SpawnItem("SentientExplosiveEffect")
    MISL B 4 Bright A_Explode(Random(3,6)*5,72)
    MISL CD 3 Bright
    Stop
    }
}