ACTOR "Lizard Tank" : "Pig Tank" 31104
{
    //$Category DN3D Aliens //Tanks
	Obituary "%o was shredded by a Lizard tank."
	AttackSound "AlienMissile/Shot"
	+MISSILEMORE
	+MISSILEEVENMORE
    States
    {
    Spawn:
        TAE3 A 2 A_Look
        TAE3 A 0 A_StopSoundEx("SoundSlot7")
        Loop
	See:
        TAE3 A 0 
        TAE3 A 0 A_PlaySoundEx("Pig/Tank3","SoundSlot7",1)
        TAE3 ABC 4 A_Chase
        Loop
	Missile:
        TAE3 A 1 A_JumpIfCloser(725,"Grenade")
	Rockets:
        TAE3 A 0 A_StopSoundEx("SoundSlot7")
		TAE3 A 0 A_PlaySound("Executor/Up",6)
        TAE3 A 20 A_FaceTarget
		TAE3 A 0 A_PlaySoundEx("AlienMissile/Shot","SoundSlot6",0,0)
        TAE3 D 8 Bright A_CustomMissile("DevastatorAttackTank",55,-29,0,0) 
        TAE3 A 10 A_FaceTarget
		TAE3 A 0 A_PlaySoundEx("AlienMissile/Shot","SoundSlot6",0,0)
        TAE3 E 8 Bright A_CustomMissile("DevastatorAttackTank",55,32,0,0) 
        TAE3 A 5
        Goto See
	Grenade:
	    TAE3 A 0 A_StopSoundEx("SoundSlot7")
		TAE3 A 0 A_Jump(128,"Rockets")
	    TAE3 A 0 A_JumpIfCloser(512,"LowNade")
	    TAE3 A 0 A_JumpIfCloser(2056,2)
	    TAE3 A 0 A_Jump(256,"Rockets")
	    TAE3 A 10 A_FaceTarget
	    TAE3 A 0 A_PlaySoundEx("AlienTank/Grenade","SoundSlot6",0,0)
	    TAE3 D 8 Bright A_CustomMissile("PigCopNade",40,-30,0,2,16)
	    TAE3 A 0 A_PlaySoundEx("AlienTank/Grenade","SoundSlot6",0,0)
	    TAE3 E 8 Bright A_CustomMissile("PigCopNade",40,30,0,2,16)
	    TAE3 A 8 A_FaceTarget
	    Goto See
    LowNade:
	    TAE3 A 10 A_FaceTarget
		TAE3 A 0 A_PlaySoundEx("AlienTank/Grenade","SoundSlot6",0,0)
	    TAE3 D 8 Bright A_CustomMissile("PigCopNade1",40,-30,0,2,16)
		TAE3 A 0 A_PlaySoundEx("AlienTank/Grenade","SoundSlot6",0,0)
	    TAE3 E 8 Bright A_CustomMissile("PigCopNade1",40,30,0,2,16)
	    TAE3 A 8 A_FaceTarget
	    Goto See
    Pain.Radial:
        TAE3 A 0
        TAE3 A 0 HealThing(2)
        Goto See
	Pain.LaserShot:
	    TAE3 A 0
		TAE3 A 0 A_SpawnItemEx("PainTripLaser",0,0,5)
		TAE3 A 0 HealThing(2)
		Goto See
	Death:	
		TAE3 A 20 A_PlaySound("Hurt/Tank",5)
		TAE3 A 0 A_Jump(128,33)
        TAE3 F 0 A_StopSoundEx("SoundSlot7")
		TAE3 F 0 A_Scream
		TAE3 F 0 A_KillMaster
		TAE3 FFFFF 0 A_SpawnDebris("MetalGibs1")		
		TAE3 FFFFF 0 A_SpawnDebris("MetalGibs2")		
		TAE3 FFFFF 0 A_SpawnDebris("MetalGibs3")		
		TAE3 FFFFF 0 A_SpawnDebris("MetalGibs4")		
		TAE3 FFFFF 0 A_SpawnDebris("MetalGibs5")	
        TAE3 F 1 A_SpawnItemEx("ExpanderExplosion",0,0,32,0,0,0,0,SXF_ABSOLUTEVELOCITY,0)
        TAE3 F 1 A_NoBlocking
		TAE3 F 1 A_SpawnItemEx("Enforcer Hurt",0,0,0,0,0,0,0)
		TAE3 F -1
        Stop
		TAE3 G 0 A_StopSoundEx("SoundSlot7")
		TAE3 G 0 A_Scream
		TAE3 G 0 A_KillMaster
		TAE3 GGGGG 0 A_SpawnDebris("MetalGibs1")		
		TAE3 GGGGG 0 A_SpawnDebris("MetalGibs2")		
		TAE3 GGGGG 0 A_SpawnDebris("MetalGibs3")		
		TAE3 GGGGG 0 A_SpawnDebris("MetalGibs4")		
		TAE3 GGGGG 0 A_SpawnDebris("MetalGibs5")	
        TAE3 G 1 A_SpawnItemEx("ExpanderExplosion",0,0,32,0,0,0,0,SXF_ABSOLUTEVELOCITY,0)
        TAE3 G 1 A_NoBlocking
		TAE3 G 1 A_SpawnItemEx("Enforcer Hurt",0,0,0,0,0,0,0)
		TAE3 G -1
        Stop
    }
}

ACTOR DevastatorAttackTank
{
    Radius 2
    Height 2
    Speed 30
    Damage (5)
    Projectile
    DeathSound "Rpg/BlowUp"
    Scale 0.23
	Decal "Scorch"
    DamageType "Damage_Explosion"
	+RANDOMIZE
	+THRUGHOST
    States
    {
    Spawn:
        RPGX A 0 A_PlaySound("MiniRocket/Fly",CHAN_BODY,1.0,True)
		RPGX A 1 Bright A_SpawnItemEx("DevastatorSmoke",0,0,0,Random(-1,1),Random(-1,1),Random(-1,1))
		Loop
    Death:
		TNT1 A 0 A_StopSound(CHAN_BODY)
		TNT1 A 0 A_PlaySound("Explosion/Sounds2",11)
		TNT1 A 0 A_Explode(80,128)
        TNT1 A 1 A_SpawnItemEx("DukeNukemExplosion2",0,0,0,0,0,0,0,0)
        Stop
        }
}