ACTOR EnragedLegendaryBabySentient 
{
//$Category Monsters/ILCA
//$Sprite EBBSA1
//$Title "Enraged Legendary Baby Sentient"
Monster
Health 2700
PainChance 40
Scale 1.3
Speed 15
Height 52
Radius 52
Mass 2500
FloatSpeed 10
SeeSound "EnragedBabySentient/Sight"
PainSound "EnragedBabySentient/Pain"
DeathSound "EnragedBabySentient/Death"
ActiveSound "EnragedBabySentient/Active "
DamageFactor "Baby15K", 0.0
DamageFactor "Legendary", 0.0
DamageFactor "LegendaryGuru", 0.0
DamageFactor "LegendaryGuruPlayer", 0.3
DamageFactor "LegendaryPlayer", 0.3
DamageFactor "Legendary1", 0.0
DamageFactor "PDTBFG", 0.25
DamageFactor "PDTBFGTracer", 0.25
DamageFactor "PlayerDevBall", 0.125
DamageFactor "PlayerDevBall2", 0.125
DamageFactor "PlayerDTRG", 0.5
DamageFactor "PlayerDTBFGRailgunSlug", 0.125
DamageFactor "PlayerDevTracer", 0.125
DamageFactor "DBFG10K2", 0.1
DamageFactor "PlayerDBFG10K2", 0.1
DamageFactor "DBFG2", 0.1
DamageFactor "PlayerDBFG2", 0.1
DamageFactor 0.55
BloodColor "Red"
Species "BabySpiders"
SpawnID 254
+BOSS
+BOSSDEATH
+MISSILEMORE
+MISSILEEVENMORE
+QUICKTORETALIATE
+DONTHURTSPECIES
+DONTHARMSPECIES
+NOICEDEATH
+DONTGIB
+NOTARGET
+NORADIUSDMG
+NOTIMEFREEZE
+FLOAT
+NOGRAVITY	
+NOFEAR
+BRIGHT
-FLOORCLIP
DropItem "EnragedLegendaryArmor" 80 1
DropItem "LegendaryRune" 100 1
DropItem "ILDemonAmmoBox" 250
DropItem "ILDemonAmmo" 250 
DropItem "EnragedLegendaryBulletBox" 220 
DropItem "EnragedLegendaryLMGBulletMag" 256 20
DropItem "LegendaryBossLifeEssence" 256 
DropItem "LegendaryBossArmorBonusMax" 256 
DropItem "LegendaryBossLifeEssence" 128
DropItem "LegendaryBossArmorBonusMax" 128
DropItem "LegendaryBossLifeEssence" 32
DropItem "LegendaryBossArmorBonusMax" 32
DropItem "Enraged Legendary Plasmatic Cannon" 170 1
DropItem "Enraged Legendary Plasmatic Rifle" 144 1
DropItem "Enraged Legendary Light Machine Gun" 112 1
DropItem "LegAmmoSphere" 70
DropItem "LegendaryRune" 70 1
DropItem "BulletBox" 256
DropItem "Explosive Minigun" 256 1
Obituary "%o was seen as a neanderthal when compared to an Enraged Legendary Baby Sentient."
Tag "\c[m6]Enraged\c- \c[z3]Legendary Baby Sentient\c-"
var int user_script;
var int user_music;
var int user_drone;
var int user_turret;
var int user_MinionSummoner;
var int user_traps;
var int user_delay;
var int user_DTWarp;
var int user_nuke;
States
{
  Spawn:
    TNT1 A 0 A_JumpIf(user_script == 1,3)
	TNT1 A 0 ACS_NamedExecuteAlways("EnragedFlameJets",0,1)
    TNT1 A 0 A_SetUserVar("user_script",1)
	EBBS AAA 0 Bright A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	EBBS A 8 Bright A_Look
	EBBS BBB 0 Bright A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	EBBS B 8 Bright A_Look	
    Loop
  See:
    TNT1 A 0 A_JumpIf(user_music == 1,3)
    TNT1 A 0 ACS_NamedExecuteAlways("StartMonsterMusic",0,414)
	TNT1 A 0 A_SetUserVar("user_music",1)
    TNT1 A 0 A_JumpIf(user_script == 1,3)
	TNT1 A 0 ACS_NamedExecuteAlways("EnragedFlameJets",0,1)
    TNT1 A 0 A_SetUserVar("user_script",1)
	TNT1 A 0 A_ChangeFlag("NOPAIN",0)
	TNT1 A 0 A_Jump(100,"Rush")
	TNT1 A 0 A_Jump(3,"Trap")
	TNT1 A 0 A_Jump(1,"ThermoNuke","Drone")
	EBBS A 0 A_UnSetInvulnerable
	EBBS AAA 0 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	EBBS AB 2 Bright A_Chase
    Loop
  Rush:
    TNT1 A 0 A_JumpIf(user_delay >= 14,"See")
	EBBS AAA 0 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	EBBS AAAAA 0 A_Chase
	EBBS A 2 Bright A_SpawnItemEx("ELBSGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	EBBS AAA 0 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	EBBS AAAAA 0 A_Chase
	EBBS B 2 Bright A_SpawnItemEx("ELBSGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	TNT1 A 0 A_Jump(30,"Teleport","Evade")
	TNT1 A 0 A_Jump(75,"See")
	TNT1 A 0 A_Jump(2,"Trap")
	TNT1 A 0 A_SetUserVar(user_delay,user_delay+1)
	Loop	
  Evade:
	TNT1 A 0 A_Jump(128,11)
	TNT1 A 0 ThrustThing(Random(-90,90),20,0,0)
	EBBS ABABABAB 2 Bright A_Chase
	TNT1 A 0 A_Stop
	Goto See
	TNT1 A 0 ThrustThing(Random(-90,90),20,0,0)
	EBBS ABABABAB 2 Bright A_Chase
	TNT1 A 0 A_Stop
	Goto See
  Teleport:
	EBBS A 1 Bright A_UnSetShootable
	EBBS AAAA 0 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	EBBS AAAAA 1 A_FadeOut(0.2,0)
	EBBS A 2 
	EBBS AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_Wander
	EBBS AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_Wander
	EBBS A 1 A_PlayWeaponSound("boss/teleport")
	EBBS AAAA 0 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	EBBS AAAAA 1 A_FadeIn(0.2)
	EBBS A 1 Bright A_SetShootable
	TNT1 A 0 A_JumpIf(user_DTWarp >= 1,"DTBFG2")
	Goto See		
  Missile:
    TNT1 A 0 A_JumpIf(user_drone >= 1,2)
    TNT1 A 0 A_JumpIfHealthLower(1400,"Drone")
    TNT1 A 0 A_SetShootable
    TNT1 A 0 A_UnsetInvulnerable
    TNT1 A 0 A_SetTranslucent(1)
	TNT1 A 0 A_SetUserVar(user_nuke,0)
    TNT1 A 0 A_Jump(136,"Railgun","BFG9K","BFG10K","BFG15K","LMG","Cannon","EnergyBolt","ThermoNuke","DTBFG","DTRailgun","Drone")
  Normal:
    TNT1 A 0 A_PlaySound("monsters/darkmasterwind")
    EBBS ABABABA 2 Bright A_FaceTarget
	TNT1 A 0 A_PlaySound("monsters/darkmasterwind2")
	TNT1 A 0 A_PlaySound("sentient/fire")
	TNT1 A 0 A_SpawnItemEx("YellowShellCasing", 8, 8, 18, Random(2, 6), 0, Random(1, 3), Random(80, 90), 128)
    EBBS KK 0 Bright A_CustomMissile("ELBSExplosiveTracer",4,0,Random(-800,800)/100.00,0)
    EBBS K 3 Bright
	TNT1 A 0 A_PlaySound("sentient/fire")
    TNT1 A 0 A_SpawnItemEx("YellowShellCasing", 8, -8, 18, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)	
    EBBS LL 0 Bright A_CustomMissile("ELBSExplosiveTracer",4,0,Random(-800,800)/100.00,0)
	EBBS L 3 Bright
	TNT1 A 0 A_Jump(4,"EnergyBolt")
    TNT1 A 0 A_SpidRefire
    Goto Normal+15
  EnergyBolt:
    EBBS CD 2 Bright A_CustomMissile("ELBSEnergyBolt",20,0,Random(-3,3),0)
	TNT1 A 0 A_Jump(24,"Missile")
    TNT1 A 0 A_SpidRefire
    Goto EnergyBolt
  Railgun:
	EBBS G 0 A_PlayWeaponSound("legbabysentient/load")
    EBBS CCCC 8 Bright A_FaceTarget
  RailgunLoop:
    TNT1 A 0 A_JumpIf(user_delay >= 6,"DTRailgun")
    EBBS D 4 Bright A_CustomMissile("ELBSRailBall",28,0,Random(2,-2)) 
	EBBS C 6 Bright A_FaceTarget
	TNT1 A 0 A_SetUserVar(user_delay,user_delay+1)
	Loop
  DTRailgun:
    TNT1 A 0 A_SetUserVar(user_delay,0)
    EBBS G 0 A_PlayWeaponSound("legbabysentient/load")
    EBBS CCCC 8 Bright A_FaceTarget
	TNT1 A 0 A_PlaySound("weapons/dtrailf")
	EBBS D 9 A_CustomMissile("EnragedDTRailSpider",11)
	EBBS C 12
	Goto See
  BFG9K:
  	TNT1 A 0 A_PlaySound("weapons/bfgf")
	EBBS CCCCCCCCCCCC 2 Bright A_FaceTarget
    EBBS D 8 Bright A_CustomMissile("ELBSBFG9500",20,0,0) 
	TNT1 A 0 A_PlaySound("weapons/bfgf")
	EBBS CCCCCCCCCCCC 2 Bright A_FaceTarget
    EBBS D 8 Bright A_CustomMissile("ELBSBFG9500",20,0,0)
	TNT1 A 0 A_Jump(144,"BFG10K")
    Goto See
  BFG10K:
	TNT1 A 0 A_PlaySound("weapons/charge15k")
    EBBS CCCCCCCCCCCC 2 Bright A_FaceTarget
  BFG10KLoop:
    TNT1 A 0 A_JumpIf(user_delay >= 7,"BFG10KEnd")
    TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
    TNT1 A 0 Bright A_CustomMissile("LegendaryBabySentient10KProjectile",15,0,Random(6,-6)) 
	EBBS DDCC 2 Bright A_FaceTarget
	TNT1 A 0 A_SetUserVar(user_delay,user_delay+1)
	Loop
  BFG10KEnd:
    EBBS C 2 Bright A_PlaySound("weapons/bfg15kcooldown",CHAN_AUTO)
	TNT1 A 0 A_SetUserVar(user_delay,0)
	EBBS CCCCCCCCC 2 Bright
	TNT1 A 0 A_Jump(144,"BFG15K")
    Goto See  
  BFG15K:
	TNT1 A 0 A_PlaySound("weapons/charge15k")
    EBBS CCCCCCCCCCCC 2 Bright A_FaceTarget
  BFG15KLoop:
    TNT1 A 0 A_JumpIf(user_delay >= 12,"BFG15KEnd")
	TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
    EBBS D 2 Bright A_CustomMissile("EBS15KBall",10,0,Random(2,-2)) 
	EBBS DCCC 1 Bright A_FaceTarget
	TNT1 A 0 A_SetUserVar(user_delay,user_delay+1)
	Loop
  BFG15KEnd:
    TNT1 A 0 A_SetUserVar(user_delay,0)
    EBBS C 2 Bright A_PlaySound("weapons/bfg15kcooldown",CHAN_AUTO)
	EBBS CCCCCCCCC 2 Bright
    Goto See
  DTBFG:
    TNT1 A 0 A_PlaySound("Cardinal/9k")
	EBBS CCCCCCCCCCCC 2 Bright A_FaceTarget
    EBBS D 8 Bright A_CustomMissile("EnragedBabySentientDTBFG10KBall",20,0,0)
	TNT1 A 0 A_SetUserVar(user_DTWarp,1)
	Goto Teleport
  DTBFG2:
	TNT1 A 0 A_SetUserVar(user_DTWarp,0)
	TNT1 A 0 A_PlaySound("Cardinal/9k")
	EBBS CCCCCCCCCCCC 2 Bright A_FaceTarget
    EBBS D 8 Bright A_CustomMissile("EnragedBabySentientDTBFG10KBall",20,0,0)
	TNT1 A 0 A_Jump(144,"BFG10K")
    Goto See
  ThermoNuke:
    TNT1 A 0 A_JumpIf(user_nuke >= 3,"Missile")
	TNT1 A 0 A_Stop
    TNT1 A 0 A_SetInvulnerable
	TNT1 A 0 A_PlaySound("legbabysentient/see")
    EBBS CCCCCCCCCCCC 2 Bright A_FaceTarget
  ThermoNukeLoop:
    TNT1 A 0 A_JumpIf(user_delay >= 15,"ThermoNukeFire")
    TNT1 AAAA 0 A_SpawnItemEx("DTBFGLightningRed2")
	TNT1 A 0 A_SpawnItemEx("ThermoNukeEnergy",Random(65,135),Random(-4,4),Random(12,76))
	EBBS CC 4 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	TNT1 A 0 A_SetUserVar(user_delay,user_delay+1)
	Loop
  ThermoNukeFire:
    TNT1 A 0 A_SetUserVar(user_delay,0)
	TNT1 A 0 A_UnSetInvulnerable
	TNT1 A 0 A_SpawnItemEx("TeleportFog",75)
    EBBS D 2 Bright A_SpawnItemEx("EnragedThermoNuke",75) 
	TNT1 A 0 A_SetUserVar(user_nuke,user_nuke+1)
	EBBS DDCCCCCCC 2 Bright A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	TNT1 A 0 A_Jump(84,"Cannon")
    Goto See	
  Cannon:   
	EBBS C 0 A_SetInvulnerable
	EBBS C 1 Bright A_FaceTarget
	EBBS CCC 2 Bright A_SpawnItemEx("ELBabySentBlueFlameSpawner",random(-24,24),random(-24,24),-30)
	EBBS C 1 Bright A_FaceTarget
	TNT1 A 0 A_PlayWeaponSound("legendarycannon/charge")
    EBBS CCCCCCCCCCCC 2 Bright A_SpawnItemEx("ELBabySentBlueFlameSpawner",random(-24,24),random(-24,24),-30)
	EBBS C 1 Bright A_FaceTarget
	EBBS C 0 A_UnSetInvulnerable
	TNT1 A 0 A_ChangeFlag(NOPAIN,1)
  CannonLoop:
    TNT1 A 0 A_JumpIf(user_delay >= 6,"CannonEnd")
	EBBS C 2 Bright A_FaceTarget
	EBBS D 0 A_PlayWeaponSound("legendarycannon/fire")
	EBBS D 2 Bright A_CustomMissile("ELBSCannonProj",15,0,Random(2,-2))
	TNT1 A 0 A_SetUserVar(user_delay,user_delay+1)
	Loop
  CannonEnd:	
    TNT1 A 0 A_SetUserVar(user_delay,0)
	TNT1 A 0 A_ChangeFlag(NOPAIN,0)
	Goto See
  LMG:
	EBBS KKKKKKKKKK 3 A_FaceTarget
  LMGLoop:
    TNT1 A 0 A_JumpIf(user_delay >= 11,"LMGEnd")
	TNT1 AA 0 A_CustomMissile("LegendaryRedTracer",9,Random(-8,8),Random(2,-2),0)
    TNT1 A 0 A_PlaySoundEx("weapons/LMGFire","Weapon")
	TNT1 A 0 A_SpawnItemEx("ELegRifleCasing", 12, -6, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
	TNT1 AA 0 A_CustomBulletAttack(6,10,1,Random(10,20)*5,"LegModdedBulletPuff")
	EBBS LK 3
	TNT1 A 0 A_SetUserVar(user_delay,user_delay+1)
	Loop
  LMGEnd:
    TNT1 A 0 A_SetUserVar(user_delay,0)
	TNT1 A 0 A_RemoveChildren(1)
	Goto See
  Trap:
    TNT1 A 0 A_JumpIf(user_traps >= 3,"Missile")
  	EBBS C 0 A_SetInvulnerable
	EBBS C 0 A_PlaySound("EnragedBabySentient/See")
    EBBS CCCCCCCCCCCCCCC 2 Bright A_SpawnItemEx("ELBSFlameSpawner",random(-24,24),random(-24,24),-30)
	TNT1 A 0 A_SetUserVar("user_traps",user_traps+1)
	EBBS CCCCCCCCCCC 8 A_SpawnItemEx("ELBSTrapMine",0,Random(26,32),Random(6,9),0,0,0,Random(0,359),32)
	EBBS C 0 A_UnSetInvulnerable
	Goto See	
  Drone:
    TNT1 A 0 A_JumpIf(user_drone >= 1,"Trap")
  	EBBS C 0 A_SetInvulnerable
	EBBS C 0 A_PlaySound("EnragedBabySentient/see")
    EBBS CCCCCCCCCCCCCCC 2 Bright A_SpawnItemEx("ELBSFlameSpawner",random(-24,24),random(-24,24),-30)
	TNT1 A 0 A_SetUserVar("user_drone",user_drone+1)
	TNT1 A 0 A_SpawnItemEx("TeleportFog",-30)
	EBBS C 0 A_SpawnItemEx("ELBSHealEffectsSpawner",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_SETMASTER)
	EBBS C 0 A_SpawnItemEx("ELBSSurveyor",-30,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_SETMASTER)
	EBBS CCCCCCCCCCCC 2 Bright A_SpawnItemEx("ELBSFlameSpawner",random(-24,24),random(-24,24),-30)
	EBBS C 0 A_UnSetInvulnerable
	Goto See	
  Pain:	
    TNT1 A 0 A_SetUserVar(user_delay,0)
	TNT1 A 0 A_Jump(45,"Teleport")
	TNT1 A 0 A_Jump(40,"Trap")
    EBBS A 3 Bright A_Pain
	EBBS A 3 Bright
	TNT1 A 0 A_Jump(185,"Missile")
    Goto See	
  Death:
    EBBS F 20 Bright A_Scream
    EBBS F 6 Bright A_Fall
	EBBS F 6 Bright
	TNT1 AAA 0 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
	EBBS GGGGG 2 Bright A_CustomMissile("EKaboomLN", random(20,40), random(10,-10), random(0,360), 2, random(0,360))
	TNT1 AAAA 0 A_CustomMissile("LegendarySmokeFX2", random(20,40), 0, random(0,360), 2, random(0,360))
    EBBS H 6 Bright
    EBBS I 4
	EBBS J 2
    TNT1 A -1 A_KillMaster
    Stop
  }
}

ACTOR ELBSExplosiveTracer : LegSentientExplosiveTracer
{
DamageType "Baby15K"
States
{
  Spawn:
    TRA3 A 1 Bright
	Loop
  Death:
	TNT1 A 0
	TNT1 A 0 A_SetTranslucent(0.75,1)
	TNT1 A 0 A_SpawnItem("EKaboomLN2")
    TNT1 B 4 Bright A_Explode(Random(8,12)*5,72)
    TNT1 CDEF 3 Bright
    Stop
  }
}

ACTOR EBS15KBall : ELegSoul15K {DamageType "Baby15K"}

ACTOR ELBSRailBall : DarkCyberRail
{
Speed 320
Damage (Random(75,85))
SeeSound "monsters/darkcyberrail"
MissileType "CardinalRailTrail"
RenderStyle Add
+THRUSPECIES
+EXTREMEDEATH
+BLOODLESSIMPACT
+NOTIMEFREEZE
+SEEKERMISSILE
Species "BabySpiders"
DamageType "Baby15K"
Decal MummyScorch
States
{
Spawn:
    CCRP ABABAB 1 Bright
	TNT1 A 0 A_Jump(64,"Pause")
Fly:
    CCRP AB 1 Bright
    Loop
Pause:
	TNT1 A 0 A_SeekerMissile(25,35)
	Goto Fly
Death:
	TNT1 A 0
	TNT1 A 0 A_PlayWeaponSound("cyberrail/impact")
	TNT1 A 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AAAAAAAA 0 A_SpawnItemEx("EKaboomLN",random(-32,32),random(-40,40),random(8,16),random(-4,4),random(-4,4),random(0,4),0,SXF_TRANSFERPOINTERS)
	TNT1 AAA 0 A_CustomMissile("LegendarySmokeFX4", 0, 0, random(0,360), 2, random(0,360))   
	TNT1 A 0 A_Explode(128,128,0)
	Stop
	}
}

ACTOR ELBSRailBall2 : ELBSRailBall
{
States
{
Spawn:
    CCRP AB 1 Bright
    Loop
Death:
	TNT1 A 0
	TNT1 A 0 A_PlayWeaponSound("cyberrail/impact")
	TNT1 A 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AAAAAAAA 0 A_SpawnItemEx("EKaboomLN",random(-32,32),random(-40,40),random(8,16),random(-4,4),random(-4,4),random(0,4),0,SXF_TRANSFERPOINTERS)
	TNT1 AAA 0 A_CustomMissile("LegendarySmokeFX4", 0, 0, random(0,360), 2, random(0,360))   
	TNT1 A 0 A_Explode(128,128,0)
	Stop
	}
}

Actor ELBSCannonProj : ELegBehCannonProj{DamageType "Baby15K"}

ACTOR EnragedThermoNuke
{
Radius 20
Height 56
Health 2000
Mass 8000
Species "BabySpiders"
+SHOOTABLE
+THRUSPECIES
+NORADIUSDMG
+LOOKALLAROUND
+AMBUSH
+NOBLOOD
+NOTIMEFREEZE
Scale 1.8
DamageType "Baby15K"
DamageFactor "Baby15K", 0.0
Obituary "%o wasn't aware that an Enraged Legendary Baby Sentient could construct Nuclear weapons."
var int user_timer;
states
{
  Spawn:
    TNT1 A 0 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
    EBSB AAAAA 4 Bright A_Look
    Loop
  See:
	EBSB AABBCC 3 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
  CountDown:
    TNT1 A 0 A_JumpIf(user_timer >= 4,"Explode")
	TNT1 A 0 A_PlaySound("EnragedBabySentient/NukeSiren",0,1,0,ATTN_NONE)
	EBSB CCCC 8 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	TNT1 A 0 A_SetUserVar(user_timer,user_timer+3)
	Loop
  Explode:
    EBSB CCBBAAAAA 3 A_SpawnItemEx("EnragedHellionSmokeSpawner",random(-24,24),random(-24,24),0)
	TNT1 A 0 A_PlaySoundEx("legendary/strike","Voice",0,2)
    TNT1 A 0 A_Explode(6582,2056)
    TNT1 A 0 A_SpawnItemEx("ELegendaryStrikeN")
  Death:
	TNT1 A 0
	TNT1 A 0 A_ScreamAndUnblock
	TNT1 A 0 A_PlayWeaponSound("weapons/rocklx")
	TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_SpawnItemEx("EnragedLightningSpark",0,0,0,random(1,10),0,random(1,10),random(0,359),129)
	TNT1 AAA 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AAAAAAA 0 A_CustomMissile("EKaboomLN", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))
	TNT1 A 0
    Stop
  }
}


Actor ThermoNukeEnergy
{
RenderStyle Add
PROJECTILE
+CLIENTSIDEONLY
+NOBLOCKMAP
+BRIGHT
+DONTSPLASH
+NOTIMEFREEZE
Scale 0.4
States
{
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
    EELE FEDCBA 3 bright 
  Death:
    EELE AAAAA 1 A_FadeOut(0.2)
	Stop
  Toaster:
    TNT1 A 0
	Stop	
  }
}

ACTOR EnragedLegendaryBabySentientFireSpawner : LegendaryRedParticleSpawner
{
  States
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_PlaySound("monster/ambientfire2")
	TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
    TNT1 AA 0 A_SpawnItemEx("EnragedLegendaryBabySentientFire",random(28,38),random(28,38),38,0,0,random(-4,-6),0,128,0)
	TNT1 AA 0 A_SpawnItemEx("EnragedLegendaryBabySentientFire",random(-28,-38),random(-28,-38),38,0,0,random(-4,-6),0,128,0)
	TNT1 AA 0 A_SpawnItemEx("EnragedLegendaryBabySentientFire",random(28,38),random(-28,-38),38,0,0,random(-4,-6),0,128,0)
	TNT1 AA 0 A_SpawnItemEx("EnragedLegendaryBabySentientFire",random(-28,-38),random(28,38),38,0,0,random(-4,-6),0,128,0)
    TNT1 A 1
    Stop
  }
}


ACTOR EnragedLegendaryBabySentientFire : SentientFire
{
Scale 0.3
+NOTIMEFREEZE
States
{
Spawn:
	EMKE ABCDEFGHIJKL 1 Bright A_FadeOut
	Stop
	}
}

Actor ELBSBFG9500 : EnragedBFG9500
{
Species "BabySpiders"
DamageType"Baby15K"
}

Actor ELBSGhost : LBSGhost
{
States
{
Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
    EBBS A 2 A_FadeOut(0.09)
    Loop
  Toaster:
    TNT1 A 0
	Stop		
    }
}

ACTOR ELBSFlameSpawner : LegendaryRedParticleSpawner
{
  +CLIENTSIDEONLY
  States
  {
  Spawn:
      TNT1 A 0
    TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
    TNT1 AAAAAA 0 A_SpawnItemEx("ELFiendFlame",random(20,-20),random(20,-20),random(40,80),0,0,random(2,6),0,128,0)
    TNT1 A 1
    Stop
  Toaster:
    TNT1 A 0
	Stop	
  }
}

Actor ELBSEnergyBolt
{
Radius 6
Height 16
Speed 40
RenderStyle Add
Damage 9
Alpha 1
SeeSound "legbaby/bolt"
DeathSound "weapons/rocklx"
Decal "Scorch"
Projectile
+NOTIMEFREEZE
States
{
  Spawn:
    EBR3 AAAABBBB 1 bright A_SpawnItemEx("ELBSEnergyBoltTrail",0,0,2,0,0,0,0,128,0)
    loop
  Death:
    TNT1 AA 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
    TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))
    EBR3 CDEF 3 bright
    stop
  }
}

