actor MFist : Weapon
{
  Game Doom
  Weapon.SelectionOrder 3700
  Weapon.Kickback 100
  +WEAPON.WIMPY_WEAPON
  +WEAPON.MELEEWEAPON
  +INVENTORY.UNDROPPABLE
  Weapon.PreferredSkin "FistMarine"
  Obituary "$OB_MPFIST" // "%o chewed on %k's fist."
  States
  {
  Ready:
    PUNG A 1 A_WeaponReady
    loop
  Deselect:
    PUNG A 1 A_Lower
    loop
  Select: 
    PUNG A 1 A_Raise
    loop
  Fire:
    PUNG B 4
	PUNG A 0 A_JumpIfInventory("PowerStrength",1,5)
    PUNG C 4 A_CustomPunch (3,0,0,"MFistPuff",60)
    PUNG D 5
    PUNG C 4
    PUNG B 5 A_ReFire
    goto Ready
	PUNG C 4 A_CustomPunch (25,0,0,"MFistPuff",60)
	PUNG D 5
    PUNG C 4
    PUNG B 5 A_ReFire
    goto Ready
  }
}

actor MFists : Fist 
{
  +WEAPON.WIMPY_WEAPON
  +WEAPON.MELEEWEAPON
  +INVENTORY.UNDROPPABLE
  Weapon.SelectionOrder 2200
  attacksound "marine/fists"
  Weapon.PreferredSkin "FistMarine"
  Obituary "$OB_MPFIST" // "%o chewed on %k's fist."
  
  States
  {
  Ready:
    MPNG A 1 A_WeaponReady
    loop
  Deselect:
    MPNG A 1 A_Lower
    loop
  Select: 
    MPNG A 1 A_Raise
    loop
  Fire:
    MPNG A 0 A_JumpIfInventory("MLeftFist",1,"Right")
	MPNG BCD 1
	MPNG A 0 A_JumpIfInventory("PowerStrength",1,6)
	MPNG E 1 A_CustomPunch (3,0,0,"MFistPuff",60)
	MPNG FGH 2
	MPNG A 2 A_GiveInventory("MLeftFist",1)
	Goto Ready
	MPNG E 1 A_CustomPunch (23,0,0,"MFistPuff",60)
	MPNG FGH 2
	MPNG A 2 A_GiveInventory("MLeftFist",1)
	Goto Ready
  Right:	
	MPNG IJK 1
	MPNG A 0 A_JumpIfInventory("PowerStrength",1,6)
	MPNG L 1 A_CustomPunch (3,0,0,"MFistPuff",60)
	MPNG MNO 2
	MPNG A 2 A_TakeInventory("MLeftFist",1)
	Goto Ready
	MPNG L 1 A_CustomPunch (23,0,0,"MFistPuff",60)
	MPNG MNO 2
	MPNG A 2 A_TakeInventory("MLeftFist",1)
	Goto Ready
  }
}

Actor MFistPuff
{
+NOBLOCKMAP
+NOGRAVITY
+PUFFONACTORS
-ALLOWPARTICLES
DamageType "MarineDamage" 
attacksound "marine/fistswall"
}


ACTOR MLeftFist : Inventory
 {
  Inventory.Amount 0
  Inventory.MaxAmount 1
  States
   {
    Spawn:
    TNT1 A -1
    Loop 
   }
 }

// ChainSaw

actor MChainsaw : Chainsaw replaces Chainsaw
{
  Weapon.SelectionOrder 3700
  Weapon.PreferredSkin "ChainSawMarine"
  States
  {
  Fire:
    SAWG AB 4 A_Saw ("weapons/sawfull","weapons/sawhit",2,"MBulletPuff")
    SAWG B 0 A_ReFire
    goto Ready
  Spawn:
    CSAW A -1
    stop
  }
}

// Pistol

actor MPistol : Pistol replaces Pistol
{
  Weapon.AmmoType "MClip"
  Weapon.PreferredSkin "PistolMarine"
  States
  {
  Fire:
    PISG A 4
	PISG B 0 A_FireBullets (5.6, 0, 1, 5, "MBulletPuff")
    PISG B 6 A_GunFlash
    PISG C 4
    PISG B 5 A_ReFire
    Goto Ready
  }
}

// Advanced Pistol

