Actor BarnacleSOD : QCDE_MonsterMedium
{ Tag "Barnacle Wilhelm"
  Health 650
  Radius 30
  Height 62
  Speed 16
  Mass 1000
  PainChance 20
  Species "Nazi"
  Monster
  +FLOORCLIP
  +CANPASS
  +DONTHURTSPECIES
  +THRUSPECIES
  SeeSound "Barn/Sight"
  PainSound "Trans/Pain"
  DeathSound "Barn/Death"
  Obituary "%o was perforated by Barnacle Wilhelm."
  HitObituary "%o was perforated by Barnacle Wilhelm."
  States
   {
   Idle:
     BARN A 4 A_Look
     Loop
   See:
     BARN AABBCCDD 6 A_Chase
     Loop
   Missile:
     BARN E 4 Bright A_FaceTarget
     BARN F 0 A_PlayweaponSound ("Barn/Missile/Fire")
     BARN F 4 Bright A_CustomMissile ("BarnRocket", 40, 15, 0, 0, 0)
     BARN E 4 Bright A_FaceTarget
     BARN G 0 Bright A_PlaySound("Barn/Chain/Shot", CHAN_WEAPON)
     BARN G 6 Bright A_CustomMissile("WolfEnemyBulletD4")
     BARN H 0 Bright A_PlaySound("Barn/Chain/Shot", CHAN_WEAPON)
     BARN H 6 Bright A_CustomMissile("WolfEnemyBulletD5")
     BARN G 0 Bright A_PlaySound("Barn/Chain/Shot", CHAN_WEAPON)
     BARN G 6 Bright A_CustomMissile("WolfEnemyBulletD5")
     BARN H 0 Bright A_PlaySound("Barn/Chain/Shot", CHAN_WEAPON)
     BARN H 6 Bright A_CustomMissile("WolfEnemyBulletD6")
     BARN H 0 Bright A_CPosRefire
     Goto Missile
   Pain:
     BARN I 6 A_Pain
     Goto See
   DeathChecksDone:
     BARN J 8 A_Scream
     BARN J 8
     BARN K 8
     BARN L 6 A_Fall
   Death.Corpse:
     BARN M -1
     Stop
   XDeathChecksDone:
     TNT1 A 0 A_PlaySound("quake2/Misc/GibExplosion")
     TNT1 A 0 A_SpawnItemEx("GibDropperMediumBig",0,0,28,0,0,0,0,SXF_NOCHECKPOSITION|SXF_USEBLOODCOLOR)
     Goto DeathChecksDone
   Raise:
     TNT1 A 0 ACS_NamedExecuteAlways("QCDE_DamageTracker",0,1)
     BARN MLKJ 6
     Goto See
   }
}

Actor BarnRocket
{
 Radius 11
 Height 8
 Speed 14
 Damage 12
 SeeSound "Barn/RSee"
 DeathSound "Barn/Missile/Explo"
 DamageType "RocketDamage"
 Projectile
 +RANDOMIZE
 States
  {
  Spawn:
  WRCK A 1 Bright A_CustomMissile ("WolfRocketSmoke", 0, 0, 0, 0, 0)
  Loop
  Death:
  WEXP A 8 Bright 
  WEXP B 6 Bright
  WEXP C 4 Bright
  Stop
  }
 }