ACTOR ELBSEnergyBoltTrail : LBSEnergyBoltTrail
{
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
	TNT1 A 1
    EBR3 AAAAAA 2 A_FadeOut(0.15)
	Stop
   Toaster:
    TNT1 A 0
	Stop  	
    }
}

ACTOR ELBSSurveyor
{
Health 1500
Speed 28
Radius 12
Height 38
+NOBLOOD
+NOPAIN
+DONTFALL
+NOGRAVITY
+FLOAT
+FLOATBOB
+MISSILEMORE
+MISSILEEVENMORE
+NOTIMEFREEZE
-COUNTKILL
Monster
Species "BabySpiders"
SeeSound "drone/sight"
ActiveSound "drone/active"
DeathSound "drone/death"
DamageFactor "Baby15K", 0.0
Obituary "%o was blindsided by an Enraged Legendary Baby Sentient's Surveyor."
States
{
  Idle:
	EBSD A 4 Bright A_Look
	Loop
  Spawn:
  See:
    EBSD AAAAAAAAAA 2 Bright A_Chase   
	TNT1 A 0 A_DamageMaster(-5)
    Loop
  Missile:
    EBSD AA 3 Bright A_FaceTarget
    EBSD B 0 A_CustomMissile("ELBSEnergyBolt",5,10,0)	
    EBSD A 5 Bright A_CustomMissile("ELBSEnergyBolt",5,-10,0)
	EBSD A 4 Bright A_FaceTarget
    Goto See
  Death:
	TNT1 A 0 A_KillSiblings
	TNT1 A 0 A_ScreamAndUnblock
	TNT1 A 0 A_PlayWeaponSound("weapons/rocklx")
	TNT1 A 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AAA 0 A_CustomMissile("EKaboomLN", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))
	TNT1 A 0
    Stop
    }
}

