//===========================================================================
// ShotgunGuy Replacements
//===========================================================================

ACTOR MKShotgunguySpawner : RandomSpawner replaces ShotgunGuy
{
	DropItem "ShotgunGuyVanilla", 255,100
	//DropItem "AmmoboxZombie1", 255, 10
	//DropItem "AmmoboxZombie2", 255, 10
}

//===========================================================================
//
// Shotgun Zombie (Vanilla)
//
// by Marty Kirra
// Sprites by idsoftware
//
//===========================================================================

ACTOR ShotgunGuyVanilla //: ShotgunGuy
{
    Health 30
    Radius 18
    Height 56
    Mass 100
    Speed 3
    PainChance 170
    Monster
    +FLOORCLIP
	SeeSound "zombie/sight"
	PainSound "zombie/pain"
	DeathSound "zombie/death"
	ActiveSound "zombie/idle"
	AttackSound "zekeshotgun/fire"
	PainChance "Melee", 235
	PainChance "Sling", 255
	PainChance "GasShellDamagePlayer", 17
	Obituary "%o was blasted by a shotgun-wielding zombie."
	DropItem BuckshotShellThrown 50
	DropItem BuckshotShellThrown 50
	DropItem BuckshotShellThrown 50
	DropItem BuckshotShellThrown 127
	DropItem BuckshotShellThrown 127
	DropItem BuckshotShellThrown 127
	DropItem BuckshotShellThrown 255
	DropItem BuckshotShellThrown 255
	DropItem ShotgunPickup 255
	//DropItem DropBuckshotShellSpawner 255 These guys are the pretty 4-shell things
	States
	{
    Spawn: 
      SPOS A 10 A_Look 
      Loop
	See:
	  SPOS AAAAAABBBBBBCCCCCCDDDDDD 1 A_Chase
	  loop 
	Missile: 
      SPOS E 0 A_Jump(140,"See") //Put here because it was murder before with the new see states
	  SPOS E 10 A_FaceTarget 
      SPOS F 10 Bright A_CustomBulletAttack(10,2,9,1)
      SPOS E 10 A_PlaySound("zekeshotgun/pump")
      Goto See
    Pain:
      SPOS G 3
      SPOS G 3 A_Pain
      Goto See
    Pain.Sling:
      TNT1 A 0 HealThing(1)
	  TNT1 A 0 A_FaceTarget
      TNT1 A 0 A_CustomMissile("MagSlingShot", 32, 0)
	  Goto Pain.Melee
	Pain.Melee:
	  SPOS G 6
	  SPOS G 8 A_Pain
	  Goto See
	Death.Uppercut:
	  TNT1 A 0 A_FaceTarget
	  TNT1 A 0 Thrustthing(angle*256/360+192, random(3,4), 0, 0)
	  TNT1 A 0 Thrustthingz(0,27,0,1)
	  Goto Death
    Death:
      SPOS H 5
      SPOS I 5 A_Scream
      SPOS J 5 A_NoBlocking
      SPOS K 5
      SPOS L -1
      Stop
    XDeath:
      SPOS M 5
      SPOS N 5 A_XScream
      SPOS O 5 A_NoBlocking
      SPOS PQRST 5
      SPOS U -1
      Stop
    Raise:
      SPOS L 5
      SPOS KJIH 5
      Goto See	  
   } 
} 

//GG Replacements

ACTOR MKShotgunguySpawnerGG : RandomSpawner
{
	DropItem "ShotgunGuyVanillaGG", 255,100
	//DropItem "AmmoboxZombie1GG", 255, 10
	//DropItem "AmmoboxZombie2GG", 255, 10
}


ACTOR ShotgunGuyVanillaGG : ShotgunGuyVanilla
{
	States
	{
	Missile: 
      SPOS E 0 A_Jump(220,"See")
	  SPOS E 10 A_FaceTarget 
      SPOS F 10 Bright A_CustomBulletAttack(10,2,9,1)
      SPOS E 10 A_PlaySound("zekeshotgun/pump")
      Goto See
   } 
} 