



actor BerserkCanister : Berserk replaces berserk
{
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	Inventory.PickupMessage "Berserk Canister!"
	inventory.pickupsound "Powerups/Generic"
	+bright
	States
	{
	Spawn:
		BZCN A 15 bright
		BZCN A 7 
		loop
	}
}



//--RED ARMOR--

actor SuperPlating : Megasphere replaces Megasphere
{
	Inventory.PickupMessage "Super plating! Max HP and armor!"
	inventory.pickupsound "Powerups/SuperArmor"
	scale 1
	states
	{
	spawn:
		SPPL A 15 bright
		SPPL A 7
		loop
	}
}


//===========================================================================
//===========================================================================
//===========================================================================

//POWER UPS

//--RADSUIT--

actor Radboots : custominventory replaces radsuit
{
	Inventory.PickupMessage "Anti-rad boots!"
	//inventory.pickupsound "subitems/upgradeitem"
	Inventory.Amount 1
	Inventory.MaxAmount 1
	inventory.pickupsound "Powerups/Generic"
	Inventory.InterHubAmount 1
	+floatbob
	States
	{
	Spawn:
		RDBT A 10 bright
		RDBT A 4 
		Loop
	pickup:
		TNT1 A 0 a_giveinventory ("Bootprotection", 1)
		stop
	} 
}

actor bootprotection : powerironfeet
{
	Powerup.Duration -80
	Powerup.Color 0, 0, 0, 0
    inventory.maxamount 1
    inventory.icon "RDBTB0"
    +INVENTORY.AUTOACTIVATE
}	



//--INFRARED--

ACTOR Lightscope : PowerupGiver replaces infrared
{
	+COUNTITEM
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	inventory.pickupsound "Powerups/Generic"
	Inventory.MaxAmount 0
	Powerup.Type "LightAmp"
	Inventory.PickupMessage "Light Amplification scope!"
	States
	{
	Spawn:
		LASC A 10 bright
		LASC A 10 
		Loop
	}
}

//--IDDQD ARMOR--

actor holoarmor : powerupgiver
{
	Inventory.PickupMessage "Holo barrier!"
	inventory.pickupsound "Powerups/HoloArmor"
    Powerup.Type "Invulnerable"
    Powerup.Duration -30
    inventory.maxamount 0
	Powerup.Color blue2 0.10
	renderstyle translucent
	alpha 0.90
    +notimefreeze
    +floatbob
    +bright
	+INVENTORY.QUIET
	+INVENTORY.BIGPOWERUP
	+INVENTORY.AUTOACTIVATE
    states
    {
    spawn:
		IQAM A 60
		IQAM B 3
		IQAM C 3
		IQAM B 3
		IQAM C 3
		TNT1 A 5
		IQAM C 3
		IQAM B 3
		loop
    }
}

actor powershieldprotection : powerprotection
{
    DamageFactor "Normal", 0.0
    +noradiusdmg
    +nopain
}


actor IDDQDbase : custominventory
{
	Inventory.PickupMessage ""
	scale 1
	+notimefreeze
	+INVENTORY.ALWAYSPICKUP
	Inventory.PickupMessage "Holo barrier!"
	inventory.pickupsound "Powerups/HoloArmor"
	+bright
	inventory.pickupflash "emptybase"
	states
	{
	spawn:
		TNT1 A 0
		IQBS A 1 a_spawnitemex ("holoarmor")
		goto waiting
	waiting:
		IQBS ABC 8
		IQBS CBA 8
		loop
	}
}

actor Emptybase
{
	+notimefreeze
	+cannotpush
	+movewithsector
	+dontsplash
	+noblockmap
	+thruactors
	-nogravity
	+FORCEXYBILLBOARD	
	+LOOKALLAROUND
	scale 1
    States
    {
    Spawn:
		IQBS ABCD 15
		IQBS D 1200
		goto fadeout
	fadeout:
		IQBS D 20
		IQBS D 1 a_fadeout (0.10) 
		loop
	}
}
	

actor BaseSpawner : randomspawner replaces InvulnerabilitySphere
{
	dropitem "IDDQDbase", 255,1
}


//--STEALTH ARMOR--

actor Invisoarmor : custominventory replaces blursphere
{
	Inventory.PickupMessage "Stealth Armor!"
	inventory.pickupsound "Powerups/InvisArmor"
    inventory.maxamount 0
    +notimefreeze
    +floatbob
    +bright
	+INVENTORY.BIGPOWERUP
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	states
	{
	spawn:
		VARM A 1
		loop
	pickup:
		TNT1 A 0
		TNT1 A 0 a_giveinventory ("Powershade",1)
		TNT1 A 0 a_giveinventory ("PowerStealthprotection",1)
		stop
	}
}


ACTOR PowerShade : PowerInvisibility
{
	Powerup.Duration -60
	Powerup.Strength 60
	Powerup.Mode "translucent"
}


actor powerstealthprotection : powerprotection
{
	Powerup.Duration -60
	DamageFactor "Normal", 0.6
}


//----------------------ALLMAP---------------------------

actor HoloMap : MapRevealer replaces allmap
{
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	+bright
	scale 2
	Inventory.MaxAmount 0
	inventory.pickupsound "Powerups/Generic"
	Inventory.PickupMessage "Downloaded a map of the level!"
	States
	{
	Spawn:
		ALMP ABCD 9
		Loop
	}
}