ACTOR ELBabySentBlueFlameSpawner : LBSFlameSpawner
{
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
    TNT1 AAAAAA 0 A_SpawnItemEx("LBSFlameFlame",random(20,-20),random(20,-20),random(40,80),0,0,random(2,6),0,128,0)
    TNT1 A 1
    Stop
  Toaster:
    TNT1 A 1
    Stop
  }
}

Actor ELegendaryStrikeN
{
 Alpha 0.9
 RenderStyle Add
 +NoGravity
 +NOTIMEFREEZE
 Scale 13.0
 States
 {
  Spawn:
   TNT1 A 0
   EFR9 AAA 1 Bright A_FadeOut(0.02)
   Wait
 }
}

ACTOR EnragedDTRailSpider : EnragedCybruiserRail
{
DamageType "Baby15K"
}

Actor ELBSTrapMine
{
Projectile
Height 8
Radius 4
Mass 100
Gravity 0.7
Reactiontime 525
Damage 30
-NoGravity
+CanBounceWater
-MOVEWITHSECTOR
+NOEXPLODEFLOOR
+ThruGhost
+THRUSPECIES
+DONTHURTSPECIES
+DONTHARMSPECIES
+DONTHARMCLASS
+NOCLIP
Damagetype "Legendary"
Species "Legendary"
Obituary "%o was seen as a neanderthal when compared to an Enraged Legendary Baby Sentient."
States
	{
  Spawn:
	TNT1 A 0 A_SpawnItemEx("TeleportFog")
  Fall:
	EBSG A 1 A_CheckFloor("Death")
	TNT1 A 0 Bright A_Countdown
	Loop
  Death:
	TNT1 A 0 Bright
	TNT1 A 0 Bright A_PlaySound("EnragedBabySentient/TrapImpact")
    TNT1 A 0 A_SpawnItemEX("ELBSTrap")
	TNT1 A 0 A_SpawnItemEx("ELBSDirtFountain")
	Stop
  Crash:
  XDeath:
	TNT1 A 0 Bright
	TNT1 A 0 Bright A_Stop
	TNT1 A 0 Bright A_PlaySound("Weapons/RockLX")
	TNT1 A 0 Bright A_NoGravity
	TNT1 A 0 Bright A_SetTranslucent(0.75,1)
	PRXD A 2 Bright A_Explode(80,96,1,1)
	TNT1 A 0 A_SpawnItemEx("OrangeParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
    TNT1 AAAA 0 A_CustomMissile("Kaboom3", 0, 0, random(0,360), 2, random(20,160))
	TNT1 AAAA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(20,160))
	TNT1 AAAA 0 A_SpawnItemEx("Debris",0,0,0,Random(4,-4),Random(4,-4),Random(4,8),0,128)
    TNT1 A 1 A_SpawnItem("RocketEx")
		Stop
	}
}

