actor blazmimic : actor replaces wolfensteinSS
{
    Health 250
    Radius 20
    Height 56
    Speed 13
    PainChance 128
 	Painchance "grappler", 256
	Monster
    +FLOORCLIP
	SeeSound "Mimic/Blazsee"
    PainSound "Mimic/Blazpain"
    DeathSound "Mimic/Blazdie"
    bloodtype bonespray
	ActiveSound "imp/active"
    Obituary "%o was outskilled by a Blaz mimic."
    HitObituary "%o was cut down by a Blaz mimic."
	dropitem "smallsubrefresh" 120
	dropitem "lilchest" 15
	states
	{
	spawn:
		BMMC AB 15 a_look
		loop
	see:
		BMMC A 4 a_facetarget
		TNT1 A 0 a_jump (60, "chaosexplode")
		goto realsee
	realsee:
		BMMC AA 2 a_chase
		BMMC A 2 a_spawnitemex("quickbonegib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		BMMC BB 2 a_chase
		BMMC B 2 a_chase
		BMMC CC 2 a_chase
		BMMC C 2 a_chase ("melee","missile",CHF_DONTMOVE)
		BMMC DD 2 a_chase
		BMMC D 2 a_spawnitemex("quickbonegib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		BMMC A 15 a_chase ("melee","missile",CHF_DONTMOVE)
		BMMC BB 2 a_chase
		BMMC B 2 a_spawnitemex("quickbonegib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		BMMC CCC 2 a_chase
		BMMC C 2 a_chase ("melee","missile",CHF_DONTMOVE)
		BMMC DD 2 a_chase
		BMMC D 2 a_spawnitemex("quickbonegib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		BMMC D 15 a_chase ("melee","missile",CHF_DONTMOVE)
		loop
	missile:
		TNT1 A 0 a_jumpifcloser (300,"axethrow")
		BMMC E 8 a_facetarget
		BMMC F 6 a_facetarget
		TNT1 A 0 a_playsound ("subweapons/lancethrow")
		BMMC G 1 a_custommissile ("MimicLance")
		BMMC G 10 a_facetarget
		goto realsee
	axethrow:
		TNT1 A 0 a_jump (80,"failaxe")
		BMMC E 8 a_facetarget
		BMMC F 6 a_facetarget
		TNT1 A 0 a_playsound("subweapons/hatchetthrow")
		BMMC G 1 a_custommissile ("MimicAxe")
		BMMC G 10 a_facetarget
		goto realsee
	failaxe:
		BMMC G 10 a_facetarget
		BMMC F 8 a_facetarget
		TNT1 A 0 a_playsound ("subweapons/hatchetthrow")
		BMMC E 1 a_custommissile ("MimicAxe",38,20,180)
		BMMC E 15
		goto pain
	Melee:
		BMMC E 10 a_facetarget
		TNT1 A 0 A_PlaySound("sword/attack1")
		TNT1 A 0 a_playsound ("Mimic/BlazMelee",CHAN_VOICE)
		BMMC F 6 a_facetarget
		BMMC G 1 A_CustomMeleeAttack(Random(1,3)*10, "weapons/vblhit")
		BMMC G 5
		goto realsee
	Pain:
        BMMC H 6 A_Pain
		Goto realSee
	death:
		BMMC H 2
		TNT1 A 0 a_scream
		TNT1 A 0 a_playsound ("skeleton/gib",0,1,0,0.6)
		TNT1 AAAAAAAAAAAAA 0 a_spawnitemex ("SkellytunSkullDeath",random(-16,16),random(-16,16),42,random(-100,100)/20.0,random(-100,100)/20.0,random(-100,100)/20.0,0)
		TNT1 AAAAAAAAA 0 a_spawnitemex("bonegib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		TNT1 AAAAAA 0 a_spawnitemex("bonegib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		ISKL AAAAAAA 0 a_spawnitemex("hipbonegib",0,0,32,random(-10,10),random(-10,10),10)
		ISKL AAAAA 0 a_spawnitemex("ribbonegib",0,0,32,random(-10,10),random(-10,10),12)
		TNT1 A 1
		stop
	chaosexplode:
		BMMC A 6 a_facetarget
		BMMC H 10 a_pain
		BMMC A 5 a_facetarget
		BMMC H 8 a_pain
		BMMC A 4 a_facetarget
		BMMC H 5 a_pain
		TNT1 A 0 a_scream
		TNT1 A 0 a_spawnitemex("skellytun",0,0,12,random(-6,6),random(-8,8),random(6,10),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_playsound ("bonelord/explode",0,1,0,0.6)
		TNT1 A 0 Radius_Quake (4,20,0,32,0)
		TNT1 AAAAAAAAAAAAA 0 a_spawnitemex ("SkellytunSkullDeath",random(-16,16),random(-16,16),42,random(-100,100)/20.0,random(-100,100)/20.0,random(-100,100)/20.0,0)
		TNT1 AAAAAAAAA 0 a_spawnitemex("bonegib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		TNT1 AAAAAA 0 a_spawnitemex("bonegib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		ISKL AAAAAAA 0 a_spawnitemex("hipbonegib",0,0,32,random(-10,10),random(-10,10),10)
		ISKL AAAAA 0 a_spawnitemex("ribbonegib",0,0,32,random(-10,10),random(-10,10),12)
		TNT1 A 20
		stop
	}
}

actor mimiclance
{
    +notimefreeze
	+BLOODSPLATTER
	+FORCEXYBILLBOARD	
	Radius 11
	Height 8
	Speed 15
	Damage (20)
	Projectile
	states
	{
	spawn: 
		LNCE A 8
		TNT1 A 0 a_jump (100,"failLance")
		goto flight
	FailLance:
		LNCE A 1 a_changeflag ("nogravity",0)
		loop
	flight:
		LNCE A 1
		loop
	death:
		TNT1 A 0 a_playsound ("subweapons/miss")
		SWMS ABC 3 bright
		stop
	Crash:
		TNT1 A 0 a_playsound ("subweapons/miss")
		SWMS ABC 3 bright
		stop
	xdeath:
		TNT1 A 0 a_playsound ("subweapons/hit")
		SWHT ABC 3 bright
		stop
	}
}

actor MimicAxe
{
	+notimefreeze
	+BLOODSPLATTER
	projectile
	+doombounce
	-nogravity
	+FORCEXYBILLBOARD	
	+LOOKALLAROUND
	+thruspecies
	seesound "cannon/lilclang"
	Gravity 0.40
	BounceCount 2
	BounceFactor 1.20  
	Radius 14
	scale 0.80
	Damage (30)
	Speed 20
	states
	{
	spawn:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("silence", CHAN_VOICE)
	flying:
		HATC ABCDEF 2
		loop
	death:
		TNT1 A 0 a_changeflag ("nogravity", 1)
		TNT1 A 0 a_playsound ("subweapons/miss")
		SWMS ABC 3 bright
		stop
	Crash:
		TNT1 A 0 a_changeflag ("nogravity", 1)
		TNT1 A 0 a_playsound ("subweapons/miss")
		SWMS ABC 3 bright
		stop
	xdeath:
		TNT1 A 0 a_changeflag ("nogravity", 1)
		TNT1 A 0 a_playsound ("subweapons/hit")
		SWHT ABC 3 bright
		stop
	}
}
