//==SUPER SHOTGUN==
//Blaz gets an enhancement to his power sword that returns mana
//on strike
//Doomslayer gets the Thunderbuss, a portable, powerful cannon
//that blasts foes with electrical shot


Actor GMOTASSG : custominventory replaces supershotgun
{
	Radius 14
	Height 14
    +DONTGIB
	+quiet
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 1
        TNT1 A 0 a_custommissile ("BlazChargerSprite",0,0,0,CMF_AIMDIRECTION)
        TNT1 A 0 a_custommissile ("DoomslayerSSGSprite",0,0,0,CMF_AIMDIRECTION)
	spawn1:
		ITRO ABCDEFGH 1 Bright
		loop
	Pickup:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory ("IamLordBlaz",1,"BlazGlove")
		TNT1 A 0 A_JumpIfInventory ("IamDoomSlayer",1,"DoomSlayerSSG")
		TNT1 A 1
		stop
	BlazGlove:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 a_setblend (FFFF00,0.1,5)
		TNT1 A 0 a_playsound ("powerups/upgrade",CHAN_ITEM)
		TNT1 A 0 ACS_NamedExecuteAlways("WeaponLog",0,2,0,0)			
		//TNT1 A 0 a_log ("Arcane charger!")
		TNT1 A 0 a_jumpifinventory ("swordcharger", 1, "nohelpblaz")
		TNT1 A 0 a_print ("Power sword attacks return mana!")
	nohelpblaz:
		TNT1 A 0
		TNT1 A 0 a_giveinventory ("swordcharger", 1)
		TNT1 A 1 a_giveinventory ("arcaneforce", 6)
		stop
	DoomslayerSSG:
		TNT1 A 0
		TNT1 A 0 ACS_NamedExecuteAlways("WeaponLog",0,2,0,0)			
		//TNT1 A 0 a_log ("You got the Thunderbuss cannon!")
		TNT1 A 0 a_playsound ("misc/w_pkup",CHAN_ITEM)
		TNT1 A 0 a_setblend (FFFF00,0.1,5)
		TNT1 A 0 a_giveinventory ("maceorbs",6)
		TNT1 A 0 a_giveinventory ("thunderbuss",1)
		TNT1 A 0 a_giveinventory ("GotThunderbuss",1)
		TNT1 A 1
		stop
	}
}

actor swordcharger : inventory
{inventory.maxamount 1}

actor GotThunderbuss : inventory
{
	+UNTOSSABLE
	inventory.maxamount 1
}


actor BlazChargerSprite :GMOTAweaponsprite
{
    VisibleToPlayerClass LordBlaz
    States
    {
	spawn:
		TNT1 A 0
		ACHR A 1 bright
		TNT1 A 0 a_warp (AAPTR_TARGET,0,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
		TNT1 A 0 a_checkflag ("SPECIAL","spawn",AAPTR_TARGET)
		ACHR A 1 bright
		goto death
	Death:
		TNT1 A 0
		TNT1 A 1 
		stop
    }
}

actor DoomSlayerSSGSprite : GMOTAweaponsprite
{
    VisibleToPlayerClass DoomSlayer
    States
    {
	spawn:
		TNT1 A 0
		TBPU A 1 bright
		TNT1 A 0 a_warp (AAPTR_TARGET,0,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
		TNT1 A 0 a_checkflag ("SPECIAL","spawn",AAPTR_TARGET)
		TBPU A 1 bright
		goto death
	death:
		TNT1 A 1
		stop
	}
}

