Actor Gnasher : Weapon replaces chaingun
{
  Weapon.SelectionOrder 35
  Weapon.AmmoUse1 1
  Weapon.AmmoUse2 30
  Weapon.AmmoGive 25
  Weapon.KickBack 40
  +WEAPON.NOALERT
  +WEAPON.ALT_AMMO_OPTIONAL
  Weapon.AmmoType1 "Clip"
  Weapon.AmmoType2 "Harpooncharge"
  Inventory.PickupSound "Misc/W_PkUp"
  Inventory.PickupMessage "You got the Mk. 2 'Gnasher' Nailgun!"
  Obituary "%o was nailed by %k."
  States
  {
	Spawn:
		NLMG J -1
		Loop
	Select:
		TNT1 A 0
		TNT1 A 0 a_playsound ("gnasher/draw",0)
	draw:
		TNT1 A 0
		NLMG AAAA 0 A_Raise
		NLMG A 1 A_Raise
		TNT1 A 0 A_GiveInventory("ACanUseHarpoon", 1)
		TNT1 A 0 a_takeinventory ("speedupcount", 99)
		Loop
	Deselect:
		TNT1 A 0
		TNT1 A 0 a_jumpifhealthlower (1, "deadlower")
		TNT1 A 0 a_playsound ("gnasher/holster",0)
	holster:
		TNT1 A 0
		NLMG A 1 A_Lower
		NLMG AA 0 A_Lower
		TNT1 A 0 A_TakeInventory("ACanUseHarpoon", 1)
		TNT1 A 0 a_takeinventory ("secretaction", 99)
		TNT1 A 0 a_takeinventory ("speedupcount", 99)
		Loop
	deadlower:
		TNT1 A 0
		TNT1 A 0
		TNT1 AAAAAAAAAAAAA 0 a_lower
		TNT1 A 1 a_lower
		wait  
	Ready:
		NLMG A 1 A_WeaponReady
		Loop
	Fire:
		TNT1 A 0 a_alertmonsters
		TNT1 A 0 a_jumpifinventory ("speedupcount", 5, "speedlevel1")
		NLMG B 0 A_PlayWeaponSound("Weapons/NailMGFire")
		NLMG B 2 A_FireCustomMissile("MGNail", Frandom(1, -1), 1, -3, 0, 0,0)
		NLMG C 1
		NLMG A 1
		NLMG D 0 A_PlayWeaponSound("Weapons/NailMGFire")
		NLMG D 2 A_FireCustomMissile("MGNail", Frandom(1, -1), 1, 3, 0, 0,0)
		NLMG E 1
		NLMG A 1 a_giveinventory ("speedupcount", 1)
		TNT1 A 0 a_refire
		TNT1 A 0 a_takeinventory ("speedupcount", 99)
		Goto Ready
	speedlevel1:
		TNT1 A 0 a_jumpifinventory ("speedupcount", 10, "speedlevel2")
		NLMG B 0 A_PlayWeaponSound("Weapons/NailMGFire")
		TNT1 A 0 A_Quake(1, 4, 0, 5)
		NLMG B 1 A_FireCustomMissile("MGNail", Frandom(2, -2), 1, -3, 0, 0, Frandom(1, -1))
		NLMG C 1
		NLMG A 1
		NLMG D 0 A_PlayWeaponSound("Weapons/NailMGFire")
		TNT1 A 0 A_Quake(1, 4, 0, 5)
		NLMG D 1 A_FireCustomMissile("MGNail", Frandom(2, -2), 1, 3, 0, 0, Frandom(1, -1))
		NLMG E 1
		NLMG A 1 a_giveinventory ("speedupcount", 1)
		TNT1 A 0 a_refire ("speedlevel1")
		TNT1 A 0 a_takeinventory ("speedupcount", 99)
		goto ready
	speedlevel2:
		NLMG B 0 A_PlayWeaponSound("Weapons/NailMGFire")
		TNT1 A 0 A_Quake(2, 2, 0, 5)
		NLMG B 1 A_FireCustomMissile("MGNail", Frandom(3, -3), 1, -3, 0, 0, Frandom(2, -2))
		NLMG C 1 
		NLMG D 0 A_PlayWeaponSound("Weapons/NailMGFire")
		TNT1 A 0 A_Quake(1, 2, 0, 5)
		NLMG D 1 A_FireCustomMissile("MGNail", Frandom(3, -3), 0, 3, 0, 0, Frandom(2, -2))
		NLMG E 1
		TNT1 A 0 a_refire ("speedlevel2")
		TNT1 A 0 a_takeinventory ("speedupcount", 99)
		goto ready
	altfire:
		TNT1 A 0
		TNT1 A 0 a_jumpifinventory ("Harpooncharge", 20, "Harpooncheck")
		goto ready
	harpooncheck:
		NLMG A 1 A_JumpIfInventory("ACanUseHarpoon", 1, "Sappershot")
		goto ready
	sappershot:
		TNT1 A 0 a_playsound ("weapons/nailalt")
		TNT1 A 0 a_alertmonsters
		TNT1 A 0 A_Takeinventory ("Harpooncharge", 20)
		TNT1 A 0 A_TakeInventory("ACanUseHarpoon", 1)
		NLMG F 2 bright
		//NLMG G 1 a_firecustommissile ("cellsapper")
		NLMG G 1 A_FireCustomMissile("AHarpoonHead",0,0,0,3)
		NLMG H 1 
		NLMG I 1
		NLMG A 8
		goto ready
		}
}



