//==============================================================================
//
// Panzerwalker (a.k.a. Gepanzer-Wanderer)
//
//==============================================================================

ACTOR Panzerwalker : NaziRobot
{
	Health 500
	Radius 31
	Height 56
	Scale 0.7
	Mass 1000
	Speed 8
	PainChance 80
	DropItem BonusShard, 156
	seesound "panzerwalker/sight"
	painsound "panzerwalker/pain"
	deathsound "panzerwalker/death"
	activesound "panzerwalker/active"
	obituary "%o was eviscerated by a Gepanzer-Wanderer."
	+NOBLOOD
	+BOSSDEATH
	States
	{
	Spawn:
		Look:
			RB05 A 5 A_Look
			loop
		See:
			RB05 A 4 A_Chase
			RB05 B 4 A_Chase
			TNT1 A 0 A_PlaySound("panzerwalker/walk")
			RB05 C 8 A_Chase
			RB05 D 4 A_Chase
			RB05 E 4 A_Chase
			RB05 F 8 A_Chase
			Loop
		Wander:
			RB05 A 4 A_Wander
			RB05 B 4 A_Wander
			TNT1 A 0 A_PlaySound("panzerwalker/walk")
			RB05 C 8 A_Wander
			RB05 D 4 A_Wander
			RB05 E 4 A_Wander
			RB05 F 8 A_Wander
			Goto Look
		Missile:
			RB05 G 5 BRIGHT A_FaceTarget
			RB05 H 5 BRIGHT A_CustomMissile("redgrenadeweak",48,-17,0)
			Goto Wander
		Pain:
			RB05 I 1 A_Pain
			goto See
		Pain.Melee:
			TNT1 A 0 A_PlaySound("robots/pain/melee")
			RB05 I 1 A_Pain
			goto See
		Death:
			RB05 I 1 A_Scream
			RB95 H 5 A_NoBlocking
			RB95 I 5 
			RB95 JKL 5
			RB95 M -1
			Stop
		Raise:
			RB95 MLKJIHG 5
			Goto See
	}
}

//==============================================================================
//
// Wehrmacht Laser Roboter made by Koto
//
//==============================================================================

ACTOR LaserRoboter : NaziRobot
{
	Health 500
	Radius 31
	Height 56
	Scale 0.95
	Mass 500
	Speed 8
	PainChance 80
	DropItem BonusShard, 156
	seesound 		"laserroboter/sight"
	painsound 		"panzerwalker/pain"
	deathsound 		"android/death"
	activesound 	""
	obituary "%o was disintegrated by a Wehrmacht-LaserRoboter."
	+NOBLOOD
	+BOSSDEATH
	+QUICKTORETALIATE
	States
	{
		Spawn:
			WMLR A 5 A_Look
			loop
		See:
			WMLR B 4 A_PlaySound("panzerwalker/walk")
			WMLR CDC 4 A_Chase
			Loop
		Wander:
			WMLR B 4 A_PlaySound("panzerwalker/walk")
			WMLR CDC 4 A_Chase
			Goto See
		Missile:
			WMLR E 5 A_FaceTarget
			WMLR F 5 BRIGHT A_CustomMissile("WeakRedstar",48,-16,0)
			WMLR E 5 A_FaceTarget
			Goto Wander
		Pain:
			WMLR G 3
			WMLR G 3 A_Pain
			goto See
		Pain.Melee:
			TNT1 A 0 A_PlaySound("robots/pain/melee")
			WMLR G 3
			WMLR G 3 A_Pain
			goto See
		Death:
			WMLR G 3
			WMLR H 1 A_Scream
			WMLR I 5 A_NoBlocking
			WMLR J 5 
			WMLR K 5
			WMLR LMN 5
			WMLR O 20
			WMLR LMN 5
			WMLR O 10
			WMLR LMN 5
			WMLR O -1 A_Die
			Stop
		XDeath:
			WMLR P 4
			WMLR Q 4 A_Scream
			WMLR R 4
			TNT1 A 0 A_PlaySound("misc/explosion")
			WMLR S 4
			WMLR T 4 A_NoBlocking
			WMLR U 4
			WMLR V 4
			WMLR W -1 A_Die
		Raise:
			WMLR ONMLKJIHG 5
			Goto See
	}
}
