ACTOR LegendaryApparition
{
Health 1010
PainChance 30
Speed 13
Radius 30
Height 56
Mass 1550
Monster
+BOSS
+BOSSDEATH
+FLOORCLIP
+MISSILEMORE
+QUICKTORETALIATE 
+NOICEDEATH
+DONTGIB
+DONTHURTSPECIES
+NOTARGET
+NOTIMEFREEZE
+NORADIUSDMG
+NOFEAR
+BRIGHT
Species "Fiends"
SeeSound "LegFiend/Sight"
PainSound "LegFiend/Pain"
DeathSound "LegFiend/Death"
ActiveSound "LegFiend/Active"
AttackSound "LegFiend/Melee"
BloodColor "Blue"
Scale 1.1
RenderStyle Translucent
Alpha 0.7
MeleeDamage 14
MeleeRange 44
DamageFactor 0.65
DamageFactor "Legendary", 0.0
DamageFactor "LegendaryPlayer", 0.0
DamageFactor "Legendary1", 0.0
DamageFactor "LegendaryGuru", 0.0
DamageFactor "LegendaryGuruPlayer", 0.0
DamageFactor "PDTBFG", 0.15
DamageFactor "PDTBFGTracer", 0.15
DamageFactor "PlayerDevBall", 0.115
DamageFactor "PlayerDevBall2", 0.115
DamageFactor "PlayerDTBFGRailgunSlug", 0.115
DamageFactor "PlayerDevTracer", 0.115
DamageFactor "FiendFire", 0.0
DamageFactor "DTFiendEx", 0.0
DamageFactor "DBFG10K2", 0.65
DamageFactor "PlayerDBFG10K2", 0.65
DamageFactor "DBFG2", 0.65
DamageFactor "PlayerDBFG2", 0.65
DamageFactor "PlayerDTRG", 0.5
DropItem "LegendaryArmor" 90 1
DropItem "LegendaryPowerSphere" 50 1
DropItem "LDemonAmmoBox" 220
DropItem "LDemonAmmo" 256
DropItem "LegTimeFreezeSphere" 55
DropItem "LegendaryBossLifeEssence" 256
DropItem "LegendaryBossArmorBonusMax" 256
DropItem "Legendary Plasmatic Rifle" 40 1
Obituary "%o was blasted into the void by a Legendary Apparition."
HitObituary "%o was silently enveloped by a Legendary Apparition."
var int user_ragewait;
var int user_inviswait;
var int user_invisdone;
var int user_music;
Tag "\c[z3]Legendary Apparition\c-"
States
{
  Spawn:
    TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
    LARP A 12 A_Look
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
	LARP A 12 A_Look
    Loop
  See:
    TNT1 A 0 A_JumpIf(user_music == 1,3)
    TNT1 A 0 ACS_NamedExecuteAlways("StartMonsterMusic",0,413)
	TNT1 A 0 A_SetUserVar("user_music",1)
	TNT1 A 0 A_SetTranslucent(0.75)
	TNT1 A 0 A_Jump(110,"Rush")
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
	TNT1 A 0 A_PlaySound("humanish2/step")
    LARP AABB 2 A_Chase
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
    TNT1 A 0 A_PlaySound("humanish2/step")
    LARP CCDD 2 A_Chase
	TNT1 A 0 A_Jump(15,"Teleport")
    Loop
  InvisSee:
    TNT1 A 0 A_JumpIf(user_invisdone >= 4,"InvisRageGo")
    TNT1 A 0 A_JumpIf(user_inviswait >= 4,"InvisPuff")
	TNT1 A 0 A_SetInvulnerable
	TNT1 A 0 A_SetTranslucent(0.0)
	TNT1 A 0 A_SetUserVar("user_inviswait",user_inviswait+1)
	TNT1 A 0 A_PlaySound("humanish2/step")
	TNT1 A 0 A_CustomMissile("LASplash",1,-21,0,CMF_AIMDIRECTION,-90)
    LARP SSSSTTTT 1 A_Chase("","")
    TNT1 A 0 A_PlaySound("humanish2/step")
	TNT1 A 0 A_CustomMissile("LASplash",1,21,0,CMF_AIMDIRECTION,-90)
    LARP UUUUVVVV 1 A_Wander
    Loop
  InvisPuff:
    TNT1 A 0 A_SetUserVar("user_inviswait",0)
	TNT1 A 0 A_SetUserVar("user_invisdone",user_invisdone+1)
	LARP AAAA 0 A_SpawnItem("LAInvisSmokeSpawner")
	Goto InvisSee
  Rush:
    TNT1 A 0 A_Jump(48,"InvisRush")
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
	TNT1 A 0 A_PlaySound("humanish2/step")
	LARP AA 0 A_Chase
	LARP A 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase
	LARP A 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase
	LARP B 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase
	LARP B 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
	TNT1 A 0 A_PlaySound("humanish2/step")
	LARP AA 0 A_Chase
	LARP C 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase
	LARP C 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase
	LARP D 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase
	LARP D 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	TNT1 A 0 A_Jump(30,"Teleport")
	TNT1 A 0 A_Jump(87,"See")
	Goto Rush+1
  InvisRush:
    TNT1 A 0 A_JumpIfTargetInLOS(2)
	Goto Rush+1
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
	TNT1 A 0 A_PlaySound("humanish2/step")
	LARP AA 0 A_Chase("","")
	TNT1 A 0 A_SetTranslucent(0.65)
	LARP A 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase("","")
	TNT1 A 0 A_SetTranslucent(0.55)
	LARP A 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase("","")
	TNT1 A 0 A_SetTranslucent(0.45)
	LARP B 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase("","")
	TNT1 A 0 A_SetTranslucent(0.35)
	LARP B 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
	TNT1 A 0 A_PlaySound("humanish2/step")
	LARP AA 0 A_Chase("","")
	TNT1 A 0 A_SetTranslucent(0.25)
	LARP C 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase("","")
	TNT1 A 0 A_SetTranslucent(0.15)
	LARP C 1 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
	LARP AA 0 A_Chase("","")
	TNT1 A 0 A_SetTranslucent(0.05)
	LARP D 1 A_SpawnItemEx("FakeLegApparition",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION|SXF_SETMASTER)
	LARP AA 0 A_Chase("","")
	TNT1 A 0 A_SetInvulnerable
	Goto InvisSee
 /*Teleport: Zandronum doesn't support variable floats, thanks you fucking hacks
    TNT1 A 0 A_SetUserVar("user_teleport",70)
	TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_SetAngle(angle+180)
    TNT1 A 0 A_JumpIf(user_teleport == 0,"See")     
    TNT1 A 0 A_SetUserVar("user_teleport",user_teleport-5)
    TNT1 A 0 A_SetTranslucent(user_teleport/100)
    LARP R 6 A_Wander
	TNT1 A 0 A_SetUserVar("user_teleport",user_teleport-5)
    TNT1 A 0 A_SetTranslucent(user_teleport/100)
    LARP Q 6 A_Wander
	TNT1 A 0 A_SetUserVar("user_teleport",user_teleport-5)
    TNT1 A 0 A_SetTranslucent(user_teleport/100)
    LARP P 6 A_Wander
	TNT1 A 0 A_SetUserVar("user_teleport",user_teleport-5)
    TNT1 A 0 A_SetTranslucent(user_teleport/100)
    LARP O 6 A_Wander
    Goto Teleport+3*/
 Teleport:
    LARP R 0 A_SetInvulnerable
	LARP AAAA 0 A_SpawnItem("LHellionSmokeSpawner")
	TNT1 A 0 A_FaceTarget
	TNT1 A 0 A_SetAngle(angle+180)
	LARP R 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.65)
	LARP R 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.6)
	LARP Q 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.55)
	LARP Q 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.5)
	LARP P 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.45)
	LARP P 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.4)
	LARP O 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.35)
	LARP AAAA 0 A_SpawnItem("LHellionSmokeSpawner")
	LARP O 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.3)
	LARP R 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.25)
	LARP R 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.2)
	LARP Q 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.15)
	LARP Q 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.1)
	LARP P 4 A_Wander
	TNT1 A 0 A_SetTranslucent(0.05)
	LARP P 4 A_Wander
	LARP AAAA 0 A_SpawnItem("LHellionSmokeSpawner")
    Goto InvisSee		
  Missile:
    TNT1 A 0 A_UnsetInvulnerable
    TNT1 A 0 A_SetTranslucent(0.75)
    TNT1 A 0 A_Jump(48,"Rage","Fake")
	TNT1 A 0 A_Jump(48,"Swarm")
    TNT1 A 0 A_JumpIfCloser(250,"Lunge")
  Normal:		
	LARP EF 6 A_FaceTarget
    LARP G 6 A_CustomMissile("LegFiendBall2",32)
    LARP E 2 A_FaceTarget
    Goto See	
  Lunge:
    TNT1 A 0 A_SetUserVar("user_inviswait",0)
	TNT1 A 0 A_SetUserVar("user_invisdone",0)
	TNT1 A 0 A_PlaySound("LegFiend/Melee")
	LARP E 7 A_FaceTarget
	TNT1 A 0 A_SetTranslucent(0.8)
	LARP F 7 A_FaceTarget
	TNT1 A 0 A_SetTranslucent(0.9)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	TNT1 A 0 ThrustThingZ(0,20,0,1)
    LARP F 2 A_Recoil(-26)
	LARP F 3 A_CustomMissile("LFLunge",18,0,0,CMF_AIMDIRECTION)
	LARP G 6 
	TNT1 A 0 A_SetTranslucent(0.8)
	LARP G 2 A_ScaleVelocity(0.2)
	TNT1 A 0 A_SetTranslucent(0.7)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	LARP G 1 A_ScaleVelocity(0)
	Goto See
  Rage:	
    LARP G 1 A_JumpIfCloser(1500,1)
    Goto Normal
    LARP G 1 A_PlaySound("LegFiend/Active")
	LARP G 0 A_SetInvulnerable
	LARP G 1 A_FaceTarget
  RageWait:
    TNT1 A 0 A_JumpIf(user_ragewait >= 16,"RageGo")
	TNT1 A 0 A_SetUserVar("user_ragewait",user_ragewait+1)
    LARP G 0 A_JumpIfTargetInLos(2)
	LARP G 0 A_Jump(256,2)
	LARP G 0 A_FaceTarget
	LARP G 2 A_SpawnItem("LFiendFlameSpawner")
	Loop
  InvisRageGo:
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_SetUserVar("user_inviswait",0)
	TNT1 A 0 A_SetUserVar("user_invisdone",0)
    LARP EEEEE 3 A_FadeIn(0.2)
	TNT1 A 0 A_JumpIfCloser(200,"Lunge")
  RageGo:
    TNT1 A 0 A_SetUserVar("user_ragewait",0) 
	LARP G 0 A_UnSetInvulnerable
	TNT1 A 0 ThrustThingZ(0,25,0,1)
    TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	TNT1 A 0 A_ChangeFlag(NOPAIN,1)
	LARP G 9 
	LARP G 0 A_JumpIfTargetInLos(2)
	LARP G 0 A_Jump(256,2)
	LARP G 0 A_FaceTarget
	LARP G 3 
	TNT1 A 0 ThrustThingZ(0,10,0,1)
    LARP F 2 A_Recoil(-90)
	TNT1 A 0 A_PlaySound("LegFiend/Melee")
  RageLoop:
    TNT1 A 0 A_JumpIf(user_ragewait >= 11,"RageEnd")
	LARP G 0 A_SpawnItemEx("LAGhost",0,0,0,0,0,0,0,128)
	TNT1 A 0 A_JumpIfCloser(120,"LungeWarp")
	LARP G 2 A_FaceTarget
	TNT1 A 0 A_SetUserVar("user_ragewait",user_ragewait+1)
	Loop
  RageEnd:
    TNT1 A 0 A_SetUserVar("user_ragewait",0)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	TNT1 A 0 A_ChangeFlag(NOPAIN,0)
	Goto See
  LungeWarp:
    TNT1 A 0 A_SetUserVar("user_ragewait",0)
	TNT1 A 0 A_ScaleVelocity(0.0)
	TNT1 A 0 A_Explode(200,128)
	TNT1 A 0 A_PlaySoundEx("exile/voidend","Voice")
	TNT1 AAAA 0 A_SpawnItem("LAInvisSmokeSpawner")
    TNT1 AAAA 0 A_SpawnItemEx("LAWarpSmoke",Random(-24,24),Random(-24,24),Random(12,40),Random(-8,8),Random(-8,8),Random(2,7))
	LARP G 1 A_SetTranslucent(0.4)
	LARP G 1 A_SetTranslucent(0.1)
	Goto InvisSee
  Swarm:
    TNT1 A 0 A_ChangeFlag(NODAMAGE,1)
	TNT1 A 0 A_SetInvulnerable
	TNT1 A 0 A_FaceTarget
	LARP EEEE 5 A_SpawnItem("LFiendFlameSpawner")
  SwarmLoop:
    TNT1 A 0 A_JumpIf(user_ragewait >= 13,"SwarmEnd")
	TNT1 A 0 A_GivetoTarget("LegAppSwarmGhostSpawner")
    LARP EE 4 A_SpawnItem("LFiendFlameSpawner")
	TNT1 A 0 A_SetUserVar("user_ragewait",user_ragewait+1)
	Loop
  SwarmEnd:
    TNT1 A 0 A_SetUserVar("user_ragewait",0)
    LARP EEEEEEE 2 A_FadeOut(0.1)
	TNT1 A 0 A_ChangeFlag(NODAMAGE,0)
	Goto InvisSee
  Fake:
    LARP EEEEEEE 2 A_FadeOut(0.1)
	TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_Wander
	PLAY AABBCCDDA 2 A_FadeIn(0.1)
  FakeLoop:
    PLAY AABB 2 A_GiveInventory("ApparitionStrafing")
	TNT1 A 0 A_Jump(128,"FakeLookRight")
	TNT1 A 0 A_SetAngle(angle+Random(1,3))
	PLAY CCDD 2 A_GiveInventory("ApparitionStrafing")
	TNT1 A 0 A_Jump(25,"FakeBreak")
	Loop
  FakeLookRight:
    TNT1 A 0 A_SetAngle(angle+Random(-1,-3))
	PLAY CCDD 2 A_GiveInventory("ApparitionStrafing")
	TNT1 A 0 A_Jump(25,"FakeBreak")
	Goto FakeLoop
  FakeBreak:
	TNT1 A 0 A_PlaySoundEx("exile/voidend","Voice")
	TNT1 AAAA 0 A_SpawnItem("LAInvisSmokeSpawner")
    TNT1 AAAA 0 A_SpawnItemEx("LAWarpSmoke",Random(-24,24),Random(-24,24),Random(12,40),Random(-8,8),Random(-8,8),Random(2,7))
	Goto RageGo
  /*MarkStart:
    LARP EEEEEEE 5 A_SpawnItem("LSoulFlameSpawner",0,0,0,0)
	TNT1 A 0 A_JumpIfTargetInLOS("Mark")
	Goto
  Mark:
	TNT1 A 0 A_GivetoTarget("LegMarkedGiver")
	LARP EEEEEEE 2 A_FadeOut(0.1)
	Goto InvisSee*/
  Melee:
	LARP EF 3 A_FaceTarget
    LARP G 2 A_MeleeAttack
    LARP E 3 A_FaceTarget
    Goto See
  Pain:
  	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	TNT1 A 0 A_FaceTarget
	TNT1 A 0 A_Jump(35,"Teleport")
    LARP H 2 
    LARP H 2 A_Pain
	TNT1 A 0 A_Jump(88,"Missile")
    Goto See
  Death:
  	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	TNT1 A 0 A_KillChildren
    LARP I 8 A_StopSound(6)
    LARP J 0 A_PlaySound("Gore/Splat")
    LARP J 0 A_SpawnItemEx("LFGibbedGenerator",0,0,0,0,0,0,0,128,0)
    LARP J 8 A_Scream
    LARP K 4 
    LARP L 4 A_NoBlocking
    LARP M 4 
    LARP N -1
    Stop
  }
}

