actor facehugger replaces lostsoul
{
 bloodcolor orange
 species Xenomorph
 bloodtype BoilerBlood
 health 15
 meleerange 50
 radius 14
 height 14
 mass 20
 speed 18
 painchance 200
 maxstepheight 34
 scale 0.8
 monster
 +FLOAT
 +FLOORCLIP
 +DONTHARMSPECIES
 +DONTHURTSPECIES
 +FASTMELEE
 +FASTER
 +CANBLAST
 +QUICKTORETALIATE
 seesound "face/active"
 activesound "face/active"
 meleesound "face/active"
 deathsound "face/death"
 damagetype "hugger"
 Obituary "%o got facehugged."
 states
 {
  Spawn:
		TNT1 A 1
		// ExecuteAlways, 802, 0, <Threat Level>
		// 1 - Small blip
		// 2 - Medium blip
		// 3 - Large blip
		TNT1 A 0 ACS_ExecuteAlways(802, 0, 2)
		Goto Idle
	Idle:
	HUGG AB 6 A_Look
	TNT1 A 0 A_Jump(120, "Stalk")
	loop
  stalk:
    TNT1 A 0 A_Jump(200, "idle")
	TNT1 A 0 A_JumpIfTargetInLOS("chase", 110)
	HUGG AB 3 A_Look
	TNT1 A 0 A_JumpIfTargetInLOS("chase", 110)
	HUGG CD 3 A_Wander
	TNT1 A 0 A_JumpIfTargetInLOS("chase", 110)
	loop
  see:
	TNT1 A 0 A_JumpIfTargetInLOS("chase", 110)
	goto chase
  hunt:
	HUGG A 0 A_FaceTarget
	HUGG AAABBBCCCDDD 4 A_Chase
	TNT1 A 0 A_JumpIfTargetInLOS("chase", 110)
	loop
  chase:
	TNT1 A 0 A_JumpIfCloser(600, "pounce")
    HUGG AABB 3 A_Chase
	TNT1 A 0 A_FaceTarget
	HUGG CCDD 3 A_Chase
	TNT1 A 0 A_FaceTarget
	TNT1 A 0 A_JumpIfTargetInLOS("chase", 110)
	goto hunt
  pounce:
	HUGG E 2 A_FaceTarget
    HUGG A 0 A_PlaySound ("xeno/attack")
    HUGG A 0 ThrustThingZ (0, 34, 0, 0)
    HUGG A 0 ThrustThing (angle*256/360, 18, 0, 0)
	HUGG A 0 A_CustomMeleeAttack(random(1, 2)*2, "xeno/hack", "xeno/claw", "hugger")
  JumpUp:
    HUGG E 1
  JumpDown:
	TNT1 A 0 A_JumpIfCloser(100, "pounce")
    HUGG E 1 A_CheckFloor ("Land")
    loop
  Land:
    HUGG E 2 A_Stop
    goto see
  pain:
	HUGG E 2 A_Pain
	goto see
  death:
	HUGG F 7 A_Scream
	HUGG G 6
	HUGG H 5 
	HUGG I 4 
	HUGG J 3
	HUGG K 2
	HUGG L 1
	HUGG M -1 A_NoBlocking
	stop
  }
}
  