actor ADMPistol : Weapon 
{
  Weapon.Kickback 100
  Weapon.SelectionOrder 1900
  Weapon.AmmoUse 1
  Weapon.AmmoUse2 1
  Weapon.AmmoGive 8
  Weapon.AmmoType "MClip"
  Weapon.AmmoType2 "MClip"
  Obituary "$OB_MPPISTOL" // 
  attacksound "weapons/adpistol"
  Weapon.PreferredSkin "PistolMarine"
  +WEAPON.WIMPY_WEAPON
  +INVENTORY.UNDROPPABLE
  Inventory.Pickupmessage "$PICKUP_PISTOL_DROPPED" // 
  States
  {
  Ready:
    ADPS A 1 A_WeaponReady
    Loop
  Deselect:
    ADPS A 1 A_Lower
    Loop
  Select:
    ADPS A 1 A_Raise
    Loop
  Fire:
    ADPS B 3 
	ADPF A 3 Bright A_FireBullets (0.7,0.7, 1, 9, "MBulletPuff")
    ADPS C 4 
	ADPS C 0 A_ReFire
	ADPS DCB 3
    Goto Ready
  AltFire:
    ADPS B 1 
	ADPF A 2 Bright A_FireBullets (3.5,3.5, -1, 9, "MBulletPuff")
	ADPS B 1
	ADPF A 2 Bright A_FireBullets (3.5,3.5, -1, 9, "MBulletPuff")
	ADPS B 1
	ADPF A 2 Bright A_FireBullets (3.5,3.5, -1, 9, "MBulletPuff")
	ADPS C 4 
	ADPS DCB 4
    Goto Ready
  Spawn:
    TNT1 A 1 Thing_Remove(0)
    Stop
  }
}

// Advanced Shotgun (Assault Shotgun)

ACTOR AssaultShotgun : Shotgun
{
	Inventory.PickupMessage "AssaultShotgun"
	Weapon.SelectionOrder 40
	Weapon.AmmoType1 "MShell"
	Weapon.AmmoGive1 8
	Weapon.AmmoUse1 1
	Weapon.Kickback 120
	AttackSound "weapons/Ashotgun/fire"
	Weapon.PreferredSkin "ShotGunMarine"
	States
	{
	Ready:
		D3SG A 1 A_WeaponReady
		loop
	Deselect:
		D3SG A 1 A_Lower
		loop
	Select:
		D3SG A 1 A_Raise
		Loop
	Fire:
		D3SG A 0 A_FireBullets(3.1, 3.1, 7, 6, "MBulletPuff", 1)
		D3SG A 5 A_GunFlash
		D3SG B 4 A_PlaySound("weapons/Ashotgun/cock/back")
		D3SG C 6
		D3SG B 4 A_PlaySound("weapons/Ashotgun/cock/forward")
		D3SG A 3
		Goto Ready
	Flash:
		D3SF A 3 BRIGHT 
		D3SF B 2 BRIGHT 
		Stop
	}
}


// Shotgun

actor MShotgun : Shotgun replaces Shotgun
{
  Weapon.AmmoType "MShell"
  Weapon.PreferredSkin "ShotGunMarine"
  States
  {
  Fire:
    SHTG A 2
    SHTG A 0 A_FireBullets (5.6, 0, 7, 5, "MBulletPuff")
    SHTG A 7 A_GunFlash
    SHTG BCDEFG 2
    SHTG H 3
    SHTG GFEDCB 2
    SHTG A 3
    SHTG A 3 A_ReFire
    Goto Ready
  }
}

// SuperShotGun

actor MSuperShotgun : SuperShotgun replaces SuperShotgun
{
  Weapon.AmmoType "MShell"
  Weapon.PreferredSkin "SSGMarine"
  States
  {
  Fire:
    SHT2 A 3
	SHT2 A 0 A_FireBullets (11.2, 7.1, 20, 5, "MBulletPuff")
    SHT2 A 7 A_GunFlash
    SHT2 B 0 A_CheckReload
	SHT2 BCDEF 3
    SHT2 F 0 A_OpenShotgun2
    SHT2 HUVKL 3
    SHT2 L 0 A_LoadShotgun2
    SHT2 OPQR 3
	SHT2 R 0 A_CloseShotgun2 
    SHT2 RST 3 
    SHT2 A 5 A_ReFire
    Goto Ready
  }
}

