Actor "Enraged Legendary Karasawa" : Weapon 18716
{
//$Category Weapons/BFG20K
//$Sprite ESWPA0
//$Title "Enraged Legendary Karasawa"
+INVENTORY.UNDROPPABLE
Scale 0.75
Weapon.SelectionOrder 6002
Weapon.PreferredSkin "LifeLeecher-Marine"
Weapon.AmmoGive1 45
Weapon.AmmoGive2 45
Weapon.AmmoUse1 2
Weapon.AmmoUse2 20
Weapon.AmmoType1 "ILDemonAmmo"
Weapon.AmmoType2 "ILDemonAmmo"
Inventory.PickupSound "Weapons/KarasawaCharge"
Inventory.PickupMessage "Enraged Karasawa Rifle"
Obituary "%o was turned into a burnt potato salad by %k."
Tag "Enraged Legendary Karasawa"
Weapon.UpSound "Weapons/KarasawaCharge"
states
  {
  Spawn:
    ESWP A -1
    loop
  Select:
    ESAW A 1 A_Raise
	ESAW A 0 A_Raise
    loop
  Deselect:
    ESAW A 1 A_Lower
	ESAW A 0 A_Lower
    loop
  Ready:
    ESAW A 0 A_PlaySound("Weapons/KarasawaIdle",0,1.0,0)
    ESAW ABCB 4 A_WeaponReady
    loop
  Fire:
    ESAW DE 2 Bright A_Light1
  Hold:
    ESAW F 2 Bright A_Light2
    ESAW A 0 A_PlaySound("HavocShots",0,0.4,0)
    TNT1 A 0 A_Jump(200,2)
    TNT1 A 0 A_Jump(256,2)
    TNT1 AA 0 A_FireCustomMissile ("EnragedLegendaryKarasawaBall")
    ESAW E 2 Bright A_Light1
    ESAW E 2 Bright A_Refire
    ESAW DCBBB 3 Bright A_Light0
    GoTo Ready
   AltFire:
    TNT1 A 0
	TNT1 A 0 A_PlayWeaponSound("Weapons/KarasawaCharge")
    ESAW DDDE 2 Bright A_Light1
	ESAW F 2 Bright A_Light2
	TNT1 A 0 A_PlaySound("monsters/newfireshoot",0,1.0,0)
	ESAW G 3 Bright A_FireCustomMissile("EnragedLegendaryKarasawaBlade",0,1,0,0)
	ESAW H 3 A_Light1
	ESAW I 3 A_Light0
	ESAW B 10
	GoTo Ready
  }
}
Actor EnragedLegendaryKarasawaBlade
{
  Radius 4
  Height 6
  Speed 90
  Damage 225
  Renderstyle Add
  Alpha 0.75
  SeeSound "lfball1/shot"
  DeathSound "lfball1/exp" 
  PROJECTILE
  Species "Player"
  Damagetype "Legendary"
  DECAL Cardinal15KLightning1
  +RIPPER
  +HEXENBOUNCE
  +NOTIMEFREEZE
  +DONTHARMSPECIES
  +FRIENDLY
  +THRUSPECIES
  BounceCount 6
  States
  {
  Spawn:
    TNT1 A 0
    EFB1 ABCDEFGHABCDEFGH 2 Bright A_SpawnItemEx("LegFiendBallTrail",0,0,0,0,0,0,0,128)
	Loop
  Death:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AAA 0 A_CustomMissile("EKaboomLN", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("LegendarySmokeFX4", 0, 0, random(0,360), 2, random(0,360))
    EFB1 IJK 4 Bright A_FadeOut(0.10)
    Stop
  }
}

ACTOR EnragedLegendaryKarasawaBall
{
   Radius 8
   Height 8
   Speed 42
   Damage 85
   Damagetype "Legendary"
   SpawnID 250
   Scale 1.0
   PROJECTILE
   RENDERSTYLE ADD
   DECAL DoomImpScorch
   ALPHA 0.95
   Species "Player"
   SeeSound "monsters/newfireshoot"
   DeathSound "monsters/newfireexplode"
   +NOTIMEFREEZE
   +DONTHARMSPECIES
   +FRIENDLY
   +THRUSPECIES
   States
   {
   Spawn: 
      EFB2 A 1 Bright A_SpawnItemEx("ELegFiendBall2Trail",0,0,0,0,0,0,0,128)
      EFB2 A 1 Bright A_SpawnItemEx("ELegFiendBall2Trail",0,0,0,0,0,0,0,128)
      Loop
   Death:
	  TNT1 A 0
	  TNT1 A 0 A_Explode(32,64)
	  TNT1 A 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	  TNT1 AAA 0 A_CustomMissile("EKaboomLN", 0, 0, random(0,360), 2, random(0,360))
	  TNT1 AAA 0 A_CustomMissile("LegendarySmokeFX4", 0, 0, random(0,360), 2, random(0,360))
      EFB2 C 5 Bright A_Explode(8,32)
      EFB2 DE 5 Bright
      stop
   }
}