Actor BruiserDemon : BaronofHell
{
  //$Title "Bruiser Demon"
  //$Category XV117Monsters
  Health 1250
  Radius 24//43spriteW(110%=47)
  Height 81//74spriteH(110%=81)
  Scale 1.1
  Mass 1060
  Speed 6
  PainChance 25
  Monster
  +FloorClip
  +MISSILEMORE
  +NoRadiusDmg
  +DONTHARMSPECIES
  MissileType BruiserBall
  SeeSound "superbaron/scream"
  PainSound "superbaron/pain"
  DeathSound "superbaron/death"
  ActiveSound "superbaron/act"
  MeleeSound "baron/melee"
  Obituary "%o was slaughtered by a Bruiserdemon."
  HitObituary "%o was cremated by a Bruiserdemon."
  Tag "Bruiser Demon"
  MeleeDamage 20
  DropItem "DemonRuneMix" 8
  States
  {
  Spawn:
    BRUS AB 10 Bright A_Look 
    Loop
	
  See:
    BRUS AABBCCDD 3 Bright A_Chase
    Loop
  Melee:
    BRUS E 6 Bright A_FaceTarget
    BRUS F 6 Bright A_FaceTarget
    BRUS G 6 Bright A_ComboAttack
    Goto See
  Missile:
    BRUS E 0 Bright A_Jump(96, 8)//BruiserBall2
    BRUS EF 8 Bright A_FaceTarget
    BRUS G 8 Bright A_MissileAttack
    BRUS G 0 Bright A_Jump(128, 1)//2nd MissileAttack
    Goto See
    BRUS HI 8 Bright A_FaceTarget
    BRUS J 8 Bright A_MissileAttack
    Goto See
    BRUS E 0 Bright A_Jump(64, 20)//BruiserFire
    BRUS E 8 Bright A_FaceTarget
    BRUS F 8 Bright A_FaceTarget
    BRUS F 1 Bright A_Custommissile("BruiserBall2",41,0,-40,0)
    BRUS G 1 Bright A_Custommissile("BruiserBall2",41,0,-30,0)
    BRUS G 1 Bright A_Custommissile("BruiserBall2",41,0,-20,0)
    BRUS G 1 Bright A_Custommissile("BruiserBall2",41,0,-10,0)
    BRUS G 1 Bright A_Custommissile("BruiserBall2",41,0,0,0)
    BRUS G 1 Bright A_Custommissile("BruiserBall2",41,0,10,0)
    BRUS G 1 Bright A_Custommissile("BruiserBall2",41,0,20,0)
    BRUS G 0 Bright A_Jump(128, 1)//2nd BruiserBall2
    Goto See
    BRUS H 8 Bright A_FaceTarget
    BRUS I 8 Bright A_FaceTarget
    BRUS I 1 Bright A_Custommissile("BruiserBall2",41,0,40,0)
    BRUS J 1 Bright A_Custommissile("BruiserBall2",41,0,30,0)
    BRUS J 1 Bright A_Custommissile("BruiserBall2",41,0,20,0)
    BRUS J 1 Bright A_Custommissile("BruiserBall2",41,0,10,0)
    BRUS J 1 Bright A_Custommissile("BruiserBall2",41,0,0,0)
    BRUS J 1 Bright A_Custommissile("BruiserBall2",41,0,-10,0)
    BRUS J 1 Bright A_Custommissile("BruiserBall2",41,0,-20,0)
    Goto See
    BRUS KL 8 Bright A_FaceTarget
    BRUS M 2 Bright A_Custommissile("BruiserFireSpawner",16,0,-15,0)
    BRUS M 2 Bright A_Custommissile("BruiserFireSpawner",16,0,0,0)
    BRUS M 1 Bright A_Custommissile("BruiserFireSpawner",16,0,15,0)
    Goto See
  Pain:
    BRUS N 5 Bright A_Pain
     Goto See
  Death:
    BRUD A 6 Bright A_Scream
	TNT1 AAAA 0 A_CustomMissile ("BloodMistBig", 30, 0, random (0, 360), 2, random (30, 90))
	 TNT1 AAAA 0 A_CustomMissile ("BruiserFire", 30, 0, random (0, 360), 2, random (30, 90))
    BRUD BCD 4 Bright 
	TNT1 AAAA 0 A_CustomMissile ("BloodMistBig", 30, 0, random (0, 360), 2, random (30, 90))
    BRUD EFG 4 Bright
    BRUD H 4 Bright A_Fall
	TNT1 AAAAAA 0 A_CustomMissile ("Xdeath1", 40, 0, random (0, 360), 2, random (0, 160))
	TNT1 AAAAA 0 A_CustomMissile ("Guts2", 32, 0, random (0, 360), 2, random (0, 160))
    BRUD IJKLMNOP 4 Bright
    TNT1 AAA 0 A_CustomMissile ("RocketSmokeTrail52", 2, 0, random (70, 110), 2, random (0, 360))
    TNT1 AAA 0 A_CustomMissile ("ExplosionSmokeFast22", 0, 0, random (0, 360), 2, random (0, 360))
    BRUD QRSTUV 4
	TNT1 AAA 0 A_CustomMissile ("RocketSmokeTrail52", 2, 0, random (70, 110), 2, random (0, 360))
    TNT1 AAA 0 A_CustomMissile ("ExplosionSmokeFast22", 0, 0, random (0, 360), 2, random (0, 360))
    BRUD W -1   
    Stop
	
	XDeath:
	    BRUD A 6 Bright A_Scream
		TNT1 AAAA 0 A_CustomMissile ("Brutal_LiquidBlood2", 26, 0, random (0, 360), 2, random (30, 60))
		TNT1 AAAA 0 A_CustomMissile ("Brutal_LiquidBlood2", 26, 0, random (0, 360), 2, random (10, 40))
		 TNT1 AAAA 0 A_CustomMissile ("BruiserFire", 30, 0, random (0, 360), 2, random (30, 90))
		TNT1 AAAA 0 A_CustomMissile ("Brutal_LiquidBlood2", 6, 0, random (0, 360), 2, random (30, 60))
		TNT1 A 0 A_PlaySound ("misc/xdeath4")
		TNT1 AAAA 0 A_CustomMissile ("XDeath1", 32, 0, random (0, 360), 2, random (0, 40))
		TNT1 AAAA 0 A_CustomMissile ("BloodMistBig", 30, 0, random (0, 360), 2, random (30, 90))
    BRUD BCD 4 Bright 
	TNT1 AAA 0 A_CustomMissile ("XDeath3", 42, 0, random (170, 190), 2, random (10, 60))
		TNT1 A 0 A_CustomMissile ("XDeath2", 42, 0, random (170, 190), 2, random (10, 60))
		TNT1 A 0 A_CustomMissile ("XDeath4", 42, 0, random (170, 190), 2, random (10, 60))
    BRUD EFG 4 Bright
    BRUD H 4 Bright A_Fall
	TNT1 AAAAAA 0 A_CustomMissile ("Xdeath1", 40, 0, random (0, 360), 2, random (0, 160))
	TNT1 AAAAA 0 A_CustomMissile ("Guts2", 32, 0, random (0, 360), 2, random (0, 160))
    BRUD IJKLMNOP 4 Bright
    TNT1 AAA 0 A_CustomMissile ("RocketSmokeTrail52", 2, 0, random (70, 110), 2, random (0, 360))
    TNT1 AAA 0 A_CustomMissile ("ExplosionSmokeFast22", 0, 0, random (0, 360), 2, random (0, 360))
    BRUD QRSTUV 4
	TNT1 AAA 0 A_CustomMissile ("RocketSmokeTrail52", 2, 0, random (70, 110), 2, random (0, 360))
    TNT1 AAA 0 A_CustomMissile ("ExplosionSmokeFast22", 0, 0, random (0, 360), 2, random (0, 360))
    BRUD W -1   
    Stop
  }
}