// AssaultRifle 

actor AssaultRifle : Weapon 
{
   Weapon.SelectionOrder 600
   Weapon.AmmoUse 1
   Weapon.AmmoUse2 1 
   Weapon.AmmoGive 30
   Weapon.AmmoType "MClip"
   Weapon.AmmoType2 "MClip"
   attacksound "weapon/msmgfire"
   Inventory.PickupMessage "$GOTCHAINGUN" // "You got the chaingun"
   Obituary "$OB_MPCHAINGUN" // "%o was mowed down by %k's chaingun."
   +INVENTORY.UNDROPPABLE
   States
   {
   Ready:
     MMCG A 1 A_WeaponReady
     Loop
   Deselect:
     MMCG A 1 A_Lower
     Loop
   Select:
     MMCG A 1 A_Raise
     Loop
   Fire:
     MMCG B 1
	 MMCG C 2 bright A_FireBullets (4.7, 1.2, 1, 10, "MBulletPuff")
	 MMCG A 0 A_ReFire
	 MMCG D 2 bright
	 MMCG E 2 bright
     Goto Ready
   AltFire:
     MMCG B 1
	 MMCG C 2 bright A_FireBullets (1, 1, -1, 10, "MBulletPuff")
	 MMCG B 1
	 MMCG C 2 bright A_FireBullets (1, 1, -1, 10, "MBulletPuff")
	 MMCG B 1
	 MMCG C 2 bright A_FireBullets (1, 1, -1, 10, "MBulletPuff")
	 MMCG B 1
	 MMCG C 2 bright A_FireBullets (1, 1, -1, 10, "MBulletPuff")
	 MMCG DE 3 bright
	 MMCG B 4
	 Goto Ready
   }
}

// ChainGun

actor MChaingun : Chaingun replaces Chaingun
{
   Weapon.AmmoType "MClip"
   Weapon.PreferredSkin "ChainGunMarine"
   States
   {
   Fire:
     CHGG A 2
	 CHGG A 0 A_Gunflash
	 CHGG B 2 A_FireBullets (5.6, 0, 1, 5, "MBulletPuff")
	 CHGG C 2 
     CHGG D 2 A_FireBullets (5.6, 0, 1, 5, "MBulletPuff")
	 CHGG A 0 A_ReFire
	 CHGG ABCD 2
	 CHGG ABCD 3 
     Goto Ready
	 Flash: 
	 CHGF A 2 bright A_Light1
	 CHGF B 2 bright A_Light2
	 CHGF A 2 bright A_Light1
	 CHGF A 0 bright A_Light0
	 Goto LightDone
   }
}

// Rocket Luncher

actor MRocketLauncher : RocketLauncher replaces RocketLauncher
{
  Weapon.Selectionorder 2400
  Weapon.AmmoType "MRocketAmmo"
  Weapon.AmmoType2 "MRocketAmmo"
  Weapon.AmmoUse2 1
  Weapon.PreferredSkin "RLMarine"
  +WEAPON.NOAUTOAIM
  States
  {
  Fire:
    MISG B 8 A_GunFlash
    MISG B 12 A_FireCustomMissile ("MMarineRocket")
    MISG B 0 A_ReFire
    Goto Ready
  AltFire:
    MISG B 8 A_GunFlash
	MISG B 0 A_PlaySoundEx ("weapons/mgren","weapon")
    MISG B 12 A_FireCustomMissile ("MGrenade",0,1,0,0,0,9)
    MISG B 0 A_ReFire
    Goto Ready
  }
}

// PlasmaRifle

actor MPlasmaRifle : PlasmaRifle replaces PlasmaRifle
{
  Weapon.PreferredSkin "PlsmMarine"
  Weapon.AmmoType "MCell"
  States
  {
  Fire:
    PLSG A 1
	PLSG A 0 A_GunFlash
    PLSG A 2 A_FireCustomMissile ("MPlasmaBall",0,1,0,0,0)
    PLSG B 0 A_ReFire
	PLSG BCDE 4
	PLSG F 8
	PLSG EDCBA 2
    Goto Ready
   Flash:
    PLSF A 2 Bright A_Light1
    PLSF B 2 Bright A_Light0
    Goto LightDone	
  }
}

