// ------------------------------------------------------------
//   Mancubus
// ------------------------------------------------------------

ACTOR ManJuice : FatShot replaces FatShot
{
	DamageType "Thermal"
	Decal "Scorch"
	+forcexybillboard
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_Explode (18, 72)
		MANF AB 4 BRIGHT A_SpawnItemEx ("HDSmoke", -6, 0, 0, 10, 0, 0)
		Loop
	Death:
		MISL BBBB 1 BRIGHT A_SpawnItemEx ("HDSmoke", -1, 0, 0, random(2,-4), random(-2,-2), 0, 0,160)
		MISL B 4 BRIGHT A_Explode (26, 96)
		MISL CCDD 4 BRIGHT A_FadeOut (0.2)
		Stop
	}
}

ACTOR Mancubus : Fatso replaces Fatso
{
	deathheight 20
	damagefactor "Thermal", 0.7
	+MISSILEMORE
	+DONTHURTSPECIES
	obituary "%o learned the hard way that, in Soviet Russia, fatty smoke YOU!"
	painchance 16
	States
	{
	See:
		TNT1 A 0 A_ChangeFlag ("ismonster", 0)
		FATT AABBCCDDEEFF 4 A_Chase
		loop
	Missile:
		FATT G 8 A_FatRaise
		FATT GGGGGG 1 BRIGHT A_SpawnItemEx ("HDSmoke", 24, ((random(0,1)*2-1)*24), 18, random(2,4), 0,0,0, 0,160)	
		FATT H 0 A_Jump (256, "Missile1", "Missile2", "Missile3")
	Missile1:
		FATT H 0 A_CustomMissile ("ManJuice", 32, -24, random(0,12))
		FATT H 0 A_CustomMissile ("ManJuice", 32, 24, random(0,-12))
		goto MissilePost
	Missile2:
		FATT H 0 A_CustomMissile ("ManJuice", 32, -24, random(8,24))
		FATT H 0 A_CustomMissile ("ManJuice", 32, 24, random(0,-2))
		goto MissilePost
	Missile3:
		FATT H 0 A_CustomMissile ("ManJuice", 32, -24, random(0,2))
		FATT H 0 A_CustomMissile ("ManJuice", 32, 24, random(-8,-24))
		goto MissilePost
	MissilePost:
		FATT H 10 bright A_GiveInventory ("Clip", 1)
		FATT H 0 A_JumpIfInventory ("Clip", 3, "MissileStop")
		FATT IG 5 A_FaceTarget
		FATT H 0 A_Jump (256, "Missile2", "Missile3")
	MissileStop:
		FATT GGGG 1 BRIGHT A_SpawnItemEx ("HDSmoke", 24, ((random(0,1)*2-1)*24), 18, random(2,4), 0, 0)	
		FATT I 5 A_FaceTarget
		FATT G 5 A_TakeInventory ("Clip", 999)
		goto See
	Death:
		TNT1 A 0 A_SpawnItemEx ("tempshield", 0,0,0, velx,vely,velz, 0,40)
		FATT K 6 A_SpawnItemEx ("HDExplosion", 0, 0, 36)
		FATT L 6 A_Scream
		FATT M 6 A_NoBlocking
		TNT1 A 0 A_SpawnItemEx ("tempshield2", 0,0,0, velx,vely,velz, 0,40)
		FATT NOPQRS 6 A_SpawnItemEx ("HDSmoke", ((random(0,1)*2-1)*random(1,3)), random(-4,4), 30, 0,0,0, 0,160)	
		FATT TTT 8 A_SpawnItemEx ("HDSmoke", ((random(0,1)*2-1)*random(1,3)), random(-4,4), 12, 0,0,0, 0,160)	
		TNT1 A 0 A_GivetoTarget("HDKillCount",1)
		TNT1 A 0 ACS_ExecuteAlways(558,0,0,1,22)
		FATT T -1 A_BossDeath
		Stop
	}
}