Actor BruiserBall
{
  Radius 16
  Height 16
  Speed 18
  Damage 5
  Projectile
  +Randomize
  RenderStyle "ADD"
  Alpha 0.9
  SeeSound "imp/attack"
  DeathSound "imp/shotx"
  DamageType Fire
  Decal Scorch
  States
  {
  Spawn: 
    BRBA AABB 2 Bright A_SpawnItemEx("BruiserBallTrail", 0, 0, 0, 0, 0, 0, 0, 128)
    Loop
  Death:
    BRBA KLMNOPQRSTUVWX 3 Bright
    Stop
  }
}

Actor BruiserBall2
{
  Radius 8
  Height 8
  Speed 10
  Damage 5
  Projectile
  +Randomize
  RenderStyle Add
  Alpha 0.9
  SeeSound "imp/attack"
  DeathSound "imp/shotx"
  DamageType Fire
  Decal BaronScorch
  States
  {
  Spawn: 
    BRB2 AB 6 Bright 
    Loop
  Death:
    BRB2 CDEFGHI 3 Bright
    Stop
  }
}

Actor BruiserFireSpawner
{
  Radius 8
  Height 8
  Speed 12
  Damage 0
  +Ripper
  +FloorHugger
  +BloodlessImpact
  Projectile
  MissileType BruiserFire
  Missileheight 0
  States
  {
  Spawn: 
    TNT1 A 3 Bright A_MissileAttack
    TNT1 A 3
    TNT1 A 3
    Loop
  Death:  
    TNT1 A 6
    Stop
  }
}

Actor BruiserBallTrail
{
  Radius 1
  Height 1
  Speed 0
  Projectile
  RenderStyle Add
  Alpha 0.70
  +NoClip
  States
  {
  Spawn:
    BRBA CDEFGHIJ 4 Bright
    Stop       
  }
}

Actor BruiserFire
{
  Radius 1
  Height 1
  Speed 0
  Damage 5
  Projectile
  SeeSound "vile/firecrkl"
  RenderStyle Add
  Alpha 0.9
  +NoClip
  +FloorHugger
  DamageType Fire
  States
  {
  Spawn:
    XXBF AB 3 Bright Radius_Quake (3, 8, 0, 15, 0)//(intensity, duration, damrad, tremrad, tid)
    XXBF C 3 Bright A_Explode(28,128,0) 
    XXBF DEFGHIJKLMNOPQRST 3 Bright
    Stop       
   }
}
