Actor Aracknight
{
Monster
Health 1200
Height 64
Radius 52
Mass 600
Speed 8
Bloodcolor Blue
Painchance 21
+FLOORCLIP
+BOSSDEATH
+NoTarget
+AvoidMelee
+MISSILEMORE
+MissileEvenMore
+QuickToRetaliate
+DontHurtSpecies
+DontHarmSpecies
+DontHarmClass
Species "BabySpiders"
Damagefactor "Acid", 0.6
DamageFactor "BeheComet", 0.0
DamageFactor "FatFlamer", 0.0
Damagefactor "DTRPlayer", 0.5
//No Infighting
Damagefactor "BabySpiders", 0.0
Damagefactor "SatanGuard", 0.0
Damagefactor "CurseComet", 0.0
DamageFactor "Baby15K", 0.0
DropItem "BossLifeEssence", 196, 50
DropItem "BossLifeEssence", 196, 50
DropItem "HEMBossArmorBonusMax35", 196
Seesound "arakn/sight"
Activesound "arakn/active"
Painsound "arakn/fusionitepain"
Deathsound "arakn/death"
Obituary "%o was hunted down by an Aracknight."
Tag "Aracknight"
States
	{
	Spawn:
		ARAK A 10 A_Look
		Loop
	See:
		ARAK A 1 A_BabyMetal
		ARAK AABBBCCC 1 A_Chase
		ARAK D 1 A_BabyMetal
		ARAK DDEEEFFF 1 A_Chase
		Goto See
	Missile:
		TNT1 A 0
		TNT1 A 0 A_Jump(80,"MiniComets","CerebralDrain","BouncerGroundshot")
	Normal:
		ARAK A 0 A_PlaySound("arakn/charge",0,2.0,0)
		ARAK AAAAAAAAAA 1 A_FaceTarget
	NLoop:
		ARAK GGGG 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArackBall",30,0,random(-13,13),0)
		ARAK HHHH 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArackBall",30,0,random(-13,13),0)
		ARAK GGGG 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArackBall",30,0,random(-13,13),0)
		ARAK HHHH 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArackBall",30,0,random(-13,13),0)
		TNT1 A 0 A_SpidRefire
		Loop
	MiniComets:
		ARAK AAAAAAAAAAAAAA 1 A_FaceTarget
		ARAK GGGG 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArMiniComet",30,0,random(-20,20),0)
		ARAK HHHH 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArMiniComet",30,0,random(-20,20),0)
		ARAK GGGG 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArMiniComet",30,0,random(-20,20),0)
		ARAK HHHH 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArMiniComet",30,0,random(-20,20),0)
		ARAK A 14
		GoTo See
	BouncerGroundshot:
		ARAK A 15
		ARAK BBBBBBBBBBBBBBBBB 1 Bright A_SpawnItemEx("BlueFire2",0,0,35,0,0,random(5,11))
		ARAK C 1 Bright A_FaceTarget
		TNT1 AAAAAAAAAAAAA 0  A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_SpawnItemEx("BlueFlare2",0,0,37)
		TNT1 A 0 A_CustomMissile("AracknightGrounder",0,0,0)
		TNT1 A 0 A_CustomMissile("AracknightGrounder",0,0,25)
		TNT1 A 0 A_CustomMissile("AracknightGrounder",0,0,-25)
		ARAK C 5 Bright
		ARAK A 15
		GoTo See
	CerebralDrain:
		TNT1 A 0 A_ChangeFlag(NOPAIN,1)
		ARAK A 1 A_PlaySound("exile/voidstart")
		ARAK AAAAAA 1 A_FaceTarget
	VileChargeLoop:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("Tic",210,"CheckLOS")
		TNT1 A 0 A_SpawnItemEx("AracknightVileFire",0,0,60)
		TNT1 A 0 HealThing(2)
		TNT1 A 0 A_VileTarget("AracknightVilefire")
	CheckLOS1:
		ARAK G 1 Bright A_FaceTarget
		TNT1 A 0 A_GiveInventory("Tic",1)
		TNT1 A 0 A_JumpIfInventory("Tic",210,"CheckLOS")
		TNT1 A 0 A_JumpIfTargetInLos("VileChargeLoop",360)
		Loop
	CheckLOS:
		TNT1 A 0 A_ChangeFlag(NOPAIN,0)
		TNT1 A 0 A_TakeInventory("Tic",999)
		TNT1 A 0 A_JumpIfTargetInLos("VileExplode",360)
		ARAK G 4
		GoTo See
	VileExplode:
		TNT1 A 0 A_ChangeFlag(NOPAIN,0)
		ARAK GGG 1 Bright A_FaceTarget
		TNT1 A 0 HealThing(80)
		TNT1 A 0 A_VileTarget("AracknightVileExplode")
		ARAK GG 1 Bright A_FaceTarget
		ARAK A 5
		GoTo See
	Pain:
		TNT1 A 0
		ARAK I 7 A_Pain
		Goto See	
	Death:
		TNT1 A 0
		ARAK I 10 A_Scream
		ARAK J 6
		TNT1 AA 0 A_SpawnItemEx("BlueGibbedGenerator",0,0,0,0,0,0,0,128,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		ARA2 K 2 Bright A_CustomMissile("Kaboom23",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 A 0 A_PlaySound("weapons/rocklx",0,1.0,0)
		TNT1 AAAA 0 A_CustomMissile("SmokeFX2",random(20,40),0,random(0,360),2,random(0,360))
		ARAK L 6 A_NoBlocking
		ARAK MN 6
		ARAK O 6 A_KillChildren
		ARAK P 63000 CanRaise
		Stop
	}
}

Actor ArackBall : PaladinBall
{
Speed 32
FastSpeed 36
+DontHurtSpecies
+DontHarmSpecies
Species ""
Species "BabySpiders"
Damagetype ""
Damagetype "BabySpiders"
States
	{
	Spawn:	
		SATL AB 1 Bright A_SpawnItemEx("ArackBallTrail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)	
		Loop
	}   
}

Actor AracknightGrounder : HeresiarchTrail
{
Bouncecount 4
BounceFactor 1.1
WallBounceFactor 1.1
+HexenBounce
+DONTHARMSPECIES
+DONTHURTSPECIES
Species ""
Species "BabySpiders"
Species ""
Damagetype "BabySpiders"
}

ACTOR ArackBallTrail
{
RENDERSTYLE Add
Gravity 0.0
Alpha 0.78
+ClientSideOnly
+NOINTERACTION
+FORCEXYBILLBOARD
States
	{
	Spawn:
		TNT1 A 1
	Fade:
		SATL AB 1 Bright A_FadeOut(0.1,1)
		Loop
	}
}

Actor AracknightVileFire : ExileFireFX
{
Renderstyle Add
VSpeed 7
Alpha 1.0
XScale 1.0
YScale 1.5
+NOGRAVITY
+SEEKERMISSILE
+NOTARGET
+PierceArmor
+NODAMAGETHRUST
+DontHurtSpecies
+DontHarmSpecies
Species ""
Species "BabySpiders"
Damagetype ""
DamageType "BabySpiders"
Obituary "%o's brain was dried by an Aracknight."
States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("DSFLAME",0,1.0,0)
		TNT1 A 0 A_SpawnItem("AracknightFireSpawner",0,0,0,0)
		SAFX C 3 Bright
		TNT1 A 0 Bright A_Explode(2,70,0)
		SAFX CDDFFGGHHHH 1 Bright A_FadeOut(0.1,1)
		Stop
	}
}

ACTOR AracknightFireSpawner : RedParticleSpawner
{
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 A_SpawnItemEx("Kaboom23",random(16,-16),random(16,-16),random(6,12),0,0,random(2,4),0,SXF_CLIENTSIDE,0)
		TNT1 A 1 A_SpawnItemEx("BlueFire2",random(16,-16),random(16,-16),random(6,12),0,0,random(4,6),0,SXF_CLIENTSIDE,0)
		Stop
	}
}

Actor AracknightVileExplode : AracknightVileFire
{
+DontHurtSpecies
+DontHarmSpecies
Species ""
Species "BabySpiders"
Damagetype ""
Damagetype "BabySpiders"
States
	{
	Spawn:
		SAFX CC 1 Bright
		TNT1 A 0 A_PlaySound("monsters/newfireexplode",0,1.0,0)
		TNT1 AAAAAAAAAAA 0 A_SpawnItem("AracknightFireSpawner2",0,0,0,0)
		TNT1 A 0 Bright A_Explode(80,150,0)
		SAFX DDFFGGHHHHH 1 Bright A_FadeOut(0.1,1)
		Stop
	}
}

ACTOR AracknightFireSpawner2 : RedParticleSpawner
{
States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("Kaboom23",random(16,-16),random(16,-16),random(6,12),random(-5,5),random(-5,5),random(9,11),random(0,360),128,0)
		TNT1 A 1 A_SpawnItemEx("BlueFire2",random(16,-16),random(16,-16),random(6,12),random(-5,5),random(-5,5),random(7,9),random(0,360),128,0)
		Stop
	}
}

Actor ArMiniComet : RuffianComet
{
Damage (random(35,45))
+DontHurtSpecies
+DontHarmSpecies
Species ""
Species "BabySpiders"
Damagetype ""
Damagetype "BabySpiders"
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_Jump(155,"Homing")
		GoTo Normal
	}
}