// --------------------------------------------------------------------------
//
// Rocket launcher
//
// --------------------------------------------------------------------------

ACTOR EriRocketLauncher : AltPlayerWeapon // replaces RocketLauncher
{
	Game Doom
	Scale 0.8
	SpawnID 29
	Weapon.SelectionOrder 2500
	Weapon.AmmoUse 1
	Weapon.AmmoGive 2
	Weapon.AmmoType "RocketAmmo"
	+WEAPON.NOAUTOFIRE
	Inventory.PickupMessage "$GOTLAUNCHER"
	Tag "$TAG_ROCKETLAUNCHER"
	States
	{
	Ready:
		DRLG A 1 A_WeaponReady
		Loop
	Deselect:
		DRLG A 1 A_Lower
		Loop
	Select:
		DRLG A 1 A_Raise
		Loop
	Fire:
		DRLG A 2 A_GunFlash
		DRLF AB 3 bright
		DRLF C 2 bright A_FireMissile
		DRLF DE 2
		DRLG B 1
		DRLG C 3
		DRLG A 2
		DRLG A 0 A_ReFire
		Goto Ready
	Flash:
		TNT1 A 2 Bright A_Light1
		TNT1 A 2 Bright A_Light2
		TNT1 A 2 Bright A_Light(3)
		TNT1 A 2 Bright A_Light2
		TNT1 A 2 Bright A_Light1
		Goto LightDone
	Spawn:
		DERL A -1
		Stop
	}
}

ACTOR EriRocket replaces Rocket
{
	Game Doom
	SpawnID 127
	Radius 11
	Height 8
	Speed 20
	Damage 20
	Projectile
	Scale 0.8
	SeeSound "weapons/rocklf"
	DeathSound "weapons/rocklx"
	Obituary "$OB_MPROCKET"
	Decal "Scorch"
	States
	{
	Spawn:
		RCKT A 0 
		RCKT A 0 A_PlaySound("weapons/missilefly", CHAN_BODY, 0.35, 1, ATTN_NORM)
		RCKT A 1 Bright A_SpawnItemEx("MissileTrail",0,0,0,-5,0,0,0,0)
		Wait
	Death:
		RCKT B 0 Bright A_SetTranslucent(1.0,1)
	    MISL B 0 Bright A_StopSound(CHAN_BODY)
		RCKT B 3 Bright A_Explode
		RCKT CD 3 Bright
		RCKT E 3 Bright A_SetTranslucent(0.75,1)
		RCKT F 3 Bright A_SetTranslucent(0.5,1)
		Stop
	}
}