Actor MGNail 
{
	Projectile
	Radius 3
	Height 3
	Speed 65
	Damage 3
	Scale 0.5
	+thruspecies
	+bright
	species "player"
	+BloodSplatter
	SeeSound ""
	DeathSound ""
	Decal BulletChip
	States
	{
	Spawn:
		NLPJ A 1 A_SpawnItemEx("NailBlur")
		NLPJ A 0 A_PlaySound("Weapons/NailFlight")
		Loop
	Crash:
	Death:
		TNT1 A 0
		TNT1 A 1
		NLPJ B 0 A_PlaySound("Weapons/NailWall")
		PUFF A 0
		PUFF A 3 Bright 
		PUFF B 3 Bright A_SetTranslucent(.75,0)
		PUFF C 3 Bright A_SetTranslucent(.5,0)
		PUFF D 3 Bright A_SetTranslucent(.25,0)
		stop
	XDeath:
		TNT1 A 0
		TNT1 A 0
		NLPJ B 0 A_PlaySound("Weapons/NailHit")
		TNT1 A 0 a_jumpifintargetinventory ("daibatana", 1, "givecharge")
		NLPJ BCDEFG 2
		stop
	givecharge:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 a_jump (80, "nothing")
		TNT1 A 0 a_giveinventory ("batcharge", 1, AAPTR_TARGET)
		NLPJ BCDEFG 2
		stop
	nothing:
		TNT1 A 0
		NLPJ BCDEFG 2
		Stop
	}
}

actor cellsapper : MGnail
{
	damage (20)
	states
	{
	xdeath:
		NLPJ B 0 A_PlaySound("Weapons/NailHitBleed")
		TNT1 A 0 a_spawnitem ("SapperReturn")
		NLPJ BCDEFG 2
		stop
	}
}

actor sapperReturn : CustomInventory
{
    Radius 30
    Height 30
    Speed  40
    Damage 0       
    +NOGRAVITY
    +SEEKERMISSILE
    +DROPOFF
    +NOBLOCKMONST
    +CANPASS
    -COUNTITEM
    +ALWAYSPICKUP
    +NOCLIP
    +FORCEXYBILLBOARD
	Inventory.PickupMessage "Gained 20 cells."
    States
    {
    Spawn:
        TNT1 AA 0 A_ReArrangePointers(AAPTR_NULL,AAPTR_NULL,AAPTR_TARGET)
        Spawn2:
        TNT1 A 1 A_SeekerMissile(20,35)
        loop
    PickUp:
        TNT1 A 0 A_GiveInventory("cell",20)
        TNT1 A 0 A_SetBlend("blue",0.1,3)
    Death:
        TNT1 A 1
        stop
    }
}

Actor NailBlur       
{
  Height 8
  Radius 1
  Damage 0
  Scale 0.6
  Speed 0.2
  RenderStyle Translucent
  Alpha 0.5
  +NoGravity
  +DropOff
  +NoTeleport
  +clientsideonly
  States
  {
  Spawn:
    NLPJ A 1 bright A_FadeOut(0.05)
    Loop
  }
}