Actor LAGhost : LFGhost
{
	Scale 1.1
	Alpha 0.3
States
{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
		LARP A 2 A_FadeOut(0.09)
		Loop
	Toaster:
		TNT1 A 0
		Stop
}
}

Actor FakeLegApparition : LegendaryApparition
{
-COUNTKILL
+NODAMAGE
PainChance 0
var int user_deathtimer;
States
{
Spawn:
  TNT1 A 0 ACS_NamedExecuteAlways("LAGhostHealthSet")
  See:
    TNT1 A 0 A_JumpIf(user_deathtimer >= 20,"Death")
	TNT1 A 0 A_SetUserVar(user_deathtimer,user_deathtimer+1)
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
	TNT1 A 0 A_PlaySound("humanish2/step")
    LARP AABB 2 Bright A_Chase
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
    TNT1 A 0 A_PlaySound("humanish2/step")
    LARP CCDD 2 Bright A_Chase
    Loop
  Melee:
  Missile:
    TNT1 A 0 A_JumpIfCloser(250,"Lunge")
	Goto See
  Lunge:
	TNT1 A 0 A_PlaySound("LegFiend/Melee")
	LARP E 7 Bright A_FaceTarget
	TNT1 A 0 A_SetTranslucent(0.7)
	LARP F 7 Bright A_FaceTarget
	TNT1 A 0 A_SetTranslucent(0.6)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	TNT1 A 0 ThrustThingZ(0,20,0,1)
    LARP F 2 Bright A_Recoil(-26)
	LARP F 3 Bright A_CustomMissile("LFLunge",18,0,0,CMF_AIMDIRECTION)
	LARP G 6 Bright
	TNT1 A 0 A_SetTranslucent(0.5)
	LARP G 2 Bright A_ScaleVelocity(0.2)
	TNT1 A 0 A_SetTranslucent(0.4)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	LARP G 1 Bright A_ScaleVelocity(0)
	LARP GGGG 2 A_FadeOut(0.1)
	Stop
  Death:
    LARP GGGG 2 A_FadeOut(0.1)
	Stop
	}
}

