ACTOR KSBehemoth
{
Monster
Health 1100
Height 64
Radius 26
Mass 2000
Speed 8
Scale 1.1
PainChance 80
+FLOORCLIP
+BOSSDEATH
+MISSILEMORE
+QUICKTORETALIATE
+DONTHURTSPECIES
+DONTHARMSPECIES
+DONTHARMCLASS
Species "Fatsos"
DamageFactor "BeheComet", 0.0
DamageFactor "FatFlamer", 0.0
SeeSound "monsters/volsee"
ActiveSound "manc/idle"
PainSound "monsters/volpain"
DeathSound "monsters/voldeath"
Obituary "%o was squashed by a Behemoth."
States
	{
	Spawn:
		FAT2 C 8 A_Look
		FAT2 C 8 A_Look
		FATI C 8 A_Look
		FATI C 8 A_Look
		Loop
	See:
		TNT1 A 0 A_SpawnItem("BeefyStep",0,0,0,0)
		FAT2 AABBCCDD 3 A_Chase
		TNT1 A 0 A_SpawnItem("BeefyStep",0,0,0,0)
		FAT2 EEFF 3 A_Chase
		Loop
	Missile:
		TNT1 A 0
		TNT1 A 0 A_Jump(82,"Seekers")
	Normal:
		TNT1 A 0 A_PlaySound("monsters/volattack")
		FAT2 GGG 5 A_FaceTarget
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 A_CustomMissile("BehemothComet",30,30,Random(6,-12),CMF_TRACKOWNER)
		FAT2 H 6 Bright A_CustomMissile("BehemothComet",30,-30,Random(12,-6),CMF_TRACKOWNER)
		FAT2 IG 8 A_FaceTarget
		TNT1 A 0 A_CustomMissile("BehemothComet",30,30,Random(6,-12),CMF_TRACKOWNER)
		FAT2 H 6 Bright A_CustomMissile("BehemothComet",30,-30,Random(12,-6),CMF_TRACKOWNER)
		FAT2 IG 12 A_FaceTarget
		TNT1 A 0 A_CustomMissile("BehemothComet",30,-30,Random(0,6),CMF_TRACKOWNER)
		FAT2 H 2 Bright A_CustomMissile("BehemothComet",30,30,Random(0,-6),CMF_TRACKOWNER)
		TNT1 A 0 A_CustomMissile("BehemothComet",30,30,Random(-7,-12),CMF_TRACKOWNER)
		FAT2 H 6 Bright A_CustomMissile("BehemothComet",30,-30,Random(7,12),CMF_TRACKOWNER)
		FAT2 IG 12
		Goto See
	Seekers:
		TNT1 A 0 A_PlaySound("monsters/volattack")
		FAT2 GGG 5 A_FaceTarget
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 A_CustomMissile("BehemothSeekingComet",30,30,-16,CMF_TRACKOWNER)
		FAT2 H 6 Bright A_CustomMissile("BehemothSeekingComet",30,-30,16,CMF_TRACKOWNER)
		FAT2 IG 12    
		Goto See
	Pain:
		TNT1 A 0
		TNT1 A 0 A_Jump(87,"PainMissile")
		FAT2 J 6 A_Pain
		Goto See
	PainMissile:
		FAT2 J 6 A_Pain
		Goto Missile
	Death:
		TNT1 A 0
		FAT2 J 3 A_ScreamAndUnblock
		TNT1 A 0 A_SpawnItemEx("KSBehemoth2",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_TELEFRAG)
		FATF AAA 2 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		TNT1 AA 0 A_SpawnItemEx("GibbedGenerator",random(10,-10),random(10,-10),random(20,60),0,0,0,0,128,0)
		TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud",random(10,80),0,random(0,360),2,random(0,360))
		FATF A 2 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		FATF A 525
		TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud",random(10,80),0,random(0,360),2,random(0,360))
		Stop
	}
}

ACTOR KSBehemoth2
{
Monster
Health 1100
Height 64
Radius 26
Mass 2000
Speed 6
PainChance 80
+FLOAT
+NOGRAVITY
-FLOORCLIP
+BOSSDEATH
+MISSILEMORE
+QUICKTORETALIATE
+DONTHURTSPECIES
+DONTHARMSPECIES
+DONTHARMCLASS
Species "Fatsos"
DamageFactor "BeheComet", 0.0
DamageFactor "FatFlamer", 0.0
DropItem "LifeEssence", 140
DropItem "ArmorBonusMax", 140
DropItem "BehemothCannon", 128
SeeSound "monsters/volsee"
PainSound "monsters/volpain"
DeathSound "monsters/voldeath"
ActiveSound "manc/idle"
Obituary "%o was squashed by a Behemoth wait again???."
States
	{
	Spawn:
		KSFA A 10 A_Look
		Loop
	See:
		KSFA AA 2 A_Chase
		Loop
	Missile:
		TNT1 A 0
		TNT1 A 0 A_Jump(82,"Seekers")
	Normal:
		TNT1 A 0 A_PlaySound("monsters/volattack")
		KSFA G 15 A_FaceTarget    
		TNT1 A 0 A_FaceTarget 
		TNT1 A 0 A_CustomMissile("BehemothComet",45,45,Random(6,-12))
		KSFA H 6 Bright A_CustomMissile("BehemothComet",45,-45,Random(12,-6))
		KSFA FG 8 A_FaceTarget      
		TNT1 A 0 A_CustomMissile("BehemothComet",45,45,Random(6,-12))
		KSFA H 6 Bright A_CustomMissile("BehemothComet",45,-45,Random(12,-6))
		KSFA FG 12 A_FaceTarget
		TNT1 A 0 A_CustomMissile("BehemothComet",45,-45,Random(0,6))
		KSFA H 2 Bright A_CustomMissile("BehemothComet",45,45,Random(0,-6))
		TNT1 A 0 A_CustomMissile("BehemothComet",45,45,Random(-7,-12))
		KSFA H 6 Bright A_CustomMissile("BehemothComet",45,-45,Random(7,12))
		KSFA FG 12
		Goto See
	Seekers:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("monsters/volattack")
		KSFA G 15 A_FaceTarget
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 A_CustomMissile("BehemothSeekingComet",45,45,-16)
		KSFA H 6 Bright A_CustomMissile("BehemothSeekingComet",45,-45,16)
		KSFA FG 12
		Goto See
	Pain:
		TNT1 A 0
		TNT1 A 0 A_Jump(87,"PainMissile")
		KSFA J 6 A_Pain
		Goto See
	PainMissile:
		TNT1 A 0
		KSFA J 6 A_Pain
		Goto Missile
	Death:
		TNT1 A 0
		KSFA K 6
		KSFA L 6 A_Scream
		TNT1 A 0 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		KSFA M 6 A_NoBlocking
		TNT1 A 0 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		KSFA NOP 6
		KSFA Q 63000 CanRaise A_KillMaster
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		KSFA QPONMLK 6
		Goto See
	}
}