/// decorate/world.txt by Kaapeli47

/// World ///

DamageType Falling
{
	Factor 5.0 // Good luck surviving with Strife-style fall damage!
	ReplaceFactor
}

ACTOR IDMExplosiveBarrel : ExplosiveBarrel replaces ExplosiveBarrel
{
  Health 20
  Radius 10
  Height 42
  Mass 10
  +SOLID
  +SHOOTABLE
  +ACTIVATEMCROSS
  +DONTGIB
  -NOBLOOD
  +NOICEDEATH
  -OLDRADIUSDMG
  +EXTREMEDEATH
  DeathSound "world/barrelx"
  Obituary "%o was blown up by %k."
  BloodColor "Green"
  States
  {
  Spawn:
    BAR1 AB 6
    Loop
  Death:
  XDeath:
    BEXP A 5 Bright
    BEXP B 5 Bright A_Scream
    BEXP CCCCC 1 Bright A_Explode(random(50,150),160,1,0,160)
    BEXP DDDDD 1 Bright A_Explode(random(100,300),192,1,0,192)
    BEXP EEEEEEEE 1 Bright A_Explode(random(25,75),160,1,0,160)
    TNT1 A 1050 Bright A_BarrelDestroy
    TNT1 A 5 A_Respawn
    Wait
  }
}

ACTOR IDMBulletPuff : BulletPuff
{
  +NOBLOCKMAP
  +NOGRAVITY
  +ALLOWPARTICLES
  +RANDOMIZE
  +PUFFONACTORS
  +SKYEXPLODE
  +CLIENTSIDEONLY
  AttackSound "misc/ricochet"
  Seesound "misc/bullethit"
  RenderStyle Translucent
  DamageType "Bullet"
  Alpha 0.7
  VSpeed 0
  States
  {
  Spawn:
  See:
    PUFF A 3 Bright
    PUFF BCD 2
	Stop
  XDeath:
	TNT1 A 1
	Stop
  }
}

ACTOR FistHitPuff : IDMBulletPuff
{
  +PUFFONACTORS
  SeeSound "weapons/punch"
  ActiveSound "silent"
  AttackSound "weapons/pwall"
  DamageType "Punch"
  States
  {
  Spawn:
	PUFF CD 3
    Stop
  }
}

ACTOR ExtremePuff : IDMBulletPuff
{
	Seesound "misc/crit"
	+EXTREMEDEATH
	DamageType "Extreme"
}

ACTOR QuadShotPuff : IDMBulletPuff
{
	+EXTREMEDEATH
	DamageType "Extreme"
}

ACTOR ChainsawPuff : IDMBulletPuff
{
	Seesound "weapons/chainsawhit"
	Damagetype "Saw"
}

ACTOR PiercePuff : IDMBulletPuff
{
	+PIERCEARMOR
}

ACTOR RailPuff : BulletPuff replaces BulletPuff
{
  +NOBLOCKMAP
  +NOGRAVITY
  +ALWAYSPUFF
  +ALLOWPARTICLES
  +RANDOMIZE
  +CLIENTSIDEONLY
  RenderStyle Translucent
  Alpha 1
  States
  {
  Spawn:
  See:
	RPUF A 0
    RPUF A 3 A_Playsound("weapons/railhit")
    RPUF B 3
    Stop
  XDeath:
	RPUF A 0
    RPUF A 3 A_Playsound("weapons/railhit")
    RPUF B 3
    Stop
  }
}


/// Teleport & spawn effects

ACTOR IDMTeleportFog : TeleportFog replaces TeleportFog
{
  +NOBLOCKMAP
  +NOTELEPORT
  +NOGRAVITY
  +CLIENTSIDEONLY
  RenderStyle Add
  States
  {
  Spawn:
    TFOG ABCDEFGHIJ 4 Bright
    Stop
  }
}

ACTOR IDMItemFog : ItemFog replaces ItemFog
{
  +NOBLOCKMAP
  +NOGRAVITY
  +CLIENTSIDEONLY
  States
  {
  Spawn:
    IFOG ABCDE 5 Bright
    Stop
  }
}