// WEAPONS //

Actor PSXFistChainsawAmmo : Ammo
{
	Inventory.Amount 0
	Inventory.MaxAmount 0
	Ammo.BackpackAmount 0
	Ammo.BackpackMaxAmount 0
}

Actor PSXFist : Fist
{
	Weapon.YAdjust 10
	Weapon.AmmoType "PSXFistChainsawAmmo"
	Weapon.AmmoUse 0
	States
	{
	Fire:
		PUNG B 4
		PUNG C 4 A_Punch
		PUNG D 5
		PUNG C 4
		PUNG B 5 A_ReFire
		Goto Ready
	}
}

Actor PSXChainsaw : Chainsaw Replaces Chainsaw
{
	Scale 0.92
	Weapon.YAdjust 10
	Weapon.UpSound ""
	Weapon.ReadySound ""
	States
	{
	Select:
		SAWG C 0 A_PlaySound ("weapons/sawup", CHAN_AUTO)
	Select.Raise:
		SAWG C 1 A_Raise
		Loop
	Ready:
		SAWG C 0 A_PlaySound ("weapons/sawidle", CHAN_AUTO)
		SAWG CD 5 A_WeaponReady
		Loop
	Fire:
		SAWG AB 5 A_Saw
		SAWG B 0 A_ReFire
		Goto Ready
	}
}

Actor PSXPistol : Pistol Replaces Pistol
{
	Scale 0.92
	Weapon.YAdjust 10
	attacksound ""
	States
	{
	Fire:
		PISG B 0 A_GunFlash
		PISG B 0 A_PlaySound ("weapons/pistol", CHAN_AUTO, 0.9)
		PISG B 8 A_FireBullets (5.6, 0, 1, 5, "PSXBulletPuff")
		PISG C 6
		PISG B 5 A_ReFire
		Goto Ready
	Flash:
		PISF A 5 Bright A_Light1
		Goto LightDone
	}
}

Actor PSXShotgun : Shotgun Replaces Shotgun
{
	Scale 0.92
	Weapon.YAdjust 10
	attacksound ""
	States
	{
	Fire:
		SHTG A 3
		SHTG A 0 A_GunFlash
		SHTG A 0 A_PlaySound ("weapons/shotgf", CHAN_AUTO)
		SHTG A 7 A_FireBullets (5.6, 0, 7, 5, "PSXBulletPuff")
		SHTG BC 6
		SHTG D 4
		SHTG CB 5
		SHTG A 7 A_ReFire
		Goto Ready
	Flash:
		SHTF A 3 Bright A_Light1
		SHTF B 3 Bright A_Light2
		Goto LightDone
	}
}

Actor PSXSuperShotgun : SuperShotgun Replaces SuperShotgun
{
	Scale 0.92
	Weapon.YAdjust 10
	Weapon.SlotPriority 1
	attacksound ""
	States
	{
	Fire:
		SHT2 A 5
		SHT2 A 0 A_GunFlash
		SHT2 A 0 A_PlaySound ("weapons/sshotf", CHAN_AUTO)
		SHT2 A 7 A_FireBullets (11.2, 7.1, 20, 5, "PSXBulletPuff")
		SHT2 B 7
		SHT2 C 7 A_CheckReload
		SHT2 D 7 A_PlaySound ("weapons/sshoto", CHAN_AUTO)
		SHT2 E 7
		SHT2 F 7 A_PlaySound ("weapons/sshotl", CHAN_AUTO)
		SHT2 G 5
		SHT2 H 0 A_PlaySound ("weapons/sshotc", CHAN_AUTO)
		SHT2 H 5 A_ReFire
		SHT2 A 5 A_ReFire
		Goto Ready
	Flash:
		SHT2 I 3 Bright A_Light1
		SHT2 J 4 Bright A_Light2
		Goto LightDone
	}
}

Actor PSXChaingun : Chaingun Replaces Chaingun
{
	Scale 0.92
	Weapon.YAdjust 10
	attacksound ""
	States
	{
	Fire:
		CHGG A 0 A_GunFlash
		CHGG A 0 A_PlaySound ("weapons/chngun", CHAN_AUTO, 0.78)
		CHGG A 5 A_FireBullets (5.6, 0, 1, 5, "PSXBulletPuff")
		CHGG B 0 A_PlaySound ("weapons/chngun", CHAN_AUTO, 0.78)
		CHGG B 5 A_FireBullets (5.6, 0, 1, 5, "PSXBulletPuff")
		CHGG B 0 A_ReFire
		Goto Ready
	Flash:
		CHGF A 5 Bright A_Light1
		CHGF B 3 Bright A_Light2
		Goto LightDone
	}
}

Actor PSXRocketLauncher : RocketLauncher Replaces RocketLauncher
{
	Scale 0.92
	Weapon.YAdjust 10
	attacksound ""
	States
	{
	Fire:
		MISG B 12 A_GunFlash
		MISG B 12 A_FireMissile
		MISG B 0 A_ReFire
		Goto Ready
	}
}

Actor PSXPlasmaRifle : PlasmaRifle Replaces PlasmaRifle
{
	Scale 0.92
	Weapon.YAdjust 10
	attacksound ""
	States
	{
	Fire:
		PLSG A 5 A_FirePlasma
		PLSG B 20 A_ReFire
		Goto Ready
	Flash:
		PLSF A 3 Bright A_Light1
		Goto LightDone
		PLSF B 3 Bright A_Light1
		Goto LightDone
	}
}

Actor PSXBFG9000 : BFG9000 Replaces BFG9000
{
	Scale 0.92
	Weapon.YAdjust 10
	attacksound ""
	States
	{
	Fire:
		BFGG A 20 A_PlaySound ("weapons/bfgf", CHAN_AUTO)
		BFGG B 20 A_GunFlash
		BFGG B 20 A_FireBFG
		BFGG B 20 A_ReFire
		Goto Ready
	}
}