Actor LegAppSwarmGhostSpawner : CustomInventory
{
+Inventory.ALWAYSPICKUP 
+Inventory.AUTOACTIVATE
States
{
  Pickup:
	TNT1 A 0 A_SpawnItemEx("FakeLegApparitionSwarmGhost",random(-360,360),random(-360,360),16,0,0,0,random(0,359),0,64)
	Stop
	}
}

Actor FakeLegApparitionSwarmGhost : FakeLegApparition
{
Alpha 0.0
+NODAMAGE
States
{
  Spawn:
  See:
    //TNT1 A 0 ACS_NamedExecuteAlways("LAGhostHealthSet")
    TNT1 A 0 A_PlaySound("LegFiend/Melee")
    LARP EEEE 3 A_FadeIn(0.2)
	TNT1 A 0 A_SetTranslucent(0.7)
	LARP EF 7 Bright A_FaceTarget
	TNT1 A 0 A_SetTranslucent(0.6)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	TNT1 A 0 ThrustThingZ(0,20,0,1)
    LARP F 2 Bright A_Recoil(-26)
	LARP F 3 Bright A_CustomMissile("LFLunge",18,0,0,CMF_AIMDIRECTION)
	LARP G 6 Bright
	TNT1 A 0 A_SetTranslucent(0.5)
	LARP G 2 Bright A_ScaleVelocity(0.2)
	TNT1 A 0 A_SetTranslucent(0.4)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	LARP G 1 Bright A_ScaleVelocity(0)
	LARP GGGG 2 A_FadeOut(0.1)
	Stop
	}
}