// Bfg 9000

actor MBFG9000 : BFG9000 replaces BFG9000
{
  Weapon.AmmoType "MCell"
  Weapon.PreferredSkin "BFGMarine"
}


actor MMarineRocket : Rocket
{
 DamageType "MarineRLDamage"
}

ACTOR MGrenade : Grenade
{
	Radius 8
	Height 8
	Speed 25
	Damage 20
	Projectile
    BounceCount 9
	-NOGRAVITY
	-NOTELEPORT
	+DOOMBOUNCE
	+DEHEXPLOSION
	+ROCKETTRAIL
	//+GRENADETRAIL
	+EXPLODEONDEATH
	+USESTBOUNCESOUND
	SeeSound "weapons/mgrenbounce"
	DeathSound "weapons/rocklx"
	Obituary "$OB_GRENADE"
	DamageType "MarineRLDamage"
	States
	{
	Spawn:
		GRN2 ABCDEFGHIJK 3  
		loop
	Death:
		MISL B 8 bright A_Explode
		MISL C 6 bright
		MISL D 4 bright
		stop
	}

}

actor MBulletPuff : BulletPuff
{
 DamageType "MarineDamage"
 +NOEXTREMEDEATH
}

actor MPlasmaBall : PlasmaBall replaces PlasmaBall 
{
 DamageType "MarineDamage"
}

actor MBFGBall : BFGBall replaces BFGBall
{
  DamageType "MarineDamage"
  States
  {
  Death:
    BFE1 AB 8 bright
    BFE1 C 8 bright A_BFGSpray("MBFGExtra")
    BFE1 DEF 8 bright
    stop
  }
}

actor MBFGExtra : BFGExtra 
{
DamageType "MarineDamage"
}

///////////////////////////////////////////////////////////////////////////
// Skulltag Weapons
/*
ACTOR Vulcan : Minigun replaces Minigun
{
    Weapon.AmmoType "MClip"
    Weapon.PreferredSkin "MinigunMarine"
	+WEAPON.DONTBOB
	States
	{
	Ready:
		VULG A 1 A_WeaponReady
		VULG A 0 A_JumpIfInventory ("Mspinch",0,1)
		Loop
		VULG ABCDEFGH 1
		goto ready
	Select: 
		VULG A 1 A_Raise
		VULG A 0 A_JumpIfInventory ("Mspinch",0,1)
		Loop
		VULG A 0 A_PlaySoundEx ("weapon/VulcanCannonLoop","weapon",1)
		goto Ready
	Deselect: 
		VULG A 0 A_TakeInventory("Mspinch",1)
		VULG A 0 A_TakeInventory("Mspinch2",1)
		VULG A 0 ACS_ExecuteAlways(426,0,3)
		VULG A 0 A_StopSoundEx ("Weapon")
		VULG A 1 A_Lower
		Loop
	Fire:
	    VULG A 1
	    VULG A 0 ACS_ExecuteAlways(426,0,2)
	    VULG A 0 A_JumpIfInventory ("Mspinch",0,"Fire2")
		VULG A 0 A_JumpIfInventory ("Mspinch2",0,27)
		VULG A 0 A_PlaySoundEx ("weapon/VulcanCannonUp","weapon",0)
		VULG ABCDEFGH 4 
		VULG ABCDEFGH 3
		VULG ABCDEFGH 2
		VULG A 0 A_GiveInventory("Mspinch2",1)
		VULG A 0 A_GunFlash
		VULF A 1 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		VULG BC 1
		VULF D 1 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		VULG EF 1
		VULF C 1 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		VULG H 1
		VULG A 0 A_ReFire
		VULG A 0 A_JumpIfInventory ("Mspinch",0,"Ready")
		VULG A 0 ACS_ExecuteAlways(426,0,3)
		VULG A 0 A_PlaySoundEx ("weapon/VulcanCannonDown","weapon",0)
		VULG ABCDEFGH 4 
		VULG ABCDEFGH 3
		VULG ABCDEFGH 2
		MNGG A 0 A_TakeInventory("Mspinch2",1)
		goto Ready
	Fire2:
	    VULG A 0 A_GunFlash
		VULF A 1 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		VULG BC 1
		VULF D 1 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		VULG EF 1
		VULF C 1 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		VULG H 1
		VULG A 0 A_ReFire
		VULG A 0 A_PlaySoundEx ("weapon/VulcanCannonLoop","weapon",1)
		VULG A 0 ACS_ExecuteAlways(426,0,1)
		goto Ready
	spawn:
	    TNT1 A 0 Thing_remove(0)
		stop
	AltFire:
	    VULG A 0 A_JumpIfInventory ("Mspinch",0,"stopspin")
		VULG A 0 ACS_ExecuteAlways(426,0,1)
		VULG A 0 A_PlaySoundEx ("weapon/VulcanCannonUp","weapon",0)
		VULG ABCDEFGH 4 
		VULG ABCDEFGH 3
		VULG ABCDEFGH 2
		VULG A 0 A_PlaySoundEx ("weapon/VulcanCannonLoop","weapon",1)
		VULG A 0 A_GiveInventory("Mspinch",1)
		goto ready
	StopSpin:
	    VULG A 0 A_TakeInventory("Mspinch",1)
		VULG A 0 ACS_ExecuteAlways(426,0,3)
		VULG A 0 A_PlaySoundEx ("weapon/VulcanCannonDown","weapon",0)
		VULG ABCDEFGH 2 
		VULG ABCDEFGH 3
		VULG ABCDEFGH 4
		goto ready
	Flash: 
		TNT1 A 0 BRIGHT A_Light1 
		TNT1 A 0 BRIGHT A_Light0
		Goto LightDone 	
	}
}
*/

