//==============================================================================
// Cross Akimbo 3: MP-86 and STG-60
//==============================================================================

ACTOR HDCrossAkimbo3 : KriegslandMediumWeapon
{
	+INVENTORY.UNDROPPABLE
	+WEAPON.NO_AUTO_SWITCH
	Weapon.SelectionOrder 1100
	Weapon.SlotNumber 9
	Weapon.AmmoUse  0
	Weapon.AmmoGive 0
	Weapon.AmmoType "BOCL1"
	Inventory.Pickupmessage "You got another Maschinenpistole 86s!"
	Obituary "%o does \"Mein Leben\" all over the place from %k's Dual machineguns."
	Tag "Cross Machineguns"
	Scale 0.5
	States
	{
	Deselect:
		TNT1 A 0 A_Gunflash("LightDone")
		CA3R CBA 1
		TNT1 A 0 A_TakeInventory("FireRight",1)
		TNT1 A 1 A_Lower
		Wait 
	Ready:
		CA3R ABC 1
		TNT1 A 0 A_TakeInventory("StopDualWield", 1)
		TNT1 A 0 A_GunFlash
		Goto ReadyToFire
	ReadyToFire:
		TNT1 A 0 A_JumpIfInventory("FiredPrimary",1,"FireLeftGun") //Check if player wants to reload
		WCLG A 1 A_WeaponReady(WRF_ALLOWZOOM)// Weapon is ready to fire
		TNT1 A 0 A_JumpifInventory("IsBombing",1,"ThrowGrenade")
		NULL A 0 A_JumpIfInventory("SlidePlayer",1,"IsSliding")
		TNT1 A 0 A_JumpIfInventory("IsKnifing",1,"Knife")
		TNT1 A 0 A_JumpifInventory("IsKicking",1,"Kick")
		Loop
	Fire:
		TNT1 A 0 A_JumpIfInventory("FiredPrimary",1,"FireLeftGun")
		WCLG A 1
		TNT1 A 0 A_JumpifInventory("IsKicking",1,"Kick")
		TNT1 A 0 A_JumpIfInventory("IsKnifing",1,"Knife")
		NULL A 0 A_JumpIfInventory("SlidePlayer",1,"IsSliding")
		TNT1 A 0 A_JumpifInventory("IsBombing",1,"ThrowGrenade")
		TNT1 A 0 A_JumpIfInventory("FiredPrimary",1,"FireLeftGun")
		Goto ReadyToFire
	Select:
		TNT1 A 0 A_Playsound("weapons/generic/select4",7)
		TNT1 A 1 Offset(67, 100)
		TNT1 A 0 A_Raise
		TNT1 A 1 Offset(54, 81)
		TNT1 A 0 A_Raise
		TNT1 A 1 Offset(32, 69)
		TNT1 A 0 A_Raise
		TNT1 A 1 Offset(22, 58)
		TNT1 A 0 A_Raise
		TNT1 A 1 Offset(10, 47)
		TNT1 A 0 A_Raise
		TNT1 A 1 Offset(7, 39)
		TNT1 A 0 A_Raise
		TNT1 A 1 Offset(2, 34)
		TNT1 A 0 A_Raise
		Wait
	FireLeftGun:
		TNT1 A 0 A_JumpIfInventory("BOCL1",1,1)
		Goto Dryfire
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		TNT1 A 0 A_Playsound("weapons/SMP/fire",6)
		TNT1 A 0 A_TakeInventory("BOCL1",1)
		TNT1 A 0 A_AlertMonsters
		TNT1 A 0 A_FireBullets(7, 7, -1, 8,"Bullet_Puff")
		TNT1 A 0 A_FireCustomMissile("FKLightCasingL",345+random(-8,8),0,-4,-5,0)
		TNT1 A 0 A_FireCustomMissile("GunSmokeSpawner",0,0,-10,0,0,0)
		TNT1 A 0 Radius_Quake(2, 2, 0, 1, 0)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		WCLF A 1 Bright
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("RecoilToggle")==0,2)
		TNT1 A 0 A_SetPitch(pitch -0.9)
		WCLG B 1 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		WCLG A 1 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		WCRG AAA 0 A_JumpIfInventory("FiredPrimary",1,"FireLeftGun")
		Goto ReadyToFire
	FireRightGun:
		TNT1 A 0 A_JumpIfInventory("StopDualWield", 1, "LightDone")
		TNT1 A 0 A_GiveInventory("IsFiringSecondary", 1)
		TNT1 A 0
		TNT1 A 0 A_TakeInventory("FiredSecondary",1)
		TNT1 A 0 A_JumpIfInventory("BOHC1",1,1)
		Goto Dryfire
		TNT1 A 0 A_Playsound("weapons/STG/fire",1)
		TNT1 A 0 A_TakeInventory("BOHC1",1)
		TNT1 A 0 A_AlertMonsters
		TNT1 A 0 A_FireBullets(5.6, 5.6, -1, 9,"Bullet_Puff",1)
		TNT1 A 0 A_FireCustomMissile("FKHeavyCasingSpawn",345+random(-8,8),0,-4,-5,0)
		TNT1 A 0 A_FireCustomMissile("GunSmokeSpawner",0,0,10,0,0,0)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		TNT1 A 0 Radius_Quake(2, 2, 0, 1, 0)
		W5RF A 1 BRIGHT
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("RecoilToggle")==0,2)
		TNT1 A 0 A_SetPitch(pitch -0.9)
		W5RG C 1 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		W5RG B 1 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		W5RG A 1 A_JumpIfInventory("StopDualWield", 1, "LightDone")
		TNT1 A 0 A_TakeInventory("IsFiringSecondary",1)
		W5LG AAA 0 A_JumpIfInventory("FiredSecondary",1,"FireRightGun")
		Goto Flash
	Dryfire:
		TNT1 A 0 A_Print("No ammo",1)
		TNT1 A 0 A_TakeInventory("IsFiringSecondary",1)
		TNT1 A 0 A_TakeInventory("FiredSecondary",1)
		CA3B A 1 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		TNT1 A 0 A_GunFlash
		Goto ReadyToFire
	Zoom:
		TNT1 A 0 A_Gunflash("LightDone")
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		CA3B A 2 A_SelectWeapon("HDChaingun")
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		Goto ReadyToFire
	Kick:
		TNT1 A 0 A_Gunflash("LightDone")
		CA3R CBA 1
		TNT1 A 2
		KICF A 1 Offset(-10,32)
		KICF CE 1
		KICF FG 1 A_Recoil(-1)
		TNT1 A 0 A_Jump(128,2)
		TNT1 A 0 A_PlaySound("FKPlayer/Grunt")
		KICF H 5 A_CustomPunch(6,0,0,"FightPuff") 
		KICF IGFEDC 1 
		KICF BA 1 A_Recoil(+0.5)
		TNT1 A 2
		CA3R ABC 1
		TNT1 A 0 A_Gunflash
		Goto ReadyToFire
	IsSliding:
		TNT1 A 0 A_Gunflash("LightDone")
		TNT1 A 0 A_TakeInventory("SlidePlayer",1)
		TNT1 A 0 A_JumpIfInventory("CrouchPlayer",1,"Ready")
		CA3R CBA 1
		TNT1 A 0 A_PlaySound("FKPlayer/slide/start",4)
		TNT1 A 0 A_PlaySound("FKPlayer/slide/loop",5,0.5,TRUE)
		TNT1 A 0 A_SetPitch(pitch+0.8)
		SLDK ABCDEF 2
		TNT1 A 0 A_SetPitch(pitch-0.8)
		SLDK G 6 A_FireCustomMissile("KickAttack",0,0,0,0)
		TNT1 A 0 A_StopSound(5)
		TNT1 A 0 A_PlaySound("FKPlayer/slide/end",6)
		SLDK HI 2
		Goto Ready
	Knife:
		TNT1 A 0 A_Gunflash("LightDone")
		CA3R CBA 1
 		NULL A 0 Offset(-10,32)
		NULL A 3
		WP1L AB 1
		NULL A 0 A_Jump(86,2)
		NULL A 0 A_PlaySound("FKPlayer/Grunt")
		WP1L C 1 A_CustomPunch(8,0,0,"KnifePuff")
		WP1L DEF 1
		NULL A 3
		CA3R ABC 1
		TNT1 A 0 A_Gunflash
		Goto ReadyToFire
	Throwgrenade:
		TNT1 A 0 A_Gunflash("LightDone")
		TNT1 A 0 A_JumpIf(waterlevel>2,"Dryfire")
		TNT1 A 0 A_JumpIfInventory("BOGR1",1,1)
		Goto Dryfire
		CA3R CBA 1
		TNT1 A 0 A_StopSound(1)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		MND2 A 1 Offset(0,28)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		MND2 B 1 Offset(0,24)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		MND2 C 1 Offset(0,23)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		MND2 D 1 Offset(0,26) A_PlaySound("weapons/SHG/throw")
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		MND2 D 1 Offset(0,28)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		TNT1 A 0 A_SpawnItemEx("RealGrenade",0,1,24,cos(pitch)*40,0,sin(-pitch)*40,3,SXF_TRANSFERPITCH|SXF_NOCHECKPOSITION)
		TNT1 A 0 A_TakeInventory("BOGR1",1)
		MND2 E 1 Offset(0,30)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		MND2 E 1 Offset(0,31)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		MND2 F 1 Offset(0,32)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		MND2 F 1 Offset(0,33)
		TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSecondary|WRF_NoSwitch)
		TNT1 A 0 A_TakeInventory("GetOnWithIt", 100)
		TNT1 A 0 A_JumpIfNoAmmo("Dryfire")
		TNT1 A 7 Offset (75, 152)
		TNT1 A 1 Offset (6, 42)
		Goto Ready
	Flash:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("StopDualWield", 1, "LightDone")
		W5RG A 1
		TNT1 A 0 A_JumpIfInventory("FiredSecondary", 1, "FireRightGun")
		Loop
	DontFlash:
		TNT1 A 1
		Goto Flash
 	Spawn:
		WPCP A -1
		Stop
	}
}