ACTOR Succubus : Imp 21027
{
    Health 370
    PainChance 80
    Obituary "%o met a magical demise after an encounter with a Succubus."
    HitObituary "%o felt a deep burn."
	BloodColor "Red"
	DamageFactor 0.8
	SeeSound "superimp/sight"
	PainSound "voidimp/pain"
	DeathSound "superimp/death"
	ActiveSound "superimp/active"
	DropItem "LifeEssence" 75
	DropItem "ArmorBonusMax" 75
    States
    {
    Spawn:
        SUC1 A 10 A_Look
		SUC1 A 10 A_Look
        Loop
    See:
		SUC1 AABB 3 A_Chase
		TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("FPESmokeSpawner",0,0,0,0)	
		SUC1 CCDD 3 A_Chase
		TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("FPESmokeSpawner",0,0,0,0)
		TNT1 A 0 A_Jump(64,"Teleport")
        Loop
    Missile:
		SUC1 EE 8 A_FaceTarget
		SUC1 F 1 Bright A_FaceTarget
		TNT1 A 0 Bright A_PlaySound("imp/attack")
        SUC1 F 1 Bright A_CustomMissile ("AvaFireBall",56,0,Random(-3,3),0,0)
        SUC1 F 1 Bright A_CustomMissile ("AvaFireBall",56,0,Random(-3,3),-5,0)
        SUC1 F 1 Bright A_CustomMissile ("AvaFireBall",56,0,Random(-3,3),5,0)
		SUC1 FE 6
		SUC1 E 1 A_SpidRefire
        Goto See
	Teleport:
		SUC1 A 1 Bright A_UnSetShootable
		SUC1 AA 4 A_FaceTarget
		SUC1 AA 1  A_FadeOut(0.1,0)
		SUC1 A 2 
		SUC1 AAAAAAAABBBBBBBBCCCCCCCCDDDDDDDD 0 A_Wander
		SUC1 AAAAAAAABBBBBBBBCCCCCCCCDDDDDDDD 0 A_Wander
		SUC1 A 1 A_PlayWeaponSound("boss/teleport")
		SUC1 AA 1 A_FadeIn(0.1)
		SUC1 AA 4 A_FaceTarget
		SUC1 A 1 Bright A_SetShootable		
		Goto See
    Pain:
        SUC1 G 4 A_Pain
        Goto See
    Death:
		SUC1 H 5
		SUC1 I 5 A_Scream
		SUC1 J 5
		SUC1 K 5 A_Fall
        SUC1 L 0 A_SpawnItem("BodyCrash",0,0,0,0)
        SUC1 M 1
		SUC1 N -1
    XDeath:
		SUC1 P 3 
		SUC1 Q 3 A_XScream
		SUC1 R 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		SUC1 S 3 A_Fall
		SUC1 TUV 3
		SUC1 W -1
        Stop
    Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
        SUC1 NMLJIH 5
        Goto See
		}
}