ACTOR LAInvisSmoke : BHellionSmoke
{
States
{
    Spawn:
        TNT1 A 0
        BMKE ABCDEFGHIJKL 2 Bright A_FadeOut
        Stop
}
}

ACTOR LAInvisSmokeSpawner : BHellionSmokeSpawner 
{
States
{
    Spawn:
        TNT1 A 0
        TNT1 AAA 0 A_SpawnItemEx("LAInvisSmoke",random(12,-12),random(12,-12),random(12,64),0,0,random(1,3),0,128,0)
        TNT1 A 1
        Stop
}
}

ACTOR LAWarpSmoke : LAInvisSmoke
{
   Alpha 0.7
   +NOBLOCKMAP
   -NOGRAVITY
   Gravity 0.8
   Scale 0.8
   +FORCEXYBILLBOARD
   +NOTIMEFREEZE
   States
   {
   Spawn:
      TNT1 A 0
      BMKE ABCDEFGHIJKL 1 Bright 
      stop
   }
}
/*
ACTOR LegMarkedGiver : PowerupGiver
{
Powerup.Duration -5
+INVENTORY.AUTOACTIVATE
+INVENTORY.ALWAYSPICKUP
+NOTIMEFREEZE
Inventory.MaxAmount 1
Powerup.Type "LegendaryMarked"
}

ACTOR PowerLegendaryMarked: PowerMorph
{
+NOTIMEFREEZE
PowerMorph.PlayerClass "LegendaryMarked"
PowerMorph.MorphFlash "None"
PowerMorph.UnMorphFlash "None"
PowerMorph.MorphStyle (MRF_FULLHEALTH|MRF_ADDSTAMINA|MRF_NEWTIDBEHAVIOUR|MRF_WHENINVULNERABLE|MRF_LOSEACTUALWEAPON)
}
	
ACTOR LegendaryMarked : PlayerPawn
{
Speed 1
Mass 300
Radius 20
Height 56
Health 100
Scale 1.1
Player.MaxHealth 100
BloodColor "Blue"
Player.AttackZOffset 0
Player.DamageScreenColor Blue, 0.1
SeeSound "LegFiend/Sight"
PainSound "LegFiend/Pain"
DeathSound "LegFiend/Death"
ActiveSound "LegFiend/Active"
MeleeSound "LegFiend/Melee"
Species "LegMarked"
+THRUSPECIES
+DONTHARMSPECIES
+NORADIUSDMG
+NOSKIN
+DONTRIP
+NOPAIN
+BOSS
+BOSSDEATH
+NOTIMEFREEZE
States
{
Spawn:
	TNT1 A 0
	LARP A 10 Bright
	Loop
See:
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
	TNT1 A 0 A_PlaySound("humanish2/step")
    LARP AABB 2 
	TNT1 A 0 A_SpawnItem("LHellionSmokeSpawner")
    TNT1 A 0 A_PlaySound("humanish2/step")
    LARP CCDD 2 
	Goto Spawn
Missile:
	LARP E 1 Bright
	LARP E 0
Death:
	TNT1 A 0
	TNT1 A 0 A_TakeInventory("HandGrenadeAction",1)
	TNT1 A 0 A_TakeInventory("MineAction",1)
	TNT1 A 0 A_TakeInventory("RailgunAction",1)
	PLAY H 8
	PLAY I 8 A_PlayerScream
	PLAY J 8 A_NoBlocking
	PLAY K 8
	PLAY L 8 A_SpawnItem("BodyCrash")
	PLAY M 8
	PLAY N -1
	Stop
}
}*/

