//===========================================================================
//
// Roaming Mine
//
//===========================================================================

ACTOR MinenRobot : NaziRobot
{
	Obituary "$OB_MINE"
	Scale 0.85
	Health 100
	Speed 15
	Radius 16
	Height 40
	Painchance 0
	DropItem BOCE3
	DropItem BonusShard, 156
	Mass 600
	Deathsound "weapons/LW6/explode"
	Seesound "enemies/robots/FS1"
	+NOBLOOD
	+FLOAT
	+NOGRAVITY
	+FLOATBOB
	+SPAWNFLOAT
		States
		{
		Spawn:
			TNT1 A 0 A_PlaySound("enemies/robots/fly1",1,1,1,1)
			RB01 IJKLMNOABCDEFGH 2 A_Look
			loop
		See:
			RB01 JKLMNOABCDEFGHI 2 A_Chase
			loop
		Melee:
			TNT1 A 0 A_Die
		Death:
			TNT1 A 0 A_ChangeFlag("FLOATBOB",0)
			LWXP A 4 BRIGHT A_NoBlocking
			LWXP B 4 BRIGHT A_Scream
			LWXP C 4 BRIGHT A_Explode(50,120)
			LWXP DEFGHIJKLM 3 BRIGHT
			TNT1 A 0 A_StopSound(1)
			stop
	}
}

//===========================================================================
//
// Hovering Drone
//
//===========================================================================

ACTOR HoveringDrone : NaziRobot
{
	Health 100
	Painchance 255
	Speed 4
	Radius 23
	Height 53
	Mass 300
	Monster
	+NOGRAVITY
	+DROPOFF
	-FLOORCLIP
	+NOBLOOD
	+NOBLOCKMONST
	+MISSILEMORE
	+FLOATBOB
	+SPAWNFLOAT
	+LOOKALLAROUND
	+NEVERRESPAWN
	MinMissileChance 150
	DropItem BOCE3
	DropItem BonusShard, 156
	Seesound "enemies/robots/FS1"
	DeathSound "sentinel/death"
	Obituary "$OB_SENTINEL"
	States
	{
	Spawn:
		TNT1 A 0 A_PlaySound("enemies/robots/fly2",1,1,1,1)
		RB02 A 2 A_Look
		Loop
	See:
		RB02 A 3 A_FastChase
		Loop
	Missile:
		RB02 B 2 A_FaceTarget
		RB02 C 4 Bright A_CustomMissile("SentinelLaZZer")
		RB02 C 20 A_FaceTarget
		RB02 C 2 Bright A_SentinelRefire
		Goto See
	Pain:
		RB02 D 1 A_Pain
		Goto See
	Pain.Melee:
		TNT1 A 0 A_PlaySound("robots/pain/melee")
		RB02 D 1 A_Pain
		Goto See
	Death:
		TNT1 A 0 A_ChangeFlag("FLOATBOB",0)
		RB02 D 5 A_Fall
		RB02 E 6 Bright
		RB02 F 3 Bright A_Scream
		RB02 GH 2 Bright
		TNT1 A 0 A_PlaySound ("weapons/LW6/explode",6)
		TNT1 A 0 A_SpawnItem("Detonation3")
		RB02 I 2 
		RB02 J 3 A_StopSound(1)
		Stop
	}
}

//===========================================================================
//
// Spike Ball
//
//===========================================================================

ACTOR SpikeBall : NaziRobot
{
	obituary "$OB_MINE"
	Scale 0.35
	Health 100
	Speed 2
	radius 16
	height 40
	painchance 50
	mass 600
	DropItem BOCE3
	DropItem BonusShard, 156
	Damage 3
	Deathsound "weapons/LW6/explode"
	Seesound "enemies/robots/FS1"
	-FLOORCLIP
	+NOBLOOD
	+FLOAT 
	+NOGRAVITY 
	+MISSILEMORE 
	+DONTFALL
	+FLOATBOB
	+SPAWNFLOAT
	+NOICEDEATH
	states
	{
		Spawn:
			TNT1 A 0 A_PlaySound("enemies/robots/fly3",1,0.6,1,1)
			RB00 ABCDEF 2 A_Look
			loop
		See:
			RB00 ABCDEF 2 A_Chase
			loop
		Missile:
			RB00 G 2
			RB00 H 2 A_PlaySound("enemies/robots/spike1",7)
			RB00 IJK 2 A_FaceTarget
			RB00 LMNOPQ 3 A_FaceTarget
			RB00 Q 3 A_SkullAttack
			Goto Missile+2
		Pain:
			RB00 R 3 A_PlaySound("enemies/robots/spike2",7)
			RB00 S 3
			RB00 T 3 A_Pain
			Goto See
		Pain.Melee:
			TNT1 A 0 A_PlaySound("robots/pain/melee")
			RB00 R 3 A_PlaySound("enemies/robots/spike2",7)
			RB00 S 3
			RB00 T 3 A_Pain
			Goto See
		Death:
			TNT1 A 0 A_ChangeFlag("FLOATBOB",0)
			LWXP A 4 BRIGHT A_NoBlocking
			LWXP B 4 BRIGHT A_Scream
			LWXP C 4 BRIGHT A_Explode(50,120)
			LWXP DEFGHIJKLM 3 BRIGHT
			TNT1 A 0 A_StopSound(1)
			Stop
	}
}

