ACTOR WitheredKnight
{
  Health 700
  Radius 30
  Height 62
  Mass 150
  Speed 18
  FastSpeed 25
  Painchance 40
  PainThreshold 10
  MeleeRange 90
  Monster
  +FLOORCLIP
  +DONTHURTSPECIES
  +DONTOVERLAP
  +MissileMore
  +MISSILEEVENMORE
  Tag "Withered Knight"
  Obituary "%o withered away from the axe of a Withered Knight."
  BloodColor "black"
  Species "Skeletons"
  SeeSound "monsters/hfirerevenantsight"
  AttackSound "WitherKnight/Melee"
  PainSound "knight/pain"
  DeathSound "WitherKnight/Death"
  ActiveSound "knight/active"
  DropItem "LifeEssence" 85
  DropItem "ArmorEssence" 90
  DropItem "Newshell" 80 8
  States
  {
  Spawn:
    XNIG A 10 A_Look
    Loop
  See:
    XNIG AB 4 A_Chase
	TNT1 A 0 A_SpawnItem("BonyStep",0,0,0,0)
	XNIG CD 4 A_Chase
	TNT1 A 0 A_SpawnItem("BonyStep",0,0,0,0)
    Loop
  Melee:
    XNIG E 10 A_FaceTarget
    XNIG F 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("WitherKnight/Melee")
	XNIG G 4 A_CustomMeleeAttack(16)
	XNIG A 4 A_FaceTarget
	XNIG H 10 A_FaceTarget
	XNIG I 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("WitherKnight/Melee")
	XNIG J 4 A_CustomMeleeAttack(16)
	Goto See
  Missile:
    TNT1 A 0 A_Jump(70, "BloodAxe")
	TNT1 A 0 A_Jump(120, "BlueAxe")
  EtherealAxe:
    XNIG E 10 A_FaceTarget
    XNIG F 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("WitherKnight/Melee")
    XNIG G 8 A_CustomMissile("CDKnightAxe", 32, 3 * random(1, 8),0,0,0)
    XNIG E 10 A_FaceTarget
    XNIG F 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("WitherKnight/Melee")
    XNIG G 8 A_CustomMissile("CDKnightAxe", 32, 3 * random(1, 8),0,0,0)
	TNT1 A 0 A_Jump(70, "EtherealAxe")
    Goto See
  BlueAxe:
    XNIG H 10 A_FaceTarget
    XNIG I 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("WitherKnight/Melee")
    XNIG J 8 A_CustomMissile("BlueKAxe", 32, 3 * random(1, 8),0,0,0)
    XNIG H 10 A_FaceTarget
    XNIG I 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("WitherKnight/Melee")
    XNIG J 8 A_CustomMissile("BlueKAxe", 32, 3 * random(1, 8),0,0,0)
    Goto See  
  BloodAxe:
    XNIG H 10 A_FaceTarget
    XNIG I 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("WitherKnight/Melee")
    XNIG J 8 A_CustomMissile("CDRedAxe", 32, 3 * random(1, 8),0,0,0)
    XNIG H 10 A_FaceTarget
    XNIG I 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("WitherKnight/Melee")
    XNIG J 8 A_CustomMissile("CDRedAxe", 32, 3 * random(1, 8),0,0,0)
    Goto See
  Pain:
    XNIG K 3
    XNIG K 3 A_Pain
    Goto See
  Death:
    XNIG L 6
    XNIG M 6 A_Scream
    XNIG N 6
    XNIG O 6 A_NoBlocking
    XNIG PQ 6
    XNIG R -1
    Stop
  Raise:
    XNIG RPQONML 7
	Goto See	
  }
}

ACTOR CDKnightAxe
{
  Radius 10
  Height 8
  Speed 16
  FastSpeed 22
  Damage 15
  Projectile
  -NOBLOCKMAP
  -ACTIVATEIMPACT
  -ACTIVATEPCROSS
  +WINDTHRUST
  +THRUGHOST
  SeeSound "WitherKnight/Attack"
  DeathSound "monsters/newfireexplode"
  States
  {
  Spawn:
    SPAX A 3 Bright
    SPAX BC 3 Bright
    Loop
  Death:
    SPAX DEF 6 Bright
    Stop
  }
}

Actor BlueKAxe : CDKnightAxe
{
  Speed 20
  FastSpeed 26
  Damage 15
  States
  {
  Spawn:
    BLAX A 3 Bright
    BLAX BC 3 Bright
    Loop
  Death:
    BLAX DEF 6 Bright
    Stop
  }
}  

ACTOR CDRedAxe : RedAxe
{
  +SEEKERMISSILE
  Speed 17
  FastSpeed 20
  Damage 13
  BloodColor "Red"
  SeeSound "WitherKnight/Attack"
  DeathSound "monsters/newfireexplode"
  States
  {
  Spawn:
     RAXE AB 5 Bright A_DripBlood
	 RAXE A 0 A_SeekerMissile(50, 30)
     Loop
  }	 
}