
//===========================================================================
//
// Cyberdemon
//
//===========================================================================
ACTOR Cyberdemon1 Replaces Cyberdemon
{
	Game Doom
	SpawnID 114
	Health 4000
	Radius 40
	Height 110
	Mass 1000
	Speed 16
	PainChance 20
	Monster
	MinMissileChance 160
	+BOSS 
	+MISSILEMORE
	+FLOORCLIP
	+NORADIUSDMG
	+DONTMORPH
	+BOSSDEATH
	SeeSound "cyber/sight"
	PainSound "CYBPAIN"
	DeathSound "CYBDIE"
	ActiveSound "cyber/active"
	Obituary "$OB_CYBORG"
	States
	{
	Spawn:
		CYBR AB 10 A_Look
		Loop
	See:
		CYBR A 3 A_Hoof
		CYBR ABBCC 3 A_Chase
		CYBR D 3 A_Metal
		CYBR D 3 A_Chase
		Loop
	Missile:
		CYBR E 6 A_FaceTarget
		CYBR F 12 A_CyberAttack
		CYBR E 12 A_FaceTarget
		CYBR F 12 A_CyberAttack
		CYBR E 12 A_FaceTarget
		CYBR F 12 A_CyberAttack
		Goto See
	Pain:
		CYBR G 10 A_Pain
		Goto See
	Death:
		CYBR H 0
		CYBR H 0 A_Scream
		CYBR H 10
		CYBR I 6
		CYBR JKL 6
		TNT1 AAAAA 0 A_SpawnItemEx("Explosion", random(-64,64), random(-64,64), random(32,120))
		TNT1 AAAAAAAAAAA 0 A_CustomMissile("FlyingBloodParticleHuge", 40,  0, random(0, 360), 2, random(30, 65))
		TNT1 AAAAAAAAAAA 0 A_CustomMissile("FlyingBloodParticleHuge", 80,  0, random(0, 360), 2, random(30, 65))
		TNT1 A 0 A_CustomMissile("CyberGib1", random(80, 90),  0, random(0, 360), 2, random(30, 65))
		TNT1 A 0 A_CustomMissile("CyberGib2", random(60, 90),  0, random(0, 360), 2, random(30, 65))
		TNT1 A 0 A_CustomMissile("CyberGib3", random(60, 90),  0, random(0, 360), 2, random(30, 65))
		TNT1 A 0 A_CustomMissile("CyberGib4", random(50, 90),  0, random(0, 360), 2, random(30, 65))
		TNT1 AAA 0 A_CustomMissile("XDeath1b", 80,  0, random(0, 360), 2, random(10, 45))
		TNT1 AAAA 0 A_CustomMissile("XDeath2", 80,  0, random(0, 360), 2, random(10, 45))
		TNT1 AAA 0 A_CustomMissile("XDeath3", 80,  0, random(0, 360), 2, random(10, 45))
		CYBR M 6 A_NoBlocking
		CYBR NO 6
		TNT1 A 0 A_CustomMissile("XDeath1", 10,  0, random(0, 360), 2, random(10, 45))
		CYBR P 30
		CYBR P -1 A_BossDeath
		Stop
	Crush:
		TNT1 AAAAAAAAAA 0 A_CustomMissile("FlyingBloodParticleCrushed", 0,  0, random(0, 360), 2, random(0, 90))
		TNT1 AA 0 A_CustomMissile("XDeath2", 50,  0, random(0, 360), 2, random(10, 45))
		TNT1 AA 0 A_CustomMissile("XDeath3", 50,  0, random(0, 360), 2, random(10, 45))
		CRSH F 1
		CRSH F -1
		Stop
	}
}