//===========================================================================
//
// Shooter Drone
//
//===========================================================================

ACTOR ShooterDrone : NaziRobot
{
	-FLOORCLIP
	+NOBLOOD
	+FLOAT
	+FLOATBOB
	+SPAWNFLOAT
	+NOGRAVITY 
	+MISSILEMORE 
	+DONTFALL 
	+NOICEDEATH
	obituary "$OB_MINE"
	Scale 0.75
	Health 100
	Speed 2
	radius 16
	height 40
	painchance 50
	mass 600
	DropItem BonusShard, 156
	Damage 3
	Deathsound "weapons/LW6/explode"
	Seesound "enemies/robots/FS1"
	States
	{
		Spawn:
			TNT1 A 0 A_PlaySound("enemies/robots/fly3",1,0.3,1,1)
			RB66 A 1 A_Look
			loop
		See:
			RB66 A 1 A_Chase
			RB66 A 1 A_FastChase
			RB66 A 1 A_Chase
			RB66 A 1 A_FastChase
			RB66 A 1 A_Chase
			RB66 A 1 A_FastChase
			RB66 A 1 A_Chase
			Loop
		Wander:
			RB66 A 1 A_Wander
			RB66 A 1 A_FastChase
			RB66 A 1 A_Wander
			RB66 A 1 A_FastChase
			RB66 A 1 A_Wander
			RB66 A 1 A_FastChase
			RB66 A 1 A_Wander
			Loop
		Missile:
			RB66 A 2 A_FaceTarget
			RB66 A 1 A_FastChase
			RB66 B 2 A_FaceTarget
			RB66 A 1 A_FastChase
			RB66 A 2 A_FaceTarget
			TNT1 A 0 A_PlaySound("enemies/nazi4/machinegun")
			RB66 C 2 BRIGHT A_CustomMissile("T1F4S4",20,6,frandom(3,-3))
			RB66 A 2 A_FaceTarget
			TNT1 A 0 A_PlaySound("enemies/nazi4/machinegun")
			RB66 C 2 BRIGHT A_CustomMissile("T1F4S4",20,6,frandom(3,-3))
			RB66 A 2 A_FaceTarget
			TNT1 A 0 A_PlaySound("enemies/nazi4/machinegun")
			RB66 C 2 BRIGHT A_CustomMissile("T1F4S4",20,6,frandom(3,-3))
			RB66 A 2 A_FaceTarget
			TNT1 A 0 A_PlaySound("enemies/nazi4/machinegun")
			RB66 C 2 BRIGHT A_CustomMissile("T1F4S4",20,6,frandom(3,-3))
			RB66 A 2 A_FaceTarget
			TNT1 A 0 A_PlaySound("enemies/nazi4/machinegun")
			RB66 C 2 BRIGHT A_CustomMissile("T1F4S4",20,6,frandom(3,-3))
			RB66 A 2 A_FaceTarget
			TNT1 A 0 A_PlaySound("enemies/nazi4/machinegun")
			RB66 C 2 BRIGHT A_CustomMissile("T1F4S4",20,6,frandom(3,-3))
			TNT1 A 0 A_Jump(96,"Wander")
			Goto Missile+1
		Pain:
			RB66 D 3
			RB66 E 3
			RB66 D 3 A_Pain
			Goto See
		Pain.Melee:
			TNT1 A 0 A_PlaySound("robots/pain/melee")
			RB66 D 3
			RB66 E 3
			RB66 D 3 A_Pain
			Goto See
		Death:
			TNT1 A 0 A_ChangeFlag("FLOATBOB",0)
			RB66 D 1 BRIGHT A_StopSound(1)
			RB66 D 1 BRIGHT A_Fall
			RB66 E 1 BRIGHT A_Scream
			RB66 E 8 BRIGHT A_NoBlocking
			RB66 F 4 BRIGHT
			RB66 G 4 BRIGHT
			RB66 H 4 BRIGHT
			LWXP A 4 BRIGHT
			LWXP B 4 BRIGHT
			LWXP C 4 BRIGHT A_Explode(50,60)
			LWXP DEFGHIJKLM 3 BRIGHT
			TNT1 A 0 A_StopSound(1)
			Stop
	}
}
