Actor CyZombie
{
Monster
Health 425
Height 59
Radius 20
Scale 1.15
Speed 4
Mass 400
Reactiontime 15
Bloodcolor Purple
Painchance "Mine", 128
Painchance 30
MissileType "BorgNail"
+FloorClip
+MissileMore
+QUICKTORETALIATE
+DONTHURTSPECIES
+DONTHARMSPECIES
Species "EliteZombies"
Damagefactor "Acid", 3.8
Damagefactor 0.9
//No Infighting
DamageFactor "RST", 0.0
Damagefactor "ZExplosiveBullets", 0.0
Damagefactor "HTZombie", 0.0
DamageFactor "ZombieCannon", 0.0
DamageFactor "MiniRocket", 0.0
DropItem "Nailgun", 100
DropItem "NailAmmo", 180
DropItem "NailAmmoBoxSmall", 80
DropItem "ArmorCharge", 150
DropItem "ArmorCharge", 150
DropItem "PortableMedCell", 80, 1
DropItem "HealthFlask", 120, 3
DropItem "HandGrenadeAmmo", 150, 1
DropItem "MineAmmo", 120, 1
DropItem "AmmoPack", 190, 2
SEESOUND "Monsters/NBSight"
ACTIVESOUND "Monsters/NBAct"
PAINSOUND "Monsters/NBPain"
DEATHSOUND "Monsters/NBDeath"
Obituary "%o was shredded by a Cyber Zombie."
Tag "\cnCyber Zombie\c-"
States
	{
	Spawn:
		NLBG A 10 A_Look
		Loop
	See:
		NLBG AAA 1 A_Chase("","")
		NLBG A 1 A_Chase
		NLBG BBB 1 A_Chase("","")
		NLBG B 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("CyZomStep",0,0,2,0,0,-20)
		NLBG CCC 1 A_Chase("","")
		NLBG C 1 A_Chase
		NLBG DDD 1 A_Chase("","")
		NLBG D 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("CyZomStep",0,0,2,0,0,-20)
		TNT1 A 0 A_Jump(62,"Run")
		Loop
	Run:
		NLBG B 1 A_Chase("","")
		TNT1 A 0 A_Chase
		NLBG B 1 A_Chase("","")
		TNT1 A 0 A_Chase
		NLBG B 1 A_Chase("","")
		TNT1 A 0 A_Chase
		NLBG B 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("CyZomStep",0,0,2,0,0,-20)
		NLBG D 1 A_Chase("","")
		TNT1 A 0 A_Chase
		NLBG D 1 A_Chase("","")
		TNT1 A 0 A_Chase
		NLBG D 1 A_Chase("","")
		TNT1 A 0 A_Chase
		NLBG D 1 A_Chase("","")
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("CyZomStep",0,0,2,0,0,-20)
		TNT1 A 0 A_Jump(26,"See")
		Loop
	Missile:
		NLBG EEEEEE 1 A_FaceTarget(45)
	Refire:
		NLBG FF 1 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("weapons/nailfire",CHAN_WEAPON)
		TNT1 A 0 A_MissileAttack
		TNT1 A 0 A_MonsterRefire(0,"MissileEnd")
		NLBG EEEEEE 1 A_FaceTarget
		NLBG FF 1 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("weapons/nailfire",CHAN_WEAPON)
		TNT1 A 0 A_MissileAttack
		TNT1 A 0 A_MonsterRefire(0,"MissileEnd")
		NLBG EEEEEE 1 A_FaceTarget
		NLBG FF 1 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("weapons/nailfire",CHAN_WEAPON)
		TNT1 A 0 A_MissileAttack
		TNT1 A 0 A_MonsterRefire(0,"MissileEnd")
		NLBG EEEEEE 1 A_FaceTarget
		NLBG FF 1 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("weapons/nailfire",CHAN_WEAPON)
		TNT1 A 0 A_MissileAttack
		TNT1 A 0 A_Jump(72,"MissileEnd")
		TNT1 A 0 A_MonsterRefire(0,"MissileEnd")
		NLBG EEEEEE 1 A_FaceTarget
		Loop
	MissileEnd:
		NLBG EEEEEEEEEEE 1 A_Chase("","Refire",CHF_NOPLAYACTIVE|CHF_DONTMOVE)
		GoTo See
	Pain:
		TNT1 A 0
		NLBG G 2 A_Pain
		NLBG G 3
		GoTo See
	Death:
		TNT1 A 0
		NLBG H 5 A_Scream
		NLBG I 5 A_Fall
		NLBG JKLM 4
		TNT1 A 0 A_SpawnItem("BodyCrash",0,0,0,0)
		NLBG N 63000 CanRaise
		Stop
	XDeath:
		TNT1 A 0
		NLBG O 5 A_XScream
		TNT1 A 0 A_Fall
		TNT1 A 0 A_GiveInventory("XDeathCheck",1)
		TNT1 A 0 A_SpawnItemEx("MutantGibbedGenerator",0,0,0,0,0,0,0,128,0) 
		NLBG PQRSTUV 5
		NLBG W 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_JumpIfInventory("XDeathCheck",1,"XRaise")
		NLBG MLKJIH 4
		GoTo See
	XRaise:
		TNT1 A 0 A_TakeInventory("XDeathCheck",1)
		NLBG VUTSRQPO 4
		GoTo See
	}
}

Actor BorgNail
{
Projectile
Radius 3
Height 3
Speed 72
Damage 2
Scale 0.3
Decal Bulletchip
+Ripper
+NOBOSSRIP
+StrifeDamage
+BLOODSPLATTER
+PIERCEARMOR
+DONTHARMSPECIES
+DONTHURTSPECIES
Species "EliteZombies"
Damagetype "ZExplosiveBullets"
SeeSound ""
DeathSound ""
States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("weapons/nailflight",CHAN_VOICE,1.0,1)
	Fly:
		CZNI A 1 A_CustomMissile("HEMNailBlur",0,0,180)
		Loop
	Crash:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("weapons/nailhit",CHAN_VOICE,1.0,0)
		TNT1 A 0 A_SpawnItemEx("ModdedBulletPuff",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,0)
		CZNI BCDEFG 2
		Stop
	XDeath:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("weapons/nailhitbleed",CHAN_VOICE,1.0,0)
		CZNI BCDEFG 2
		Stop
	Death:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("weapons/nailhit",CHAN_VOICE,1.0,0)
		TNT1 A 0 A_SpawnItemEx("ModdedBulletPuff",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,0)
		CZNI BCDEFG 2
		Stop
	}
}

Actor HEMNailBlur
{
Height 8
Radius 1
Scale 0.3
Speed 0.2
RenderStyle Translucent
Alpha 0.5
Damage (0)
+NOINTERACTION
+NOGRAVITY
+DROPOFF
States
	{
	Spawn:
		CZNI A 1 A_FadeOut(0.1,1)
		Loop
	}
}