//////////////////////////////
// MANCUBUS					//
//////////////////////////////
ACTOR TheMancubus Replaces Fatso
{
	Health 600
	Radius 48
	Height 64
	Mass 1000
	Speed 8
	PainChance 80
	MONSTER 
	+FLOORCLIP
	+BOSSDEATH
	SeeSound "fatso/sight"
	PainSound "fatso/pain"
	DeathSound "fatso/death"
	ActiveSound "fatso/active"
	Obituary "$OB_FATSO"
	States
	{
	Spawn:
		FATT AB 15 A_Look
	Loop
		
	See:
		FATT AABBCCDDEEFF 4 A_Chase
	Loop
		
	Missile:
		FATT G 20 A_FatRaise
		FATT H 10 BRIGHT A_FatAttack1
		FATT IG 5
		FATT H 10 BRIGHT A_FatAttack2
		FATT IG 5
		FATT H 10 BRIGHT A_FatAttack3
		FATT IG 5
	Goto See
		
	Pain:
		FATT J 3
		FATT J 3 A_Pain
	Goto See

    Death.SmallBullets:
		TNT1 A 0 A_CustomMissile("FlyingBlood", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 A 0 A_CustomMissile("FlyingBlood", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 AA 0 A_CustomMissile("ThickBloodSlatter", 20,  0, random(0, 500), 2, random(0, 190))
		FATT K 4
		FATT L 4 A_Scream
		FATT M 4 A_NoBlocking
		FATT NOPQRS 5
		FATT T -1 A_BossDeath    
	Stop
		
    Death:
		TNT1 AAA 0 A_CustomMissile("FlyingBlood", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 AA 0 A_CustomMissile("UniversalBloodSlatter", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 AAA 0 A_CustomMissile("ThickBloodSlatter", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 AA 0 A_CustomMissile("FlyingBlood", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 AAA 0 A_CustomMissile("ThickBloodSlatter", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 AA 0 A_CustomMissile("GoreChunkSuper", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 A 0 A_Playsound ("BIGDETH", 1, 128, FALSE)
		FATT K 6
		FATT L 6 A_Scream
		FATT M 6 A_NoBlocking
		FATT NOPQRS 6
		FATT T -1 A_BossDeath    
	Stop
	
	XDeath:
		FATT K 1 A_BossDeath
		TNT1 A 0 A_Playsound ("BIGDETH", 1, 128, FALSE)  
		TNT1 A 0 A_CustomMissile("XFatDeath", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 AAA 0 A_CustomMissile("FlyingBlood", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 AAA 0 A_CustomMissile("UniversalBloodSlatter", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 AAA 0 A_CustomMissile("ThickBloodSlatter", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 AA 0 A_CustomMissile("ThickBloodSlatter", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 A 0 A_CustomMissile("XDeathMonster", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 A 0 A_CustomMissile("XDeathMonster2", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 A 0 A_CustomMissile("IntestinalGutsFlying", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 A 0 A_CustomMissile("RibsFlying", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 A 0 A_CustomMissile("OrgansFlying", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 A 0 A_CustomMissile("TorsoFlying", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 A 0 A_CustomMissile("OrgansFlying", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 A 0 A_CustomMissile("TorsoFlying", 20,  0, random(0, 500), 2, random(0, 190))
		TNT1 A 0 A_CustomMissile("GoreChunk2", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 A 0 A_CustomMissile("GoreChunk1", 20,  0, random(0, 360), 2, random(0, 90))
		TNT1 A 0 A_CustomMissile("GoreChunkSuper", 20,  0, random(0, 360), 2, random(0, 90))
	Stop
		 
	 Raise:
		FATT R 5
		FATT QPONMLK 5
	Goto See
	}
}

///////////////////////////////////////
ACTOR XFatDeath
{
	Radius 8
	Height 8
	Mass 1
	Speed 8
	+NOBLOCKMAP
	+MISSILE
	+NOTELEPORT
	+BOUNCEONCEILINGS
	+MOVEWITHSECTOR
	-DONTSPLASH
	+THRUGHOST
	DeathSound "LILGORE5"
	Decal BloodSuperSplatter
	States
{
	Spawn:
		MCZZ ABCDE 3 A_CustomMissile ("FlyingBloodTrail", 0, 0, random (0, 360), 2, random (0, 360))
	Loop
	
	Death:
		TNT1 A 0 A_SpawnItem("BloodSpot",0,0,0,1)
		TNT1 A 0 A_CustomMissile ("ThickBloodSlatter", 0, 0, random (0, 360), 2, random (0, 360))
		TNT1 A 0 A_CustomMissile ("UniversalBloodSlatter", 0, 0, random (0, 360), 2, random (0, 360))
		MCZZ F -1
	Stop
		
	Splash:
		TNT1 A 0
	Stop
	}
}