ACTOR Vulcan : Minigun replaces Minigun
{
    Weapon.AmmoType "MClip"
    Weapon.PreferredSkin "MinigunMarine"
	+WEAPON.DONTBOB
	States
	{
	Ready:
		MNGG A 1 A_WeaponReady
		MNGG A 0 A_JumpIfInventory ("Mspinch",0,1)
		Loop
        MNGG A 0 A_PlaySoundEx ("weapon/VulcanCannonLoop","weapon",0)
		MNGG BA 2
		goto ready
	Select: 
		MNGG A 1 A_Raise
		MNGG A 0 A_JumpIfInventory ("Mspinch",0,1)
		Loop
		MNGG A 0 A_PlaySoundEx ("weapon/VulcanCannonLoop","weapon",0)
		goto Ready
	Deselect: 
		MNGG A 0 A_TakeInventory("Mspinch",1)
		MNGG A 0 A_TakeInventory("Mspinch2",1)
		MNGG A 0 ACS_ExecuteAlways(426,0,3)
		MNGG A 0 A_StopSoundEx ("Weapon")
		MNGG A 1 A_Lower
		Loop
	Fire:
	    MNGG A 1
	    MNGG A 0 ACS_ExecuteAlways(426,0,2)
	    MNGG A 0 A_JumpIfInventory ("Mspinch",0,"Fire2")
		MNGG A 0 A_JumpIfInventory ("Mspinch2",0,18)
		MNGG A 0 A_PlaySoundEx ("weapon/VulcanCannonUp","weapon",0)
		MNGG ABABA 4 
		MNGG BABAB 3
		MNGG ABABA 2
		MNGG A 0 A_GiveInventory("Mspinch2",1)
		MNGG A 0 A_GunFlash
		MNGG A 2 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		MNGG A 0 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		MNGG B 2 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		MNGG B 0 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		MNGG A 1 A_ReFire
		MNGG A 0 A_JumpIfInventory ("Mspinch",0,"Ready")
		MNGG A 0 ACS_ExecuteAlways(426,0,3)
		MNGG A 0 A_PlaySoundEx ("weapon/VulcanCannonDown","weapon",0)
		MNGG ABABA 2 
		MNGG BABAB 3
		MNGG ABABA 4
		MNGG A 0 A_TakeInventory("Mspinch2",1)
		goto Ready
	Fire2:
	    MNGG A 0 A_GunFlash
		MNGG A 2 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		MNGG A 0 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		MNGG B 2 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		MNGG B 0 A_FireBullets(5.6, 2.5, -1, 13, "MBulletPuff")
		MNGG A 1 A_ReFire
		MNGG A 0 ACS_ExecuteAlways(426,0,1)
		goto Ready
	spawn:
	    TNT1 A 0 Thing_remove(0)
		stop
	AltFire:
	    MNGG A 0 A_JumpIfInventory ("Mspinch",0,"stopspin")
		MNGG A 0 ACS_ExecuteAlways(426,0,1)
		MNGG A 0 A_PlaySoundEx ("weapon/VulcanCannonUp","weapon",0)
		MNGG ABABA 4 
		MNGG BABAB 3
		MNGG ABABA 2
		MNGG A 0 A_GiveInventory("Mspinch",1)
		goto ready
	StopSpin:
	    MNGG A 0 A_TakeInventory("Mspinch",1)
		MNGG A 0 ACS_ExecuteAlways(426,0,3)
		MNGG A 0 A_PlaySoundEx ("weapon/VulcanCannonDown","weapon",0)
		MNGG ABABA 2 
		MNGG BABAB 3
		MNGG ABABA 4
		goto ready
	Flash: 
		MNGF A 2 BRIGHT A_Light1 
		MNGF B 2 BRIGHT A_Light0
		Goto LightDone 	
	}
}

