//Weapons used in Wolfenstein 3D

ACTOR WolfClip : Ammo 21049
{
	Inventory.PickupSound "pickups/ammo"
	Inventory.PickupMessage "Clip of Bullets"
	Inventory.Amount 8
	Inventory.MaxAmount 99
	Ammo.BackpackAmount 8
	Ammo.BackpackMaxAmount 99
	Mass 10000
	States
	{
	Spawn:
		WCLI A -1
		Loop
	}
}

ACTOR WolfClipDrop : WolfClip
{
	Inventory.Amount 4
}

ACTOR WolfClipBox : WolfClip 21072
{
	Inventory.PickupMessage "Box of Bullets"
	Inventory.Amount 25
	Ammo.BackpackAmount 25
	States
	{
	Spawn:
		WAMM A -1
		Loop
	}
}

ACTOR WolfKnife : Weapon
{
	Weapon.SelectionOrder 4
	Weapon.AmmoUse 0
	AttackSound ""
	States
	{
	Ready:
		KNIF A 1 A_WeaponReady
		Loop
	Deselect:
		KNIF A 1 A_Lower
		Loop
	Select:
		KNIF A 1 A_Raise
		Loop
	Fire:
		KNIF B 3 OFFSET (0, 8)
		KNIF C 3
		KNIF D 3 A_CustomPunch (5, 1, 0, "BulletPuff")
		KNIF D 0 A_PlayWeaponSound ("weapons/wknife")
		KNIF E 3
		KNIF A 0 A_Refire
		Goto Ready
	Hold:
		KNIF A 1 OFFSET (0, 32)
		KNIF A 0 A_Refire
		Goto Ready
	}
} 


ACTOR WolfPistol : Weapon
{
	Weapon.SelectionOrder 3
	Inventory.PickupSound "pickups/ammo"
	Inventory.PickupMessage "Clip of Bullets"
	Weapon.AmmoType "WolfClip"
	Weapon.AmmoGive 8
	Weapon.AmmoUse 1
	AttackSound "weapons/wpistol"
	States
	{
	Spawn:
		WCLI A -1
		Loop
	Ready:
		LUGR A 1 A_WeaponReady
		Loop
	Deselect:
		LUGR A 1 A_Lower
		Loop
	Select:
		LUGR A 1 A_Raise
		Loop
	Fire:
		LUGR B 2
		LUGR C 3 BRIGHT A_FireBullets (0, 0, 1, 5)
		LUGR DE 3
		LUGR A 0 OFFSET (0, 32) A_Refire
		Goto Ready
	Hold:
		LUGR A 1 OFFSET (0, 32)
		LUGR A 0 A_Refire
		Goto Ready
	}
}
 
ACTOR WolfMachineGun : Weapon 21050
{
	Weapon.SelectionOrder 2
	Inventory.PickupSound "pickups/mgun"
	Inventory.PickupMessage "Machine Gun"
	Weapon.AmmoType "WolfClip"
	Weapon.AmmoGive 6
	Weapon.AmmoUse 1
	AttackSound "weapons/wmachinegun"
	States
	{
	Spawn:
		MGUN P -1
		Loop
	Ready:
		MPUN A 1 A_WeaponReady
		Loop
	Deselect:
		MPUN A 1 A_Lower
		Loop
	Select:
		MPUN A 1 A_Raise
		Loop
	Fire:
		MPUN AB 2
		MPUN C 3 BRIGHT A_FireBullets (0, 0, 1, 5)
		MPUN D 3
		MPUN E 3 A_ReFire
		Goto Ready
	Hold:
		MPUN C 3 BRIGHT A_FireBullets (0, 0, 1, 5)
		MPUN D 3
		MPUN E 3 A_Refire
		Goto Ready
	}
} 

ACTOR WolfChaingun : Weapon 21051
{
	Weapon.SelectionOrder 1
	Inventory.PickupSound "pickups/cgun"
	Inventory.PickupMessage "Chaingun"
	Weapon.AmmoType "WolfClip"
	Weapon.AmmoGive 6
	Weapon.AmmoUse 1
	AttackSound "weapons/wchaingun"
	States
	{
	Spawn:
		CGUN P -1
		Loop
	Ready:
		CGUN A 1 A_WeaponReady
		Loop
	Deselect:
		CGUN A 1 A_Lower
		Loop
	Select:
		CGUN A 1 A_Raise
		Loop
	Fire:
		CGUN AB 2
		CGUN CD 3 A_FireBullets (0, 0, 1, 5)
		CGUN E 2 A_ReFire
		Goto Ready
	Hold:
		CGUN CD 3 A_FireBullets (0, 0, 1, 5)
		CGUN E 2 A_ReFire
		Goto Ready
	}
}