ACTOR LASplash
{
Projectile
Radius 1
Height 1
+NOCLIP
Speed 90
States
{
  Spawn:
    TNT1 AAA 0
	Stop
	}
}

Actor ApparitionStrafing : LegZombieStrafingg3
{
States
{
  Pickup:
    NULL A 1 
	NULL A 1 A_JumpIf(velx != 0 || vely != 0,2)
	NULL A 1 A_Jump(256,2)
	NULL A 1 A_Jump(235,5)
	NULL A 1 A_JumpIfInventory("LegCommandoStrafeSens",1,3)
	NULL A 1 A_GiveInventory("LegCommandoStrafeSens",1)
	NULL A 1 A_Jump(256,2)	
	NULL A 1 A_TakeInventory("LegCommandoStrafeSens",1)
	NULL A 1 A_JumpIfInventory("LegCommandoStrafeSens",1,3)
	NULL A 1 ThrustThing(angle*256/360+38.7,5,0,0)
	NULL A 1 A_Jump(256,2)	
	NULL A 1 ThrustThing(angle*256/360+38.7,-5,0,0)
    NULL A 1 A_FaceTarget
	NULL A 1 A_Jump(24,2)
	NULL A 1 A_JumpIfCloser(300,2)
	NULL A 1 A_Recoil(-1)
    Stop
	NULL A 1 A_Recoil(1)
    Stop	
  }
}