ACTOR DemonicZombie
{ 
MONSTER 
Health 300
Height 56
Radius 20
Mass 400
Speed 4
Scale 1.075
Painchance "Mine", 128
PainChance "ZombieCannon", 0
PainChance 45
+FLOORCLIP
+MISSILEMORE
+QUICKTORETALIATE
+DONTHURTSPECIES
+DONTHARMSPECIES
Species "EliteZombies"
Damagefactor "Acid", 0.8
//No Infighting
Damagefactor "HTZombie", 0.0
DamageFactor "MiniRocket", 0.0
Damagefactor "ZExplosiveBullets", 0.0
DamageFactor "ZombieCannon", 0.0
Damagefactor "ZGrenade", 0.0
DropItem "LifeEssence", 185, 15
DropItem "HEMArmorBonusMax10", 135
DropItem "PortableMedkit", 200
DropItem "ArmorPlate", 200
DropItem "HandGrenadeAmmo", 225, 2
DropItem "HealthFlask", 250, 6
DropItem "MineAmmo", 125
DropItem "AmmoPack", 125, 2
DropItem "BehemothCannon", 24, 1
SeeSound "superzombie/sight"
PainSound "superzombie/pain"
DeathSound "superzombie/death"
ActiveSound "superzombie/active"
Obituary "%o met a Demonic Zombie and was reduced to shit-smelling ashes."
Tag "\caDemonic Zombie\c-"
States
	{
	Spawn:
		ZUNM A 10 A_Look
		ZUNI A 10 A_Look
		Loop
	Idle:
		ZUNM AAAAAA 1 A_Wander
		TNT1 A 0 A_Look
		ZUNM BBBBBB 1 A_Wander
		TNT1 A 0 A_Look
		TNT1 A 0 HealThing(1)
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		ZUNM CCCCCC 1 A_Wander
		TNT1 A 0 A_Look
		ZUNM DDDDDD 1 A_Wander
		TNT1 A 0 A_Look
		TNT1 A 0 HealThing(1)
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		Loop
	See:
		ZUNM AAAAAABBBBBB 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		ZUNM CCCCCCDDDDDD 1 A_Chase
		TNT1 A 0 HealThing(1)
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		Loop
	Missile:
		TNT1 A 0 A_Jump(64,"Missile2")
		ZUNM EEEEEEEEEE 1 A_FaceTarget
		ZUNM F 10 Bright A_CustomMissile("HEMZombieComet",32,0,0)
		ZUNM EEEEEEEEEE 1 A_FaceTarget
		ZUNM F 10 Bright A_CustomMissile("HEMZombieComet",32,0,0)
		ZUNM E 20
		Goto See
	Missile2:
		ZUNM EEEEEEEEEE 1 A_FaceTarget
		ZUNM F 10 Bright A_CustomMissile("ZombieSeekingComet",32,0,0)
		ZUNM E 20 
		Goto See
	Pain:
		TNT1 A 0
		ZUNM G 6 A_Pain
		Goto See
	Death:
		TNT1 A 0
		ZUNM H 5 A_Scream
		ZUNM I 5 A_Fall
		ZUNM J 5 A_SpawnItem("BodyCrash",0,0,0,0)
		ZUNM KLM 5
		ZUNM N 63000 CanRaise
		Stop
	XDeath:
		TNT1 A 0
		ZUNM O 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		ZUNM P 3 A_XScream
		TNT1 A 0 A_GiveInventory("XDeathCheck",1)
		ZUNM Q 3 A_Fall
		ZUNM RSTUV 3
		ZUNM W 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_JumpIfInventory("XDeathCheck",1,"XRaise")
		ZUNM NMLKJIH 5
		Goto See
	XRaise:
		TNT1 A 0
		TNT1 A 0 A_TakeInventory("XDeathCheck",1)
		ZUNM VUTSRQPO 4
		GoTo See
	}
}

ACTOR HEMZombieComet : BehemothComet
{
+THRUSPECIES
+MTHRUSPECIES
Species ""
Species "EliteZombies"
DamageType ""
DamageType "ZombieCannon"
}