actor speedupcount : inventory
{inventory.maxamount 20}


actor Harpooncharge : ammo
{
  Inventory.PickupMessage "Harpoon Charge (you shouldn't find this either!)"
  Inventory.Amount 1
  Inventory.MaxAmount 20
  Inventory.Icon "BAL1A0"
  Ammo.BackpackAmount 0
  Ammo.BackpackMaxAmount 0
  states
  {
  Spawn:
    BAL1 A -1
    stop
  }
}



/*
Copyright (C) 2015 Graham Sanderson

Anyone is free to copy, modify, publish, use, compile, sell, or
distribute this software, either in source code form or as a compiled
binary, for any purpose, commercial or non-commercial, and by any
means.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
IN NO EVENT SHALL THE AUTHORS BE LIABLE FOR ANY CLAIM, DAMAGES OR
OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
OTHER DEALINGS IN THE SOFTWARE.
*/

const int HARPOON_MAIN = 660;
const int HARPOON_SNAPBACK = 661;
const int HARPOON_HITENEMY = 662;

actor AHarpoonDummy : Inventory
{
   Inventory.MaxAmount 1
}

actor ACanUseHarpoon : Inventory
{
   Inventory.MaxAmount 1
}

actor AHarpoonHead
{
   Speed 24.0
   Damage 10
   Projectile
   +NOGRAVITY
   +NOTELEPORT
   +FORCEXYBILLBOARD
   +BRIGHT
   +SKYEXPLODE
   +SEEKERMISSILE
   +NOEXTREMEDEATH

   states
   {
   Spawn:
      TNT1 A 0
      TNT1 A 0 ACS_ExecuteWithResult(HARPOON_MAIN)
      GNSH A 1 A_JumpIfInventory("AHarpoonDummy", 1, "Death")
      wait
   Crash:
   XDeath:
      TNT1 A 0 A_SeekerMissile(30, 90, SMF_LOOK, 256, 8)
      TNT1 A 0 ACS_ExecuteWithResult(HARPOON_HITENEMY)
      TNT1 A 0 a_spawndebris ("harpoonblood")
	  GNSH C 2
      TNT1 A 0 A_SpawnItemEx("AHarpoonHead3", 0,0,0,0,0,0,0, SXF_TRANSFERPOINTERS|SXF_NOCHECKPOSITION)
      stop
   Death:
	  TNT1 A 0
	  TNT1 A 0
	  TNT1 A 0 A_PlaySound("pipe/wall", CHAN_AUTO)
	  TNT1 AA 0 A_SpawnDebris("WWStyleBulletSpark")
	  GNSH B 2
      TNT1 A 0 A_SpawnItemEx("AHarpoonHead2", 0,0,0,0,0,0,0, SXF_TRANSFERPOINTERS|SXF_NOCHECKPOSITION)
      stop
   }
}

actor AHarpoonHead2 : AHarpoonHead
{
   -MISSILE
   -ACTIVATEIMPACT
   -ACTIVATEPCROSS
   +NOCLIP
   states
   {
   Spawn:
      TNT1 A 0
      TNT1 A 0 ACS_ExecuteWithResult(HARPOON_SNAPBACK, 0)
      GNSH B 75
      stop
   }
}

actor AHarpoonHead3 : AHarpoonHead2
{
   states
   {
   Spawn:
      TNT1 A 0
      TNT1 A 0 ACS_ExecuteWithResult(HARPOON_SNAPBACK, 1)
      GNSH C 75
      stop
   }
}

actor AHarpoonLink
{
   +NOINTERACTION
   +NOTELEPORT
   +FORCEXYBILLBOARD
   +BRIGHT

   states
   {
   Spawn:
      TNT1 A 0
      LINK A 1
      stop
   }
}

actor harpoonblood
{
	Health 4
	radius 3
	height 6
	speed .1
	Scale 1.5
	Mass		0
	+missile
	+doombounce
	+FLOORCLIP
	+DONTSPLASH
	+NOTELEPORT
	+clientsideonly
	States
	{
		NLPJ B 0 A_PlaySound("Weapons/NailHit")
		NLPJ BCDEFG 2
		Stop
	}
}
