ACTOR Hades-TechZombie
{ 
MONSTER
Health 310
Height 56
Radius 20
Mass 100
Speed 10
Bloodcolor Green
Painchance "Mine", 128
PainChance "ZombieBFG", 0
PainChance 30
+FLOORCLIP
+MISSILEMORE
+QUICKTORETALIATE
+DONTHURTSPECIES
+DONTHARMSPECIES
Species "EliteZombies"
DamageFactor "ZombieBFG", 0.15
DamageFactor "DrainLife", 0.1
//No Infighting
Damagefactor "HTZombie", 0.0
DamageFactor "MiniRocket", 0.0
Damagefactor "ZGrenade", 0.0
Damagefactor "ZExplosiveBullets", 0.0
DropItem "LifeEssence", 196, 10
DropItem "HEMArmorBonusMax10", 196
DropItem "HealthFlask", 250, 6
DropItem "ArmorPlate", 196
DropItem "AmmoPack", 100
DropItem "HandGrenadeAmmo", 200, 1
DropItem "MineAmmo", 100, 1
DropItem "HadesCrystal", 100
DropItem "HadesCrystal", 32
DropItem "HemFlare", 64, 1
SeeSound "superzombie/sight"
ActiveSound "superzombie/active"
AttackSound "weapons/bfg15kfire"
PainSound "superzombie/pain"
DeathSound "superzombie/death"
Obituary "%o got sucked dry by a Dark Zombieman."
Tag "\cqDark Zombieman\c-"
States
	{
	Spawn:
		KSWZ A 10 A_Look
		KSWI A 10 A_Look
		Loop
	See:
		KSWZ AABB 2 A_Chase
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		KSWZ CCDD 2 A_Chase
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		TNT1 A 0 HEALTHING(1)
		TNT1 A 0 A_Jump(62,"Rush")
		Loop
	Rush:
		KSWZ A 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("HTZGhostA",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		KSWZ A 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("HTZGhostA",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		KSWZ B 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("HTZGhostB",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		KSWZ B 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		TNT1 A 0 A_SpawnItemEx("HTZGhostB",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		KSWZ C 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("HTZGhostC",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		KSWZ C 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("HTZGhostC",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		KSWZ D 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("HTZGhostD",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		KSWZ D 1 A_Chase
		TNT1 A 0 A_Chase
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		TNT1 A 0 A_SpawnItemEx("HTZGhostD",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		TNT1 A 0 A_Jump(50,"See")
		Loop
	Missile:
		TNT1 A 0
		TNT1 A 0 A_Jump(30,"DoomWraith")
		KSWZ EEEEEE 1 A_FaceTarget(45)
		KSWZ F 3 Bright A_CustomMissile("ZombieHadesBall",34,0,0,CMF_TRACKOWNER)
		KSWZ EEE 1 A_FaceTarget
		KSWZ F 3 Bright A_CustomMissile("ZombieHadesBall",34,0,0,CMF_TRACKOWNER)
		KSWZ EEE 1 A_FaceTarget
		KSWZ F 3 Bright A_CustomMissile("ZombieHadesBall",34,0,0,CMF_TRACKOWNER)
		KSWZ EEE 1 A_FaceTarget
		KSWZ F 3 Bright A_CustomMissile("ZombieHadesBall",34,0,0,CMF_TRACKOWNER)
		KSWZ EEE 1 A_FaceTarget
		KSWZ F 3 Bright A_CustomMissile("ZombieHadesBall",34,0,0,CMF_TRACKOWNER)
		KSWZ E 10
		Goto See
	DoomWraith:
		KSWZ EEEEEEEEEE 1 A_FaceTarget(45)
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 A_PlaySound("DoomWraithSpawn",CHAN_WEAPON,1.0,0)
		KSWZ F 3 Bright A_CustomMissile("ZombieDoomWraith",34,0,0,CMF_TRACKOWNER)
		KSWZ EEE 1 A_FaceTarget(45)
		KSWZ E 10
		GoTo See
	Pain:
		TNT1 A 0
		KSWZ G 6 A_Pain
		Goto See
	Death:
		TNT1 A 0
		KSWZ H 5 A_Scream
		KSWZ I 5 A_Fall
		TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(298) == 1, "AlwaysDrop")
		TNT1 A 0 A_SpawnItemEx("LifeLeecher",0,0,8,random(0,8),random(0,8),2,random(0,360),0,252)
		Goto EndDrop
	AlwaysDrop:
		TNT1 A 0 A_SpawnItemEx("LifeLeecher",0,0,8,random(0,8),random(0,8),2,random(0,360),0,0)
		Goto EndDrop
	EndDrop:
		KSWZ J 5 A_SpawnItem("BodyCrash",0,0,0,0)
		KSWZ KLM 5
		KSWZ N 63000 CanRaise
		Stop
	XDeath:
		TNT1 A 0
		TNT1 A 0 A_GiveInventory("xdeathcheck",1)
		KSWZ O 3 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
		KSWZ P 3 A_XScream
		KSWZ R 3 A_Fall
		TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(298) == 1, "XAlwaysDrop")
		TNT1 A 0 A_SpawnItemEx("LifeLeecher",0,0,8,random(0,8),random(0,8),2,random(0,360),0,252)
		Goto XEndDrop
	XAlwaysDrop:
		TNT1 A 0 A_SpawnItemEx("LifeLeecher",0,0,8,random(0,8),random(0,8),2,random(0,360),0,0)
		Goto XEndDrop
	XEndDrop:
		KSWZ STUV 3
		KSWZ W 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_jumpifinventory("xdeathcheck",1,"Xraise")
		KSWZ NMLKJIH 5
		Goto See
	Xraise:
		TNT1 A 0 a_takeinventory("xdeathcheck",1)
		KSWZ WVTUSRQPO 3
		GOTO SEE
	}
}

Actor ZombieHadesBall : ShadeMissile
{
Speed 27
//Species ""
//Species "EliteZombies"
//Damagetype ""
Damagetype "HTZombie"
States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_CheckFlag(FRIENDLY,2,AAPTR_TARGET)
		TNT1 A 0
		Goto Super::Spawn
		TNT1 A 0 A_SetDamageType("DrainLife")
		Goto Super::Spawn
	XDeath:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_GiveToTarget("Health",20)
		TNT1 A 0 A_SpawnItemEx("RedParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 A_CustomMissile("Kaboom10",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		TNT1 AAA 0 A_CustomMissile("SmokeFX4",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		NBAL HIJKLM 3 Bright A_FadeOut(0.1,1)
		Stop
	}
}

Actor ZombieDoomWraith : DoomWraith2
{
Damage (3*random(3,8))
Species ""
Species "EliteZombies"
Damagetype ""
Damagetype "HTZombie"
}

ACTOR HTZGhostA
{
Projectile
Height 56
Radius 2
Speed 0
RENDERSTYLE Translucent
Alpha 0.7
+NOINTERACTION
+CLIENTSIDEONLY
+NONETID
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
		TNT1 A 1 Bright
		Goto Fade
	Fade:
		KSWZ A 2 A_FadeOut(0.1,1)
		Loop
	Toaster:
		TNT1 A 1 Bright
		Stop
	}
}

Actor HTZGhostB : HTZGhostA
{
States
	{
	Fade:
		KSWZ B 2 A_FadeOut(0.1,1)
		Loop
	}
}

Actor HTZGhostC : HTZGhostA
{
States
	{
	Fade:
		KSWZ C 2 A_FadeOut(0.1,1)
		Loop
	}
}

Actor HTZGhostD : HTZGhostA
{
States
	{
	Fade:
		KSWZ D 2 A_FadeOut(0.1,1)
		Loop
	}
}