ACTOR BabyDDemolisher 23336
{
Monster
Health 1200
Height 64
Radius 52
Speed 13
Scale 1.2
BloodColor "DarkGreen"
PainChance 70
+FLOORCLIP
+BOSSDEATH
+MISSILEMORE
+QUICKTORETALIATE
Species "BabySpiders"
DamageFactor "Baby15K", 0.0
DropItem "LifeEssence", 140
DropItem "ArmorBonusMax", 140
DropItem "DemonAmmoBox", 128, 200
SeeSound "minidemo/sight"
ActiveSound "minidemo/active"
AttackSound ""
PainSound "monsters/fusionitepain"
DeathSound "minidemo/death"
Obituary "%o was annihilated by a Baby Dark Demolisher."
Tag "Baby Dark Demolisher"
States
	{
	Spawn:
		DMSP A 10 A_Look
		Loop
	See:
		TNT1 A 0 A_Jump(62,"Rush")
		DMSP A 2 A_BabyMetal
		DMSP ABBCC 2 A_Chase
		DMSP D 2 A_BabyMetal
		DMSP DEEFF 2 A_Chase
		Loop
	Rush:
		TNT1 A 0 A_Metal
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostA",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP A 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostA",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP A 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostB",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP B 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostB",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP B 1 A_Chase
		TNT1 A 0 A_Metal		
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostC",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP C 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostC",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP C 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostD",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP D 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostD",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP D 1 A_Chase
		TNT1 A 0 A_Metal		
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostE",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP E 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostE",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP E 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostF",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP F 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("BabyDDGhostF",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		DMSP F 1 A_Chase	
		TNT1 A 0 A_Jump(84,"See")		
		Loop	
	Pause:
		TNT1 A 0
		DMSP A 10
		Goto See
	Missile:
		TNT1 A 0
		TNT1 A 0 A_Jump(70,"BFG10K")
	Normal:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("monsters/darkmasterwind",6,1.0,false)
		DMSP AAAAAAAAAAAAA 1 A_FaceTarget
	NormalLoop:
		TNT1 A 0 Bright A_PlaySound("monsters/darkmasterwind2",6,1.0,false)
		TNT1 A 0 Bright A_PlaySound("weapons/minigunfire",CHAN_WEAPON,1.0,0)
		TNT1 A 0 Bright A_CustomMissile("MonsterTracer",Random(26,30),0,Random(5,-5),0)
		TNT1 A 0 Bright A_SpawnItemEx("RifleCasing",8,8,18,Random(2,6),0,Random(1,3),Random(80,90),128)
		DMSP Q 3 Bright A_CustomBulletAttack(20.0,0,1,Random(1,5)*3,"BabyPuff")
		TNT1 A 0 Bright A_PlaySound("weapons/minigunfire",CHAN_WEAPON,1.0,0)
		TNT1 A 0 Bright A_SpawnItemEx("RifleCasing",8,-8,18,Random(2,6),0,Random(1,3),Random(-80,-90),128)
		DMSP R 2 Bright A_CustomBulletAttack(20.0,0,1,Random(1,5)*3,"BabyPuff")
		TNT1 A 0 Bright A_Jump(3,"Pause","Missile")
		TNT1 A 0 Bright A_SpidRefire
		Loop
	BFG10K:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("weapons/charge15k")
		DMSP G 16 Bright A_FaceTarget
		DMSP G 6 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
		DMSP H 4 Bright A_CustomMissile("BabyDemo10K",20,0,Random(4,-4),CMF_TRACKOWNER)
		DMSP G 6 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
		DMSP H 4 Bright A_CustomMissile("BabyDemo10K",20,0,Random(4,-4),CMF_TRACKOWNER)
		DMSP G 6 Bright A_FaceTarget	
		TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
		DMSP H 4 Bright A_CustomMissile("BabyDemo10K",20,0,Random(4,-4),CMF_TRACKOWNER)
		DMSP G 20 Bright A_PlaySound("weapons/bfg15kcooldown",CHAN_AUTO)
		Goto See
	Pain:
		TNT1 A 0
		TNT1 A 0 A_Jump(87,"PainMissile")
		DMSP I 10 A_Pain
		Goto See
	PainMissile:
		DMSP I 10 A_Pain
		Goto Missile
	Death:
		TNT1 A 0
		DMSP I 20 A_Scream
		DMSP J 6
		TNT1 AAA 0 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
		DMS2 KKKKK 2 Bright A_CustomMissile("Kaboom5", random(20,40), random(10,-10),random(0,360),2,random(0,360))
		TNT1 AAAA 0 A_CustomMissile("SmokeFX2",random(20,40),0,random(0,360),2,random(0,360))
		DMSP L 6 A_NoBlocking
		DMSP MN 6
		DMSP O 6 A_BossDeath
		DMSP P 63000 CanRaise A_KillMaster
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		DMSP PONMLKJ 5
		Goto See+1
	}
}

ACTOR BabyDDGhostA
{
Scale 1.2
RENDERSTYLE Translucent
Alpha 0.75
+CLIENTSIDEONLY
+NOINTERACTION
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 1 Bright
		DMSP A 2 A_FadeOut(0.18,1)
		Goto Spawn+2
	}
}

ACTOR BabyDDGhostB : BabyDDGhostA
{
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 1 Bright
		DMSP B 2 A_FadeOut(0.18,1)
		Goto Spawn+2
	}
}

ACTOR BabyDDGhostC : BabyDDGhostA
{
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 1 Bright
		DMSP C 2 A_FadeOut(0.18,1)
		Goto Spawn+2
	}
}

ACTOR BabyDDGhostD : BabyDDGhostA
{
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 1 Bright
		DMSP D 2 A_FadeOut(0.18,1)
		Goto Spawn+2
	}
}

ACTOR BabyDDGhostE : BabyDDGhostA
{
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 1 Bright
		DMSP E 2 A_FadeOut(0.18,1)
		Goto Spawn+2
	}
}

ACTOR BabyDDGhostF : BabyDDGhostA
{
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 1 Bright
		DMSP F 2 A_FadeOut(0.18,1)
		Goto Spawn+2
	}
}

ACTOR BabyDemo10K : 10KProjectile
{
-ThruSpecies
States
	{
	Death:
	XDeath:  
		TNT1 A 0 Bright
		TNT1 A 1 Bright A_SpawnItem("BabyDemo10KEx")
		Stop
	}
}
ACTOR BabyDemo10KEx : DarkDemo10KEx
{
DamageType ""
DamageType "Baby15K"
Obituary "%o was annihilated by a Baby Dark Demolisher."
}