ACTOR ELBSTrap
{
Mass 60000000
Gravity 0.8
Speed 0
Species "Legendary"
DamageType "LACGrenade"
Monster
+DOOMBOUNCE
+THRUSPECIES
+FORCERADIUSDMG
+NOBLOOD
+NOTIMEFREEZE
+NOCLIP
+NODAMAGE
+NORADIUSDMG
var int user_explodedelay;
States
{
Spawn:
    TNT1 A 0 A_RearrangePointers(AAPTR_NULL, AAPTR_TARGET, AAPTR_NULL)
	TNT1 A 100 A_ChangeFlag(NOBLOCKMAP,0)
  FuckJustUseAStateThatIsntTakenGoddamnit:
	TNT1 A 1 A_LookEx(LOF_NOSOUNDCHECK|LOF_NOSEESOUND,0,100,0,360,"Explode")
    TNT1 A 0 A_JumpIf(user_explodedelay >= 1500,"Explode")	 
    TNT1 A 0 A_SetUserVar("user_explodedelay",user_explodedelay+1)
	Loop
Explode:
    TNT1 A 0 A_SpawnItemEx("ELBSDirtFountain")
	TNT1 A 0 ThrustThingZ(0,45,0,0)
	EBSG B 25 Bright A_PlaySound("EnragedBabySentient/TrapBeep")
	TNT1 A 0 A_AlertMonsters
	TNT1 A 0 A_Explode(168,200)
	TNT1 A 0 A_PlaySound("weapons/mineexplode")
	TNT1 A 0 A_SpawnItemEx("OrangeParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
    TNT1 AAAA 0 A_CustomMissile("EKaboomLN", 0, 0, random(0,360), 2, random(20,160))
	TNT1 AAAA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(20,160))
	TNT1 AAAA 0 A_SpawnItemEx("Debris",0,0,0,Random(4,-4),Random(4,-4),Random(4,8),0,128)
    TNT1 A 1 A_SpawnItem("RocketEx")
    Stop
    }
}