ACTOR Mspinch : Inventory
 {
  Inventory.Amount 0
  Inventory.MaxAmount 1
  States
   {
    Spawn:
    TNT1 A -1
    Loop 
   }
 }
ACTOR Mspinch2 : Inventory
 {
  Inventory.Amount 0
  Inventory.MaxAmount 1
  States
   {
    Spawn:
    TNT1 A -1
    Loop 
   }
 }
 
// Items 

// Plasm Cells

ACTOR MCell : Ammo replaces Cell
{
  Inventory.PickupMessage "$GOTCELL" // "Picked up an energy cell."
  Inventory.Amount 20
  Inventory.MaxAmount 200
  Ammo.BackpackAmount 15
  Ammo.BackpackMaxAmount 400
  Inventory.Icon "ICONC"
  States
  {
  Spawn:
    CELL A -1
    Stop
  }
}

ACTOR MCellPack : MCell replaces CellPack
{
  Inventory.PickupMessage "$GOTCELLBOX" // "Picked up an energy cell pack."
  Inventory.Amount 70
  States
  {
  Spawn:
    CELP A -1
    Stop
  }
}

// Rockets

ACTOR MRocketAmmo : Ammo replaces RocketAmmo
{
  Inventory.PickupMessage "$GOTROCKET" // "Picked up a rocket."
  Inventory.Amount 1
  Inventory.MaxAmount 30
  Ammo.BackpackAmount 1
  Ammo.BackpackMaxAmount 50
  Inventory.Icon "ICONR"
  States
  {
  Spawn:
    ROCK A -1
    stop  }
}

ACTOR MRocketBox : MRocketAmmo replaces RocketBox
{
  Inventory.PickupMessage "$GOTROCKBOX" // "Picked up a box of rockets."
  Inventory.Amount 5
  States
  {
  Spawn:
    BROK A -1
    Stop
  }
}

// Shells

ACTOR MShell : Ammo replaces Shell
{
  Inventory.PickupMessage "$GOTSHELLS" // "Picked up 4 shotgun shells."
  Inventory.Amount 4
  Inventory.MaxAmount 50
  Ammo.BackpackAmount 4
  Ammo.BackpackMaxAmount 80
  Inventory.Icon "ICONS"
  States
  {
  Spawn:
    SHEL A -1
    Stop
  }
}

ACTOR MShellBox : MShell replaces ShellBox
{
  Inventory.PickupMessage "$GOTSHELLBOX" // "Picked up a box of shotgun shells."
  Inventory.Amount 16
  States
  {
  Spawn:
    SBOX A -1
    Stop
  }
}

// CLip 

ACTOR MClip : Ammo replaces Clip
{
  Inventory.PickupMessage "$GOTCLIP" // "Picked up a clip."
  Inventory.Amount 8
  Inventory.MaxAmount 400
  Ammo.BackpackAmount 8
  Ammo.BackpackMaxAmount 600
  Inventory.Icon "ICONB"
  States
  {
  Spawn:
    CLIP A -1
    Stop
  }
}

actor MClipBox : MClip replaces ClipBox
{
  Inventory.PickupMessage "$GOTCLIPBOX" // "Picked up a box of bullets."
  Inventory.Amount 48
  States
  {
  Spawn:
    AMMO A -1
    Stop
  }
}







