ACTOR ImpLord 21768
{
Monster
Health 400
Height 56
Radius 20
Mass 500
Speed 10
bloodcolor "DarkRed"
PainChance 30
MeleeDamage 10
+FloorClip
+FastMelee
+MissileMore
+QUICKTORETALIATE
RadiusDamageFactor 0.3
DropItem "LifeEssence", 100
DropItem "ArmorBonusMax", 100
DropItem "BerserkPack", 80
DropItem "PureRage", 45
DropItem "DemonAmmo", 100
SeeSound "superimp/sight"
ActiveSound "superimp/active"
MeleeSound "baron/melee"
PainSound "voidimp/pain"
DeathSound "superimp/death"
Obituary "%o was smashed by an Imp Lord."
HitObituary "%o was smashed by an Imp Lord."
States
	{
	Spawn:
		LROO A 10 A_Look
		LROI A 10 A_Look
		Loop
	See:
		LROO AABB 3 A_Chase
		TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
		LROO CCDD 3 A_Chase
		TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
		Loop	
	Missile:
		TNT1 A 0
		TNT1 A 0 A_JumpIfCloser(250,"Claw")
		LROO EEEEEEEFFFFFFF 1 A_FaceTarget
		LROO G 5 A_CustomMissile("ImpLordBall",32,0,0)
		Goto See
	Claw:
		LROO AA 7 A_FaceTarget
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
		TNT1 A 0 ThrustThingZ(0,20,0,1)
		LROO F 2 A_Recoil(-30)
		LROO F 3 A_CustomMissile("ImpLunge",18,0,0,CMF_AIMDIRECTION)
		TNT1 A 0 A_PlaySound("baron/melee")
		LROO F 6
		LROO F 2 A_ScaleVelocity(0.2)
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		LROO F 1 A_ScaleVelocity(0)
		Goto See
	Melee:
		TNT1 A 0
		LROO EF 6 A_FaceTarget
		LROO G 4 A_MeleeAttack
		Goto See
	Pain:
		LROO H 2
		LROO H 2 A_Pain
		Goto See
	Death:
		TNT1 A 0
		LROO J 8 A_Scream
		LROO K 6
		LROO L 6 A_Fall
		LROO M 63000 CanRaise
		Stop
	XDeath:
		LROO N 3
		LROO O 3 A_XScream
		LROO P 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		LROO Q 3 A_Fall
		LROO RST 3
		LROO U 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		LROO TSRQPON 5
		Goto See
	}
}

ACTOR ImpLordBall : NewImpBall
{
Speed 18
FastSpeed 30
Damage 7
}

Actor ImpLunge : PinkyLunge { Species "Imps" }