//===========================================================================
//
// Pain Elemental
//
//===========================================================================
ACTOR PainElemental1 Replaces PainElemental
{
	Game Doom
	SpawnID 115
	Health 400
	Radius 31
	Height 56
	Mass 400
	Speed 8
	PainChance 128
	Monster
	+FLOAT 
	+NOGRAVITY
	SeeSound "pain/sight"
	PainSound "pain/pain"
	DeathSound "pain/death"
	ActiveSound "pain/active"
	States
	{
	Spawn:
		PAIN A 10 A_Look
		Loop
	See:
		PAIN AABBCC 3 A_Chase
		Loop
	Missile:
		PAIN D 5 A_FaceTarget
		PAIN E 5 A_FaceTarget
		PAIN F 4 BRIGHT A_FaceTarget
		PAIN F 1 BRIGHT A_PainAttack
		Goto See
	Pain:
		PAIN G 6
		PAIN G 6 A_Pain
		Goto See
	Death:
		PAIN H 8 BRIGHT
		PAIN I 8 BRIGHT A_Scream
		PAIN JK 8 BRIGHT
		TNT1 A 0 A_CustomMissile("XDeath1b", 20,  0, random(0, 360), 2, random(10, 45))
		TNT1 AAAAAAAA 0 A_CustomMissile("FlyingBloodParticleFast", 50,  0, random(0, 360), 2, random(0, 90))
		TNT1 AAAAAA 0 A_CustomMissile("FlyingBloodParticleBig", 50,  0, random(0, 360), 2, random(10, 45))
		TNT1 AAA 0 A_CustomMissile("XDeath2", 40,  0, random(0, 360), 2, random(10, 45))
		TNT1 AAA 0 A_CustomMissile("XDeath3", 40,  0, random(0, 360), 2, random(10, 45))
		TNT1 AAA 0 A_CustomMissile("ExplosionFire", 0,  0, random(0, 360), 2, random(-90, 90))
		TNT1 AAA 0 A_CustomMissile("ExplSmokeParticle", 0,  0, random(0, 360), 2, random(0, 90))
		PAIN L 8 BRIGHT A_PainDie
		PAIN M 8 
		PAIN X 1
		TNT1 A 0 A_CustomMissile("XDeath1", 20,  0, random(0, 360), 2, random(10, 45))
		PAIN X -1
		Stop
	Raise:
		PAIN MLKJIH 8
		Goto See
	}
}