ACTOR ELBSDirtFountain
{
+NOINTERACTION
States
{
  Spawn:
    TNT1 AAAAAA 0 A_SpawnItemEx("ELBSDirtPuff",0,0,0,Random(-6,6),Random(-6,6),Random(0,6))
    EBBD ABCDE 1 A_SpawnItemEx("ELBSDirtPuff",0,0,0,Random(-6,6),Random(-6,6),Random(0,6))
	EBBD FGHIJKLMNOPQRSTUVWXYZ 1
	Stop
	}
}

ACTOR ELBSDirtPuff 
{
Gravity 0.9
RenderStyle Add
Alpha 0.9
Scale 0.6
+DOOMBOUNCE
Projectile
States
{
  Spawn:
    LBSR ABCDEFGHI 2 A_FadeOut(0.08)
	Stop
    }
}

ACTOR ELBSHealEffectsSpawner : ILegImpLineSpawner
{
Monster
+NOINTERACTION
var int user_rotate;
States
{
  Spawn:
    TNT1 A 0 A_JumpIf(user_rotate >= 360, "Reset")
	TNT1 AAA 0 A_SpawnItemEx("RedPowerLine",random(32,-32),random(32,-32),random(8,48),0,0,random(1,4),user_rotate,128,0) 
	TNT1 A 0 A_CustomMissile("RedSparkleSpawner",0,0,random(0,-360),2,random(0,360))
	TNT1 A 1 A_Warp(AAPTR_MASTER,0,0,0,0,WARPF_NOCHECKPOSITION)
	TNT1 A 0 A_SetUserVar(user_rotate,user_rotate+12)
    Loop
  Reset:
    TNT1 A 0 A_SetUserVar(user_rotate,0)
	Goto Spawn
  Death:
    TNT1 A 1
	Stop
    }
}